gentoo resync : 13.06.2020

2 files changed, 166 insertions, 0 deletions

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 1b7d5816f155..5314998664bb 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1,7 +1,9 @@
 AUX pandas-0.24.2-skip-broken-test.patch 644 BLAKE2B 8a879cb0cf3f9b2e7c80a649fe37730334a6c24d130578f0febb6aceb8857db375a38e136c498d3468f664bac0499fd60edeaa49c198ccc022a49fe11362476d SHA512 b3ac2e667b116ffca750bd0abb39408c696d6e8459b5a5a83417618bdcec1724a70a0ab3e15a3b314c25de4a1bccea73c226ca7df4dd80141b4befa204c392d4
 DIST pandas-0.24.2.tar.gz 11837693 BLAKE2B 3762e94554a3ae3c803c9a412c5c551c15a9fbf15cb05633f7d1b0ccbfddc646f68f0306666e688a83a4495b0537cea2fec671157f5a63aaa5f9cad6b791261e SHA512 0795c6bb8a47a511853558ea59d371b4540ec175f213cfba4ad2361d6481fea5d3f7074bb4961c32f2f0080a72d7436a9b3706f5cc692074f98d83bfc587fd15
 DIST pandas-1.0.1.tar.gz 4852368 BLAKE2B d6d3ae757d245b665e4b67bd237c090ddff97688934268b171e278a14d2439f5d993addc304f16a0ac9ab7bc34bfe36df807f998148106b062c567a5a7f14f4a SHA512 6755d17a4a4a8c3770f413199a12b3c4d6b5f5fcc925bec9b9b0f813fcd020df0b2c0a32dc8528c795b16556e00c078a03e4a6746192b44bfbd7ffc809c1e56c
+DIST pandas-1.0.4.tar.gz 5040267 BLAKE2B 2855b1708e1ae4c56b6118613ec644d010a3af7db474bb30aec3cf84e497371af03b63a2168f6daf0fc42da07274f8724734117c6aaea34f49eeafbf6ac73b9f SHA512 01ef73cab3db067ca4a29992d71aa637425b8d70473fde6ccfb359dfedc9546315c6d37d74f3825c924cab789c2536ec69db071a303cfc5e1a7897b253dd9467
 EBUILD pandas-0.24.2.ebuild 5376 BLAKE2B 9277f27158afa9b9989d89190d04a67165d6452fb8a83964c85582b6d984726499fb2d10aa684194d5414500e04d86fd3307a0b74330d35848952d2c6c780a84 SHA512 b2577e30bb76a8b86d3ed062acf3978ff885c355428b677a0cb66cdfb80de84a81eb6126753a94b642e608b19990589518acb7aa2ce7209ff5e04bbdd05748b2
 EBUILD pandas-1.0.1.ebuild 5375 BLAKE2B 558b287f3d7f754bb15fb691de2170805fee29358b50d7248953b99fd4bf83d01afec9d382015f10e549a561bd34b87225fcbab8c2fcdf035c312cc1515e584a SHA512 edcf506b007633a4676e49c29f6446dd9753a1362998a1b8ac05831b912af3a3e7effe9a1163e17d126e1565d777ddeafd3f66e9c467f150efbbe9c08dc1ed64
+EBUILD pandas-1.0.4.ebuild 5375 BLAKE2B 558b287f3d7f754bb15fb691de2170805fee29358b50d7248953b99fd4bf83d01afec9d382015f10e549a561bd34b87225fcbab8c2fcdf035c312cc1515e584a SHA512 edcf506b007633a4676e49c29f6446dd9753a1362998a1b8ac05831b912af3a3e7effe9a1163e17d126e1565d777ddeafd3f66e9c467f150efbbe9c08dc1ed64
 EBUILD pandas-9999.ebuild 5663 BLAKE2B 1b4c3889527930dd52d1a8a688b484acc524b318d6bd5b4b0c6cfceceeeb0b1b87b48476b5da8464e01c0d67cbcee93fe4b2aacb6679d1909d566bc8acc20bb5 SHA512 16ff9d6e6c0516ac468b23d4aa4b8e2b487b6404271a78b76bd8705df078d0d66e04a20dad1d65cda62d31ee5ec1965949202188c2450ebda45788896ad2bdbe
 MISC metadata.xml 834 BLAKE2B b075b9c90c4f1be265117df2c47ace4c86dad3fec9945b5a483a11048211348ee10e433f378610de4a9b599031914b32992b9fad693b832cf0266b0f171b3e38 SHA512 85ad67a653f4ced5fb9331b778fb2906c253874cf8e522f1b67547ef8e2f49e084e84d9e055aee7e2a57c6e6e4e7f7791a4ce299fac7c74dd6448a94977e8f5e
diff --git a/dev-python/pandas/pandas-1.0.4.ebuild b/dev-python/pandas/pandas-1.0.4.ebuild
new file mode 100644
index 000000000000..c2bd75a1183a
--- /dev/null
+++ b/dev-python/pandas/pandas-1.0.4.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="https://pandas.pydata.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/_/}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	dev-python/s3fs[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.10.8[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-1.0.0[${PYTHON_USEDEP}]
+	dev-python/xlwt[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-1.1[${PYTHON_USEDEP}]
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>dev-python/numpy-1.13.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+S="${WORKDIR}/${P/_/}"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+python_test() {
+	pushd  "${BUILD_DIR}"/lib > /dev/null
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	PYTHONPATH=. virtx pytest pandas -v --skip-slow --skip-network \
+		-m "not single"
+	find . -name .pytest_cache -exec rm -r {} + || die
+	popd > /dev/null
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "necessary for Amazon S3 access" dev-python/s3fs
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-1.6.1" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-0.8.1"
+	optfeature "miscellaneous statistical functions" sci-libs/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}