gentoo resync : 19.03.2019

2 files changed, 173 insertions, 0 deletions

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 3733da678f45..94a5d1ffdd80 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -4,8 +4,10 @@ AUX pandas-0.23.4-skip-broken-test.patch 1027 BLAKE2B cf6c1d8a2a99a04a30ba989fa8
 DIST pandas-0.19.1.tar.gz 8360233 BLAKE2B 82611ca1a3e3169ac2d084f4dcd9c4d4d74e9e9c9913a41acad48ae68a208a884dfd877445a7d658a7ff098ef383cedae7e79a4900baa8d56c032ce9aaad96eb SHA512 6451990a7fae8c6db8ab0b014a13b4f1828754d3998f13c17b111f891fb9fd23f8e09b907623096dfa55668c42298eee1373210a9fddb95f56dd7d552b964e6f
 DIST pandas-0.23.0.tar.gz 13092442 BLAKE2B e11ae088c9a4be481f516d83797b1b1d5e9c82f7d9fa98f1ea65e3405e33c99e1e1cf7a35f56a21d9dc922c1d0828b4947d9c6189a5f76ad5c1b28618293f9da SHA512 c9dc7bf843e3392b8b1b4d46c6aa6dd12435aa974abc875574a7a8794abe6ea531fa92d8a635153839fd3fef9059d96a4512831b86b1fb6fb69588c8b29a95d6
 DIST pandas-0.23.4.tar.gz 10490077 BLAKE2B 28a78860e0aa5de8def7bb529fc98b9121a516b7fd7620e31e000ae14217165e6677ce26b56da0b9c603930ab1304725c644426a135d8f9b2a84921b88f3d23d SHA512 0c89db820a49e0cfb9764e64589ff9af819f9a53c01bd0254cd1b6dbd1e9fd452b2ff7c7330ede7623c7576589113e831a19a57c735562b55f90506df15805b9
+DIST pandas-0.24.1.tar.gz 11832827 BLAKE2B fd30fb736be9ac1e1778d78963ffa33e492fa27a54767c93647cef826cc95459dc97d07a88836554586c9a2db038fb2d897caa8bd1413433f276cffbdb49b1cc SHA512 15f75308f4c437ad0096c3a3d768563b071b3d8e55e1850a5ee0f980f56a9d8d1b9fed9d7707ba43e80052e6c5fea313ac1ad2687935f0ab37a16a68bf64ae19
 EBUILD pandas-0.19.1.ebuild 5789 BLAKE2B 1a48461ca3a2c779646b50ed1279c44f7d0a5af9b7686968704f7538035eaf55133c0f92e9510c8781e3d3fe8704ec5428ea826dd20225864d87a08d76921f9f SHA512 4bf3ce6604cb8815fe26843983c07ef9e17969d98cd24de24e614bfd12fe826644893f81f74daa64df2148651c2c80ea944a719211c90cc4c6bdeb8ca772bf2f
 EBUILD pandas-0.23.0.ebuild 5907 BLAKE2B 552a809a85a1ec3842c5e3ef7da41c32b07818f11a00121eed4fe4ff3131d8e90a3f56dba4f2f546fa226e23f29da8d3827bb17f676caf654b7c1293de294226 SHA512 e1b4cce520baea14cfaf7c46e7f4ac881b6871133b13c50828ed946482b4d4f3fca688db4508007a108fd7f94997f384f6ca14eb53667e9f28e697e8d8aba94e
 EBUILD pandas-0.23.4.ebuild 5778 BLAKE2B 1fd378e985e5794f331e45741b5f2fe7380b4f0f993ff727a34d4a0879cc7dfb3ffe6c0bfb119a59ddc73fee2ef5554e31790a638673d5ee652dd1e55c0e55a6 SHA512 999dde9816f75a305e223dfcbeac0a37bd5ec084a0af24547297cb8553a57d1ed33e10279fb6a1ed43e4295c6b9b7ab805cfb413e3833d540a7090e8fe25f071
+EBUILD pandas-0.24.1.ebuild 5778 BLAKE2B e25cf59468018d079adcab0bfb8e2f154b94d886327567b3777440d3ee5774f38d69065bc8fd69fba15fcfe899fcae8e3d6b06054c57b2ef91188a40f245259c SHA512 631bee29755feebee928be30f0bb239d2594c2e3ab0cacad81d2831308392837f70c3f6dda17bdf517363e317c424784de8c3097ceed1e6695f15f94d5f034a3
 EBUILD pandas-9999.ebuild 5864 BLAKE2B 23df5dc740f518ce7c82cda5d351b248f8d8e0983b937be43200f2a2f5bc6d48ea71234203fc6776f94a9460dc6e6340dbfa0248b64205eb2792a7b633ee58a3 SHA512 80c4d885b9dc3872b3da9a9daa9f18e2e1b226d249b23eb2d8b3b3161458648ebd77a2c3b17d25e58d2f278d9a9fc2372a62b946acf24bdc441da882067fee67
 MISC metadata.xml 834 BLAKE2B b075b9c90c4f1be265117df2c47ace4c86dad3fec9945b5a483a11048211348ee10e433f378610de4a9b599031914b32992b9fad693b832cf0266b0f171b3e38 SHA512 85ad67a653f4ced5fb9331b778fb2906c253874cf8e522f1b67547ef8e2f49e084e84d9e055aee7e2a57c6e6e4e7f7791a4ce299fac7c74dd6448a94977e8f5e
diff --git a/dev-python/pandas/pandas-0.24.1.ebuild b/dev-python/pandas/pandas-0.24.1.ebuild
new file mode 100644
index 000000000000..25670ee8bcfa
--- /dev/null
+++ b/dev-python/pandas/pandas-0.24.1.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.pydata.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/_/}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc full-support minimal test X"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+"
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	dev-python/boto[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
+	dev-python/rpy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.10.8[${PYTHON_USEDEP}]
+	dev-python/xlrd[${PYTHON_USEDEP}]
+	dev-python/xlwt[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			dev-python/pygtk[$(python_gen_usedep python2_7)]
+		)
+		|| (
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cython-0.23[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${COMMON_DEPEND}
+	!<dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+	!~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+S="${WORKDIR}/${P/_/}"
+
+#PATCHES=(
+#	"${FILESDIR}/${PN}-0.23.4-skip-broken-test.patch"
+#)
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html || die
+	fi
+}
+
+python_test() {
+	pushd  "${BUILD_DIR}"/lib > /dev/null
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	PYTHONPATH=. virtx pytest pandas -v --skip-slow --skip-network \
+		-m "not single"
+	popd > /dev/null
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "necessary for Amazon S3 access" dev-python/boto
+	optfeature "needed for pandas.io.gbq" dev-python/httplib2 dev-python/setuptools dev-python/python-gflags ">=dev-python/google-api-python-client-1.2.0"
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-1.6.1" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-0.8.1"
+	optfeature "miscellaneous statistical functions" sci-libs/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}