gentoo resync : 04.05.2018

2 files changed, 173 insertions, 0 deletions

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 773fe1b5b200..512e26cbb6ea 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -7,11 +7,13 @@ DIST pandas-0.17.1.tar.gz 6674479 BLAKE2B 0d61f0a603f758aaef6c2eddf6d70307255679
 DIST pandas-0.19.1.tar.gz 8360233 BLAKE2B 82611ca1a3e3169ac2d084f4dcd9c4d4d74e9e9c9913a41acad48ae68a208a884dfd877445a7d658a7ff098ef383cedae7e79a4900baa8d56c032ce9aaad96eb SHA512 6451990a7fae8c6db8ab0b014a13b4f1828754d3998f13c17b111f891fb9fd23f8e09b907623096dfa55668c42298eee1373210a9fddb95f56dd7d552b964e6f
 DIST pandas-0.20.1.tar.gz 10307434 BLAKE2B f8490a4a7f5c165753df274a0dea81552efc90a0cbf78d9e1fbeb6d0bc26e8ffaf3dbdf796a3abfb29d01332004af2adfbd9946c69d905f309cc730613de8123 SHA512 d477a815914c825efd6430f7eb19f3f9115c1c4ab03000ca6d4f64023f7b5f53eff512792fea2d8b33c7febb3667fc3a3de55f11eeb453f285cae40e6b473707
 DIST pandas-0.20.3.tar.gz 10402185 BLAKE2B a2c8d8f0007d481ccb897d2e9be106319cd3b7c0edf397fb99e7c6f43511c218ff5e7a7f099fcf23406f7e3ea691272e75c0f130cce991ccf159df7223d26584 SHA512 891c7e04d075f96fadf3775e903472e279eaeaa4509eb0da81a74261a3ed86ff309de0b5a2c100ee93dd968fed1df6d7e426ca78785b2b36785fe7679218fdc5
+DIST pandas-0.23.0rc2.tar.gz 12542694 BLAKE2B 7c6383d32430fec89b7d5cbb1f8eef0f2201ba85d5865118fa035b6ad4c852b5f4e691f98f0cf3ac5c1283720025f8500c43414d0931af5211972208428537bd SHA512 3df13f74dbcac00baffd39c732751d4e7bd16adf529b60b05b2373651d86e0aba37d6f3a4339df170e9ab3d89ee03fc18827dd3728ff972bcdfe3a0604bff59d
 EBUILD pandas-0.16.2.ebuild 3830 BLAKE2B a4feceede6288ca9d86177cd316168013d4a1d85bfab47de686a8435e4aa422c98ea156468da22010a61fae309fe1049902766f3a83d5e7db6483e8eaf9b3080 SHA512 b6e18279292c1772e5d9527e5f4baf520d07f30ee45e3604946cdc2b1731f881519815c229bdda41b2a02740c04f3d70fce6210bac094fb55c23fc5364970808
 EBUILD pandas-0.17.0.ebuild 3983 BLAKE2B a9875a252348369ff718878dd2ae06d703742d1ba1dafa1538a456b1ccf231a99f6b774c745035e9a4c23df7e7679674da50db55c2b4c0fad03de659d1ab75d4 SHA512 6a70c8b7045218f70ade388bde921c0f48c70344623d3ccaa4c0c7dd0ed35198da14e5faa28d1b16ed3a3ff88e174e662c53c2bb5cd6186464e8b718c97d84c7
 EBUILD pandas-0.17.1.ebuild 5955 BLAKE2B d6a2126678d1c93d16346c7a83425810eb11853a95a6391dfc8b67577708485c7906ec18c1d50b641061e559061bcaa2f5c562ba6532b39b068b8e15aa356013 SHA512 7fd34871cdf5178536c45416c2fcb39d76e3fa3355cee9ce39e44a228da6cb929980e52727683ece946328d0acd7f8a9072f60e1d696d9f00fea7b07f187f941
 EBUILD pandas-0.19.1.ebuild 5913 BLAKE2B 994e9ea3397d2dacb0a01ad17c8285cae39a898c5615b42598f0a85745a74b4c01a2968da343a969160f18658fdae8cc6e6f0288f7254189d6233a4e16b21923 SHA512 6e88582440d02ad3adf338692082ff671c0c4f93f56adb029abfa5dea7210de30308371f990e4b2bbcdfbd510040e40c18a373123a862099d779993f81dda714
 EBUILD pandas-0.20.1.ebuild 5846 BLAKE2B b6abf38026c04a904b40d130c039c4395fd0bbd51aeb584a72428a26afddccb90198e6e02469eaa3942f6f76b95bdd6e9b53f433cfd5fd7715de9729ea35fb41 SHA512 9bb42445edb8f4dc62df830e30b8ea2e0856bf214f0621d7cbecebd2adc142bc2a4031e162e9ff93daf5f600d9e405386a32dca515fa6433f91e962c8ae00c37
 EBUILD pandas-0.20.3.ebuild 5759 BLAKE2B 59d904b1b8ca18a0baf2f58340a0b24cf1e99bee4a40a51530ec9fc79eac2fa093a05aedcb7f0e268d06a1828a013736679d26594ba443e1ad763d69c062f29b SHA512 fe6f54a082a50d4ab3edb16c9b2f11cae1440027b06e35b539133b76584c9ae615fa9f72a70328df26de7012c67d250574e47ec0b443eb84e480792b6743846b
