gentoo auto-resync : 25:01:2024 - 10:43:56

2 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index 0b19fabb13c4..26ec6905cccb 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,3 +1,5 @@
 DIST hatch-hatchling-v1.21.0.gh.tar.gz 764748 BLAKE2B 3b048ed34df4da9ed5ec8d1c0121e21aabada559e981e9fd36a7188aceedf79594b165ed705edfbc5d210a09ee9a022c8c6e433e930338f2053e4c48feef0d44 SHA512 5ee8151929d6bdbb67e7f4e3e0298c730ff7fef5a7d7b764192eb2e16327d80a2935eee8831c168d19ed41c7184ca5b5eef7a67c9d5756cea25a7bd79945d344
+DIST hatch-hatchling-v1.21.1.gh.tar.gz 774577 BLAKE2B 31e2b50598b4fe120ecea407a37e3262876a2ec1e8cf02f272c25838e73afc37f2fef1f8fab08b2e3b83bfd828f6c558ce303b084081b83504343a8bb057c341 SHA512 91b5684737fac19758d7095b357f99031d46e9f981e093cab848ce770fd1f9440b69212f3ef2217e3700e7dd7985a97c2735bbd27b306c7b8aa7bffc5c950fb4
 EBUILD hatchling-1.21.0.ebuild 2602 BLAKE2B aa338609c3f53239f4be83a0fd88195bdd1882ca809a9154ac7eac4fe8b9dc229760ed06146dcde7d10d4aa24944e11a2b0043405400932ebf7a70a5f4d4cb96 SHA512 d1c6db265007dee1a40bd20c8318f679446c6a1ff4964514a3a98285e6b9fb44177bf1ba8aa15174ba450279626a5f7c44c053dd75473640b9409e7b3e9a92c8
+EBUILD hatchling-1.21.1.ebuild 2610 BLAKE2B b4a9ad8a3e6e5ab44fadc8af382bb3e3c100831f11638b41b3b603bbe724b00b020347ba814c36e6f68d540edbc6021fd9742b98965d0082e1609e26afa55854 SHA512 2a7d083ddacf3a4c9b8282d543b9bf485fcc9b27ac4be6b3882b9448658c8e69d562c953c97816757ce059eb6657a4c759102714aa6d698b0191985143ec81d5
 MISC metadata.xml 365 BLAKE2B 5a40a6cf6df042e6e8387830babd0171c9d8bc5d490fe2175b83d1588d827e826b49044ef29de48553515996b742fc475bb9699dcfa8ec05229162b22e0ed317 SHA512 f11bb25bc12c2bb0b0a0a4691115b9a2af525d9e44b33e0d6db98c7fcef0b49b5989fb7574ee8b27bc88f1dd2543bfdd492a6614de172e2c4edabbee8bf6161e
diff --git a/dev-python/hatchling/hatchling-1.21.1.ebuild b/dev-python/hatchling/hatchling-1.21.1.ebuild
new file mode 100644
index 000000000000..724901016b56
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.21.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/trove-classifiers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+		# broken if CARGO is set
+		tests/backend/builders/test_app.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+	epytest tests/backend
+}