gentoo auto-resync : 29:06:2024 - 08:00:25

2 files changed, 155 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 014e078bf1d2..c2c92e444b98 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -3,7 +3,9 @@ AUX ipython-8.24.0-mpl-3.9.patch 2792 BLAKE2B 6a06595e59a6f86f9f211a3a37d2d5792d
 AUX ipython-8.24.0-pytest-8.patch 4709 BLAKE2B 213f1bef47a0be8fd8d98e6eaf61933b19d8eb50a55157461f3b984e884450f4ae0abdd96bf13fd084c93aa70044f6e710af2e833de812474bcd82a130782dd9 SHA512 5231ef70de1edaeb2acb704c1422103fd01f6b41fd27fa5496bc16a382770ea61a0888f246ec1997e4436cdf203648ed0931a222a2d65398585a2981b3354ef8
 DIST ipython-8.24.0.tar.gz 5491819 BLAKE2B 49ca26f4ab6ceb7c787038db5b1073790d7a32cb96951bcc2ffa4ac05b3a689507e654344fda196560e2dc4b9e2225335e27bc3fb7472ba487adebb1ebba44e1 SHA512 adf032a93e94e1e8008a1cc106fb348d0bccb914a335e0ad04490531e7a7d16e7a2dc4a345f7faf1b3151d60a649413fa78130688cb59de088e5eb4291689310
 DIST ipython-8.25.0.tar.gz 5492936 BLAKE2B 1abb407e60d04e9f7834ee112f68bc1152b5693880dc091103ee015b1749949f9522537f183fd598992a5fe26124408bcfa8ad8550779fe94c0f2223b4879dca SHA512 b048a7bf65a16a1bc0d451a547998458ebfe93b4576bb89080f99d3e6ccbba34cfb1d3d33e2d32a6d1f6e8b2f3cf1b102b775f66c6610272ee8ffe15222d951f
+DIST ipython-8.26.0.tar.gz 5493422 BLAKE2B 2d05630d64d932190bf07c233e4241f5ce4830e62a3fb3551a93d9bfa83545de8090902a0528004b8233169d20652b7a3bbf1913ce078254246002956b1e44e1 SHA512 05f331cd39b75aed78bb06460f56145d9cefa2d65d818ae0fd25b3739d2c11830e3d6c427206787d3b3efec10de8ed4c966c25a70e4b7a7e1c914cfe8fba6a70
 EBUILD ipython-8.24.0-r1.ebuild 5033 BLAKE2B 411304291881059c87351861c7158db7cd0212b7d30055a5569ba4cbb0880c42062444487626b3f8bbc4edc7b964e12369c8ece6314e0db309af9818943364a0 SHA512 37f45ec0d1093cb27c2f8cb48e61ab9accc1815f4be15a193090cde1e626b238255d73d8902efbbc04b0c42fe2552f3762401d12296b4c9061f9ab871aa019c4
 EBUILD ipython-8.24.0.ebuild 4896 BLAKE2B d1bbab9880fe8d356f8d5c753c7f731ecd339272f769d025f7f6f1acc40b9776f612b6586334038ed86334fea8eb8a5f65d9245c9550644a79461f7731a71471 SHA512 aba6aa15e071dbd616f8ada72e0ba68424857b2fe58152e2697d920bfa77036804dda56155cd40bdf11a1aee6ecb29dc05cbc5f22e27d2a4af91a655e3de1e82
 EBUILD ipython-8.25.0.ebuild 4241 BLAKE2B b0ded5131d30ac2d8bbe39b245b25dfdbd1139fec3d602540c4e6b4913696e1a1b968972808875dcc920e8ad6161ecd4c97486cc8999475e782767ae595bfd22 SHA512 098b8de160ce77b1ae42d88e4abade649a486e265e30e296caf24058cd5e7f9a248bad8031444d73ddbd9b2a227d887e4e82166dcee11f2028564c5f6dbcc43a
+EBUILD ipython-8.26.0.ebuild 4286 BLAKE2B 6d4084ac2868b467be8eeefc6bb2b378f5f60dc6422f94650f16e6c5855439ca3e5e0532e45e3a5aaa30ca2461f073b14ff7a23dde142aebe1e08fdc8c0f4d80 SHA512 246a6d8bb6229c7ddc9edb6eb1b4aae4fbdcf6aac9605da4813676501b98083ebe0d56cdc1551da9dab42b865c29e57a0b64661a1d3ba78219a4e35ca3708ede
 MISC metadata.xml 2802 BLAKE2B 2fb6773ad4ef10d531f978e3ed40f6d99cf1586ec6d7cf2bf7e60fd5d640d082a0946651e0a066993320ffeaace3426066ca24c325926b62125ae91816707128 SHA512 965c3e36e05475d9454af8219b84e080d4c83d775f8a7e20a4951a82246d672c46fd3cb1fff5f8664d0ce8e8fcb846de6f15abc4575db3a6b7d87209194bcecc
diff --git a/dev-python/ipython/ipython-8.26.0.ebuild b/dev-python/ipython/ipython-8.26.0.ebuild
new file mode 100644
index 000000000000..c5cb7a5fe775
--- /dev/null
+++ b/dev-python/ipython/ipython-8.26.0.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/stack-data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10 3.11)
+"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.9[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+		qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# https://github.com/ipython/ipython/issues/14244
+				IPython/lib/tests/test_display.py::TestAudioDataWithoutNumpy
+			)
+			;;
+	esac
+
+	# nonfatal implied by virtx
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest -p asyncio --asyncio-mode=auto ||
+		die "Tests failed on ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}