+EBUILD pandas-0.23.0_rc2.ebuild 5867 BLAKE2B 1f646f93b08f31f65bb61479fb09b3cf1005dd21dbbe859c332de535f2540f22bc53180e23bbdb66870a0675ca527f37343b3a5f9aabde9ae1c953775bf9a76e SHA512 922c5dcff6e238a018781f2b289149fe004b72371411dc0f3191565c9a590e7fe5f3e372ca8e524c4745e26789e68d5029e7ff96de23f1ee274aaf4c6e2fe828
 EBUILD pandas-9999.ebuild 5824 BLAKE2B adee94b3e8a50e86a21ef64b75650ae372d7b9d9be888519fdf4769e6fe3d6e4425e5c325685f820b8d7599addc39e260d6b138080b40f9e275586dae9a3a096 SHA512 043c913888f3290c2bc651de252ac73d8ea9c9061a72781f747d291f46a3f8dd4b760ef2449f61b5249a79293dcad6ca389b11608e0431c6324c9e1adde1a189
 MISC metadata.xml 1077 BLAKE2B e9bfcfb9fc1baf813931a3cd0829136cdeb0a52a3a34a0d0ba28fbad6d4c3ebee24f1e5624d5242541fd14f4c435830b68ea30eab03d796e497116bdff732c77 SHA512 60b23a75873ded48dd01a36dae62f45f1cf5d044b88b125bda249fd6cf558ddef42d6677218053ed9d73de31da54f1f85bd1f64eab9b377f1a8b51fe1c510308
diff --git a/dev-python/pandas/pandas-0.23.0_rc2.ebuild b/dev-python/pandas/pandas-0.23.0_rc2.ebuild
new file mode 100644
index 000000000000..57471830de8c
--- /dev/null
+++ b/dev-python/pandas/pandas-0.23.0_rc2.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.pydata.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/_/}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc full-support minimal test X"
+
+RECOMMENDED_DEPEND="
+	dev-python/bottleneck[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+"
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	dev-python/boto[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
+	dev-python/rpy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
+	dev-python/xarray[${PYTHON_USEDEP}]
+	dev-python/xlrd[${PYTHON_USEDEP}]
+	dev-python/xlwt[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			dev-python/pygtk[$(python_gen_usedep python2_7)]
+		)
+		|| (
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cython-0.23[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${COMMON_DEPEND}
+	!<dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+	!~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+S="${WORKDIR}/${P/_/}"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# https://github.com/pydata/pandas/issues/11299
+	sed -e 's:testOdArray:disable:g' \
+		-i pandas/tests/io/json/test_ujson.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html || die
+	fi
+}
+
+python_test() {
+	local test_pandas='not network and not disabled'
+	[[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
+	pushd  "${BUILD_DIR}"/lib > /dev/null
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	PYTHONPATH=. MPLCONFIGDIR=. \
+		virtx nosetests --verbosity=3 -A "${test_pandas}" pandas
+	popd > /dev/null
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "necessary for Amazon S3 access" dev-python/boto
+	optfeature "needed for pandas.io.gbq" dev-python/httplib2 dev-python/setuptools dev-python/python-gflags ">=dev-python/google-api-python-client-1.2.0"
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-1.6.1" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-0.8.1"
+	optfeature "miscellaneous statistical functions" sci-libs/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}