reinit the tree, so we can have metadata

5 files changed, 194 insertions, 0 deletions

diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
new file mode 100644
index 000000000000..f854a4884a31
--- /dev/null
+++ b/dev-python/irc/Manifest
@@ -0,0 +1,9 @@
+DIST irc-11.0.1.zip 120409 SHA256 25d818003780fd6d62e93d3ff32580e74c0e527c6290ae14b47af50b58339233 SHA512 fca2fe653d921c9ec65dfb2b072c16658d88d4a22ae91568b1eaf722a90179920808db157f587afe6de0055af3a04a528eb9022122e539150e5635f05b58f466 WHIRLPOOL dd9b9e8624e6bd86d27fead1f3006a2b80832d236ad21f50c147c07a27b2cc4933d68efd951dece44398dbc0299b73ba7a98e4eff2061d0e3a8a01833518113b
+DIST irc-15.0.2.tar.gz 81790 SHA256 23893c1fb21826fd9b3edf6ef49b0e1080c846761900ab06b4f1980f5cb8e2e3 SHA512 5f6daa539a9ae665b0153d97ab11f246040963d9109d84efde0a92cbe200c2a6e8126120eee11b4bc92d65d415946627116b62cde07bebeb68a7105af40f98ab WHIRLPOOL 1f28b3e343328a2c78af406944fcfac4be25a61834e1807d7a1636834a2ea9fa9775856380e8ea75df7917913756a4b971e76ab47a06e0379304dfd2e5d81e61
+DIST irc-15.0.6.tar.gz 81996 SHA256 986706eb76da86f14ebd69f7955a2ae132fe45dde60e67ddd9c6c50b7dc914ee SHA512 48240eb496a3c88310f02cf092b8e19e4aa8d8dc165a9a8a39c313490a69ecc29ac67db297436df5e86e7253e2481bd19bc0429ea9cc359089a5cd6179125c0f WHIRLPOOL 33dbe34c49027d3dad6d1b3b322713185ebabb1607dde8a4f53ab9f48294dd5d592cffb98e66572d33e0e68a5a394eab2c2d3a5021af2ffa7b761792774bab5f
+EBUILD irc-11.0.1.ebuild 1058 SHA256 57e6f7719d5a3ca29847510ccda943df51c1802a62abbeaaea665f9e3b312ff9 SHA512 3fecbcd9053445d79aa566748ae22bd83583e3d58cd2ef45ededa958dbdfa4033ef2ca8296e206400702f8737ec58862360e12276566c36a6a312d2f1a53f01c WHIRLPOOL ab9f597e412dac442e16b87125b5bb1194f05af989549b121a448b1e8ec6b543f44d04650061d33678667ce3514158ad60bb43d49f842ebeae876a2fb0aa7993
+EBUILD irc-15.0.2.ebuild 1585 SHA256 8b10925f59ea14c98633c8f4b3db67e3489d797bb13594118a3329b195b773ca SHA512 010c5830c9717f23088867e090647295f73cdcbb01642d67ca936cc08595a53bb155e44b1f120821010dc4422f8ada908e2a7f66e3f4853604a8640758015443 WHIRLPOOL 4a7a39cafdbb6443d078ad9e40acb3bf7d86eeafeb468bfe73647a25ad5ca7db9b8454c3e29981bdeaab7ebe35be917e6f678a957233841085507dfd219bbffb
+EBUILD irc-15.0.6.ebuild 1597 SHA256 655958533c07c373692e31e8c5f5e8b266975a78fbd16942e16d251fb890a50b SHA512 df65de77ef9fdb42bfd560212e5c9e86fb1d6febb58e4691a1a8ac3392b424709e81614b22c301f775b40e7682cb938012f4d98298ffad6e1dd62c1600af9ecb WHIRLPOOL bb4bd874b63fa5d6f3c747f615edb15d08c0e66b5fcc0b34c757a96164d31608805412daf7d140ad2368a44291b7cd08c3f22de4bbe5c2f5047ee328c297c17e
+MISC ChangeLog 5958 SHA256 34214b36da2ad6979b1602c5393e7ea5489980bb6770745998b513b62f1e607d SHA512 b5a6479f697328f18596936163d370bd686f8b2020b3085a3d2076b0175481eaec48ed71cce0c54b2f3f03814dd1691b7ba9dfa388b129b52cb506e573665fe6 WHIRLPOOL 5fba93dc262fe2020afca56aac6dd7f83495d8eb6daa6305444eb8ce73c72e2d50e791e3963ffe2679000aa6260a32129b6615932f7707cfdacaba4c8108cdb9
+MISC ChangeLog-2015 4853 SHA256 e0a6e9e62d7cbcb58c82332e7a1784f79a8225674273fd8f522269e387a005a7 SHA512 f1f1c7bbb13686353cb8361caff6419a22b3b97482b6607f8063b33376a58333fdb8e1c15b271189719e6c1f063eb7076a445881e2d4b852249a70803dc72461 WHIRLPOOL 837f08859e2c680c39eed1142b24dd4f4e308b70e804b9bc2c36c340f45c1487ec5f035aebaa9a00feb1bd8c15255b6f20cbf3085d5835be6b9bc4c7336eb7cc
+MISC metadata.xml 814 SHA256 66667bb653290fcb226a7311d2324c8b1cf9c26dae3a25d13dd6c5cb7f9ba187 SHA512 97c3129365cbe22cf31f5ea6147163b21da942f65838330d608ddbc41a516f2600e0bc00e7fef18ee53f7a51cc1682650684283a8abf45a4ae28972939783e05 WHIRLPOOL 303211aa59397bede6787aa1d4f693b61fbefc52334f811a47406cb8a67bc03368c0fb8269b7246cc14509db8a75cea5a45ea5ce98d3665a2f500267104debfd
diff --git a/dev-python/irc/irc-11.0.1.ebuild b/dev-python/irc/irc-11.0.1.ebuild
new file mode 100644
index 000000000000..29fbdd70e186
--- /dev/null
+++ b/dev-python/irc/irc-11.0.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="examples test"
+
+RDEPEND="
+	!>=dev-python/python-irclib-3.2.2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jaraco-utils[${PYTHON_USEDEP}]"
+
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/hgtools-5[${PYTHON_USEDEP}]
+	dev-python/pytest-runner[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+# A doc folder is present however it appears to be used for doctests
+
+python_test() {
+	py.test irc/tests || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( scripts/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/irc/irc-15.0.2.ebuild b/dev-python/irc/irc-15.0.2.ebuild
new file mode 100644
index 000000000000..c58d4a5e56c9
--- /dev/null
+++ b/dev-python/irc/irc-15.0.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.5[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		doins -r scripts
+	fi
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/irc/irc-15.0.6.ebuild b/dev-python/irc/irc-15.0.6.ebuild
new file mode 100644
index 000000000000..b84a0821d677
--- /dev/null
+++ b/dev-python/irc/irc-15.0.6.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.5[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		doins -r scripts
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/irc/metadata.xml b/dev-python/irc/metadata.xml
new file mode 100644
index 000000000000..f4d5c71852d1
--- /dev/null
+++ b/dev-python/irc/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@gmail.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>
+		This project includes an event-driven IRC client framework written in Python,
+		as well as an object-oriented wrapper class and some example programs.
+	</longdescription>
+	<upstream>
+		<remote-id type="pypi">irc</remote-id>
+		<remote-id type="github">jaraco/irc</remote-id>
+		<bugs-to>https://github.com/jaraco/irc/issues</bugs-to>
+		<changelog>https://github.com/jaraco/irc/blob/master/CHANGES.rst</changelog>
+	</upstream>
+</pkgmetadata>