gentoo resync : 23.09.2020

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/pexpect/pexpect-4.8.0-r1.ebuild b/dev-python/pexpect/pexpect-4.8.0-r1.ebuild
new file mode 100644
index 000000000000..8a77f172f4c2
--- /dev/null
+++ b/dev-python/pexpect/pexpect-4.8.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for spawning child apps and responding to expected patterns"
+HOMEPAGE="https://pexpect.readthedocs.io/ https://pypi.org/project/pexpect/ https://github.com/pexpect/pexpect/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples"
+
+RDEPEND=">=dev-python/ptyprocess-0.5[${PYTHON_USEDEP}]"
+DEPEND="
+	doc? ( dev-python/sphinx )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-sphinx-3.patch
+)
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! python_is_python3; then
+		# https://bugs.gentoo.org/703100
+		rm "${D}$(python_get_sitedir)/pexpect/_async.py" || die
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}