gentoo resync : 06.04.2022

2 files changed, 162 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index b7c9f16c6a6a..f884ceea2dd3 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -3,8 +3,10 @@ DIST ipython-7.31.1.tar.gz 5156314 BLAKE2B e6528c9d3920078918180c4c2fae5d0ac20cd
 DIST ipython-8.0.1.tar.gz 5306811 BLAKE2B 9088faf779e2783ce97c6a45f0baa3c7163e12f63546aa65eb961de2b2fbacaac8ba1cf0c3c705bc326b4c999fe3ce672f31e3abaa7168d912504880ad8d3c2f SHA512 c4f3cf6e4aa7dab1e4e8cec2d669e5fe4ea3eeac9063132a38544596fafbaaed0f287bbdce12e8bc3d7613766c51b0e1ff8c7c86fdbd53e387caade6bbcdb828
 DIST ipython-8.1.0.tar.gz 5312523 BLAKE2B 9a44555dcb91655c5d483a7ba5d99074b9c2c4af3ec272d0adabc345352359b061ea4fd92198c3910945139edb80c8837afe1ae3c34b0bddb517d226584f28a1 SHA512 847ddab96ecfe06e46921b081fe3a51910c3fde1fa440c9955e374614b1ae6a7d20fc2e78d286178366893d342126a01a160a4efb0aa7be0b2234229638e95bc
 DIST ipython-8.1.1.tar.gz 5313998 BLAKE2B 0972b2f4a8072c5775f5cc4637aeb8e684b342d097d77e2d9d0a3e659d7a10f94f741bafc7f33595cbb205d8dbbc72e88b820e5407cb9ab506189d44e8c19cf0 SHA512 ce93d4d0839f32256461ff53c510f694db6ec0358a487a6af016d41f811e1b78b3244f1c67097e14afd32635ae392b4bff5d6eb2fc823c299c699335dc43bdc0
+DIST ipython-8.2.0.tar.gz 5400583 BLAKE2B 6af50e671823005b035a8463e65463b06dacb3bf4d43c4d3bd9720d1747ebda8abe3d73a49f59ae0e6e2651035db20bcfa1e82dbb0a73e40b4e2507e63118921 SHA512 0bf93527bcafe5dfbfe034b901dff2f002e0fc732159073f0371263e23784f45eb6c9e3f7f2cb9567e93ea4ee313773f836157afe9d23256e71bc4b2fcac15af
 EBUILD ipython-7.31.1.ebuild 4651 BLAKE2B ebe9ec2ae2f606efb76fed9ca1e3e04c78a13c8d86ec3223d02c980289e215bec65f01714d7758b707784c98f59fb7c934ff6f207cfe8943c9c0712217457637 SHA512 27e831552e274196810f5e88fbd7242dfdd8a233f60e8767c040d70557f0389f973105905eae473d8136d10b4f566ef3245afeb286065156d0b87ed3d451267d
 EBUILD ipython-8.0.1.ebuild 4503 BLAKE2B 1e152762209f46d4a20f8eaeda4cfe351ea0719131f667d03e5efde42eb18cf09128b6274b61afde42a4e2e88a35b6c0ae533dfa5053124d757d79aa8af4631d SHA512 1d42837b4e311c3e56e8be0ed0e076d1bf118cdbd4c5ef8038951629de21d5e7c4d1749fd3f7378c5080f3e9bd78d4a43c6cab087a5abbf8e0ee5ce9dda42e2f
 EBUILD ipython-8.1.0.ebuild 4522 BLAKE2B d260913823293f3314687bc8a9a9177c5de9543162e5c02b2331bc823b412335bd01435c349b7df2474a23a6abed79a17d40f98b69e125b6fa80e6dc80d56e91 SHA512 ba55f3888f8fa6b8d7a9052af96d01f1d9edac4d0cf4f969c5fc317e6321ecdb32b2f661b8c3bd6a3bd743e280e7bfad657f5c2d7c6b54befce8d92b0a0ddc3f
 EBUILD ipython-8.1.1.ebuild 4535 BLAKE2B 6c5613de80033d7a78fae46482b13f79abd65ab927774b682fe3da6afd02dca5e63dfd3e46962b72f1aabca936808eec43957daa031a3053bbd1ea92b289e30c SHA512 0acc5242b42bf9aef8e20fa2267ce6b1309077ec359f4a0cd2f3b18463dd21872ce3eb54468046d92317ce31d5d91bc654ddd97895503b27e6c14ecfdd430874
+EBUILD ipython-8.2.0.ebuild 4542 BLAKE2B 98ffcdf4c31a115165ac78fd383f0b7030a856952bcf03c4f8bff726189508b87d0f2c4a6cf807187a71fa5bb3419a7005a8401476a3cd51c8f3b6ae79299c07 SHA512 abb280e25136c3118b5842e069b7e0b50aa90932adae5c1708b1e8474200fececa1a7be8f9106604a2c8b73b5d5634a39c984f6875af6aa9a44f6e1c0881252c
 MISC metadata.xml 2883 BLAKE2B f61d1c66cdc9a956f3fdc9fcbc93fbc2051e9d0872beb9229e87a8fdabbce656efee9702e66bf30bec68009702f42e4036202e02208a428a8ed87b448f625536 SHA512 617f19e859544079d2680e9796e3ff0b7af41577776847d4c4dccfffc460dfc887631169289e5271120f375bea7c7836395abb9bf8a7628b3b55a7c1beefda9b
diff --git a/dev-python/ipython/ipython-8.2.0.ebuild b/dev-python/ipython/ipython-8.2.0.ebuild
new file mode 100644
index 000000000000..f4c7b535daeb
--- /dev/null
+++ b/dev-python/ipython/ipython-8.2.0.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/stack_data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# Internet
+		IPython/core/display.py::IPython.core.display.Image.__init__
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+	)
+	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
+		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
+	)
+	epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}