summaryrefslogtreecommitdiff
path: root/dev-python/ipython
diff options
context:
space:
mode:
authorV3n3RiX <venerix@koprulu.sector>2023-03-31 10:04:50 +0100
committerV3n3RiX <venerix@koprulu.sector>2023-03-31 10:04:50 +0100
commitf8b05ca448cdc580f580ff86eb8bef367d67c9ae (patch)
treeb11f11ae6a7fee98b05350f8cc542402aeb23d95 /dev-python/ipython
parent15d97fe857a00a52fd4efb0a31ed0560f9de3a24 (diff)
gentoo auto-resync : 31:03:2023 - 10:04:50
Diffstat (limited to 'dev-python/ipython')
-rw-r--r--dev-python/ipython/Manifest2
-rw-r--r--dev-python/ipython/ipython-8.12.0.ebuild159
2 files changed, 161 insertions, 0 deletions
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 3d549878587d..e6a2286cb4ef 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,6 +1,8 @@
AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc6a0b6bbdb524dfc66e0f4a7c69b0eeb2d35efb9d1845d567a11d1afa7881068b4757e42b9baf24dc01ba3026608a38 SHA512 fc4c9e12267ac5f04a2e16ad27334a093638538b8149ff380099fcbeb674a276ab9eb624a508010e37f82c05d5f7ab527a80e386b3e7b61c123ecb8effd9d542
DIST ipython-8.10.0.tar.gz 5456256 BLAKE2B 8ca8781326396ffa1e8012bab3b539b857a68e212afd5b2b97bc2f0eac6ec1aee45c0743d745554ef24fabd24667c2d6cdb3927350ca61b747e02afa215c1519 SHA512 5cfcdd49120d9ffc11d2f18501826b2f7094a51c439ac23e507f1027989ece4104d739a1905feba41f899d22a66e1345333f46e0f55d18925f166906f4992cfe
DIST ipython-8.11.0.tar.gz 5462176 BLAKE2B 6024c191f327d04f7a26f2f371b200e2e3f26029d84a3a53fc7421cb4751f0e29fb8741a2aa0447026b43cc1d9a7674a07e06c30578812cc33220c55df72c497 SHA512 9b07da3fed304f6739396883d0219386bb08d4860853b30f308c2e9b9017f48d1228dedb511c872b706881ee80dc7bf03f541720ffb816c35b66f6f53ac289a3
+DIST ipython-8.12.0.tar.gz 5465154 BLAKE2B 946d3e649dcf8eea3518ed68499cfcaa6caa7eac99aa21c05fcbb81338037151253ba84d8d942746600dad3883f6d0e8ba1e82e9932cdddc8e1e77a270573ebf SHA512 3e9a42a6fb34a46d32d1236eac99182a756db2ec7b57c77dbedff1e4b25bcf2ef37effe4e5575cda450a1cde77e3c0d24172dcf19d102110a1ac75b9cfe9272c
EBUILD ipython-8.10.0.ebuild 4302 BLAKE2B 56977f20d28b41ff6a3deae19eccf31c2f6cde75cb384dc7ed31bd969cf074278b8bc34fb1b5569be893715c11195754733efd00e492e1518dd6abc8c4a8f6e4 SHA512 428e96f2aa0593a08a82e2cfff989424ba0cef8f78270d1e497161c0ede8d9a88fa659d585033fb7d87b4d9be0fb2a74abf2c219a16213c0c9ee5ea81dfc4e67
EBUILD ipython-8.11.0.ebuild 4341 BLAKE2B c657404f0bf7fa6c9bed0772292859fa45456c702e3825651531efc1eaff7a2fb740c9ea52a2ad1fee18584670112b3cbe2e760d83bbd87b575062334c323375 SHA512 179cf02ed16f0f8a760bd1d53a92a60c3001813c89f84e78f7cc1ab4fd93a11d7997257166ec4804378d2b611cc0ba3902a9d5ad4f9fc0b3b17ec7f0fb17ec4b
+EBUILD ipython-8.12.0.ebuild 4423 BLAKE2B 82ea5dabe4579dec38cddc9e54e9ea3b403f60f5f803e2cb84c6ecd35775201a109f79481cf1863aef8bf49e3c93eb03481bacb3f15154c6d03e035467114bdf SHA512 31240e79ed752a85efec0341ebcb83f3eff0442a9b995592d6e5dd327c51861d24025bf5a990923e5f9edd2be64f8e38d3643b9dfaebf596e4bc60fc443b6da3
MISC metadata.xml 2886 BLAKE2B 88c80f5eef5c89c8939e60c1944be4c63a5a318e55a3490b38bf864e7919debf8e3c3a32f1fa0a43766ceec6462fb20fd4d943194fe2c08208f0839783c20916 SHA512 f4ed7c1898930ade11983fb0666dc25dce7907f017145e1ad903651dcd95ead2734893d55b4548c4ae23425388485a86bffc9d885eae17d12ae1ac2c0058aac2
diff --git a/dev-python/ipython/ipython-8.12.0.ebuild b/dev-python/ipython/ipython-8.12.0.ebuild
new file mode 100644
index 000000000000..1a16373c26a0
--- /dev/null
+++ b/dev-python/ipython/ipython-8.12.0.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+ https://ipython.org/
+ https://github.com/ipython/ipython/
+ https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/backcall[${PYTHON_USEDEP}]
+ dev-python/decorator[${PYTHON_USEDEP}]
+ >=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+ >=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+ dev-python/pickleshare[${PYTHON_USEDEP}]
+ >=dev-python/prompt-toolkit-3.0.38[${PYTHON_USEDEP}]
+ <dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/stack_data[${PYTHON_USEDEP}]
+ >=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ ' 3.9)
+"
+
+BDEPEND="
+ test? (
+ app-text/dvipng[truetype]
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+ dev-python/nbformat[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/testpath[${PYTHON_USEDEP}]
+ )
+ doc? (
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-2[${PYTHON_USEDEP}]
+ dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+ nbconvert? (
+ dev-python/nbconvert[${PYTHON_USEDEP}]
+ )
+"
+PDEPEND="
+ notebook? (
+ dev-python/notebook[${PYTHON_USEDEP}]
+ dev-python/ipywidgets[${PYTHON_USEDEP}]
+ dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+ )
+ qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+ smp? (
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ >=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+ )
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+python_prepare_all() {
+ # Remove out of date insource files
+ #rm IPython/extensions/cythonmagic.py || die
+ #rm IPython/extensions/rmagic.py || die
+
+ # Prevent un-needed download during build
+ if use doc; then
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+ fi
+
+ # Rename the test directory to reduce sys.path pollution
+ # https://github.com/ipython/ipython/issues/12892
+ mv IPython/extensions/{,ipython_}tests || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ emake -C docs html_noapi
+ HTML_DOCS=( docs/build/html/. )
+ fi
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+ local EPYTEST_DESELECT=(
+ # TODO: looks to be a regression due to a newer dep
+ IPython/core/tests/test_oinspect.py::test_class_signature
+ IPython/core/tests/test_oinspect.py::test_render_signature_long
+ IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+ )
+ # nonfatal implied by virtx
+ nonfatal epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+ distutils-r1_python_install
+
+ # Create ipythonX.Y symlinks.
+ # TODO:
+ # 1. do we want them for pypy? No. pypy has no numpy
+ # 2. handle it in the eclass instead (use _python_ln_rel).
+ # With pypy not an option the dosym becomes unconditional
+ dosym ../lib/python-exec/${EPYTHON}/ipython \
+ /usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+}
+
+pkg_postinst() {
+ optfeature "code formatting" dev-python/black
+ optfeature "sympyprinting" dev-python/sympy
+ optfeature "cythonmagic" dev-python/cython
+ optfeature "%lprun magic command" dev-python/line_profiler
+ optfeature "%mprun magic command" dev-python/memory_profiler
+
+ if use nbconvert; then
+ if ! has_version app-text/pandoc ; then
+ einfo "Node.js will be used to convert notebooks to other formats"
+ einfo "like HTML. Support for that is still experimental. If you"
+ einfo "encounter any problems, please use app-text/pandoc instead."
+ fi
+ fi
+}