gentoo auto-resync : 07:08:2024 - 12:37:20

3 files changed, 175 insertions, 2 deletions

diff --git a/dev-python/pip/Manifest b/dev-python/pip/Manifest
index 0e8bd9bae486..a6a1f55e7e42 100644
--- a/dev-python/pip/Manifest
+++ b/dev-python/pip/Manifest
@@ -6,9 +6,11 @@ DIST pip-24.0.gh.tar.gz 9398156 BLAKE2B 17a7ed9e15e9b8efa0d3e3c5586dc446958b62cf
 DIST pip-24.1.1.gh.tar.gz 9190972 BLAKE2B 1ce876d2767c1c36bac3237c17a3aced9dd5a335a7b522c70cee1e155bc0b47256db74c6835aab5f58133ebcde0daeb8e6eb217b06f76418c355034cbe736cf6 SHA512 523e7273134b68252693ba7a032e7992c72075aebd2bcd895fbd90ad28d76f98b13ea1a7df0b6da1802650782ae977868177f740dc6f0a2eaccb95915c27b318
 DIST pip-24.1.2.gh.tar.gz 9192691 BLAKE2B 9b5a07e9f10b5787d668766423d8b3a9dfcc62564673155b80c7bc95ffe79daafa8788d8141f67c76d4098c21922e62fcb2164f72bf580bbeec136786c48d512 SHA512 222a957030e9c51defa6f741f8e176f2a19bd54f0ef664d2e218d3d2c2b5a335c9b7ce4bd1c804133d6116b3fbf37648453cd85f7a2bcf86a5aeb43e22db4b0f
 DIST pip-24.1.gh.tar.gz 9188658 BLAKE2B 4a43ff0199d811dd30461e376f655a447f3f706a48dd97fe1d0ccf630f558e72209ccd06d98949a1541cd6b2942a816db23ce8aaa7fbbf9aef429502fb91ab92 SHA512 c60ab329fe91202ff64b5f0f90209085fbf8db0f0a05f0703f952ad69e39e2e3edb5dadc006a3f317cdd4ba4fb5abe56dfbd22792249a2d139702eec272186d1
+DIST pip-24.2.gh.tar.gz 9189637 BLAKE2B 6bc7bf69cd3e1edc1898a4476d36b749c037ac10a1614ef3a6bacc0c7debd38de94e0cf6d8a2931b1a7afb2f6f853922fcd62b65d17ac805f22741b7ff6423c6 SHA512 2c44881f62f7b89cedeb0b739409ad67c6144bfdffc347efeb7bcf85aed77bcd7ddd10868d24577fbba0ef84dd752473d6b6dff329b42841939fae2ff2f63d28
 EBUILD pip-24.0.ebuild 4559 BLAKE2B 6f34aa0dcd0c78b53d63c0dd523ec1b397186e8d9efc90781812d94e96138630653a896636931d2095c59065065b9140d104ebb9cf178858de0e5985aca4e05b SHA512 587b9eb40e71ee078d74853dfb0694ae2733fed6f54fb4ce48f410113179f15c55d17efc47e8ad0dc70d704302d731240ba0aad77c40450daecffc522d6f0320
 EBUILD pip-24.1-r1.ebuild 5839 BLAKE2B d70aa1453b8f7394294ca5fdbf3f97c53baf0aee7946f842b638416b0b6a6beb553dff60faf6ba3484684d04d82aca0b823ab6c5645e420b324aaefed13a2505 SHA512 faa9cfec1984eef2d942632b4fc643ff79c668610c5b31ad05f905ae520eaa3f5a4e77674a60b52dedfa88610b5b13113a0c3d4a202420fe1453059f0d9b52a9
 EBUILD pip-24.1.1.ebuild 5869 BLAKE2B 4745e899fdcda51dc08322943d0f7a36dfdfbfeb8226ae50d4c21c29e577f219bed132f4d526ab8fcd88eb6da9d551f9756827b9fdc710762bc4c11e737f55be SHA512 152ddca27aa59e7ccfe7e8f67f9999544209454370d11670fcbf63e4edf46955b97c1156ea04b78cba58e36c9516c383e4ac95dc3f31f67bfaa313f8220d78a5
-EBUILD pip-24.1.2.ebuild 5896 BLAKE2B e92e2b9a0ac53a72d5e4c24a1cc7a230282dddea98f15cade714bb228d2bf6f692d98048a13c62058804d079844f2ef23293bbb57839b9775d87ebb7b520aa24 SHA512 b77bbeef1d79a2f60a71097c3125ae1d08b3644ecc8b117b73a5756f5cd77f3fc24b7bdb1a583e659883bebfa3c36a5afb7bab768b0079687227fcb59aa1bf02
+EBUILD pip-24.1.2.ebuild 5896 BLAKE2B d43a099058e6fb7706db601957b6b2e0e187b14f13188f57818736157f20dcd509376b998e37a7aa32c6ae3ff0efec2658e833b42e21fce98d08f39564659c45 SHA512 81083bcdf4355ebc0e5d4fb80224ca0d660a50223d27e948e1f9235791fb8a6c021c7ffe3046c99e1eb8183e5fb7cd9dc22080b8198aa12362f9edd47ef12f98
 EBUILD pip-24.1.ebuild 4075 BLAKE2B 6cb7c20cfdd759fa1dcc80fa25421db1e0d2e885228a0eec231d4ef138a8ae9c91b418fe4fcb7f7e32a2804b22972bd41ecc025aad4b689f80753d8cacf83f9f SHA512 85f2640255282b964deab13ee3a59ce5856f90459a8271e52726322477cf5f98b632dda49eadf39b1dfc22a2a4740e2191a97515f7503d7484839b5f43d5fe1e
+EBUILD pip-24.2-r1.ebuild 5895 BLAKE2B 45989c4da6769da1a0131bf037fe08d2dd45b80cb78a262bc5f54e240802a39b7c302959642275cb957e83a1ca0c87f1e8c15bd503ebb5e4b3662155848d5133 SHA512 75647e786def50807caca49622f954abd1395154301d3461c2747f1ff2d746e726b1ed0f584a1d125ba6a1d649c90aa2e4dbd84f7bc7540102ec5174a5244ec6
 MISC metadata.xml 392 BLAKE2B 94ea3de1220cb9ca64ae1186597789cc83a54adfe44695932c07dd5065df0e5f9ee5078a495e3a12563b36809d781d8ab86bb6c92c485c023199d92547b74f27 SHA512 603199f6547105f3bb64f4fcaf004e9ef62fa2e0f8ec6eab56078119684b0f5119161e0f164fe02b2cf6dd6b115588c9ef77d727eeb6d138e281f1cb0bcb5de9
diff --git a/dev-python/pip/pip-24.1.2.ebuild b/dev-python/pip/pip-24.1.2.ebuild
index 27a0bac854bf..c54a1a33aa91 100644
--- a/dev-python/pip/pip-24.1.2.ebuild
+++ b/dev-python/pip/pip-24.1.2.ebuild
@@ -26,7 +26,7 @@ LICENSE="MIT"
 # bundled deps
 LICENSE+=" Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MPL-2.0 PSF-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ppc ~ppc64 ~riscv ~sparc x86"
 IUSE="test-rust"
 
 # see src/pip/_vendor/vendor.txt
diff --git a/dev-python/pip/pip-24.2-r1.ebuild b/dev-python/pip/pip-24.2-r1.ebuild
new file mode 100644
index 000000000000..36e18a838629
--- /dev/null
+++ b/dev-python/pip/pip-24.2-r1.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# please bump dev-python/ensurepip-pip along with this package!
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{10..13} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" pypy3 )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="The PyPA recommended tool for installing Python packages"
+HOMEPAGE="
+	https://pip.pypa.io/en/stable/
+	https://pypi.org/project/pip/
+	https://github.com/pypa/pip/
+"
+SRC_URI="
+	https://github.com/pypa/pip/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+# bundled deps
+LICENSE+=" Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MPL-2.0 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test-rust"
+
+# see src/pip/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/cachecontrol-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.8[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.8[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.1[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-hooks-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.32.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-13.7.1[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-69.5.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/truststore-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.12.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/ensurepip-setuptools
+			dev-python/ensurepip-wheel
+			dev-python/freezegun[${PYTHON_USEDEP}]
+			dev-python/pretend[${PYTHON_USEDEP}]
+			dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/scripttest[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+			dev-python/werkzeug[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			test-rust? (
+				dev-python/cryptography[${PYTHON_USEDEP}]
+			)
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/pip-23.1-no-coverage.patch"
+		# prepare to unbundle dependencies
+		"${FILESDIR}/pip-24.1-unbundle.patch"
+	)
+
+	distutils-r1_python_prepare_all
+
+	# unbundle dependencies
+	rm -r src/pip/_vendor || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from pip\._vendor import:import:g' \
+		-e 's:from pip\._vendor\.:from :g' \
+		{} + || die
+
+	if use test; then
+		local wheels=(
+			"${BROOT}"/usr/lib/python/ensurepip/{setuptools,wheel}-*.whl
+		)
+		mkdir tests/data/common_wheels/ || die
+		cp "${wheels[@]}" tests/data/common_wheels/ || die
+	fi
+}
+
+python_compile_all() {
+	# 'pip completion' command embeds full $0 into completion script, which confuses
+	# 'complete' and causes QA warning when running as "${PYTHON} -m pip".
+	# This trick sets correct $0 while still calling just installed pip.
+	local pipcmd='import sys; sys.argv[0] = "pip"; __file__ = ""; from pip._internal.cli.main import main; sys.exit(main())'
+	"${EPYTHON}" -c "${pipcmd}" completion --bash > completion.bash || die
+	"${EPYTHON}" -c "${pipcmd}" completion --zsh > completion.zsh || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return 0
+	fi
+
+	local EPYTEST_DESELECT=(
+		tests/functional/test_inspect.py::test_inspect_basic
+		# Internet
+		tests/functional/test_config_settings.py::test_backend_sees_config_via_sdist
+		tests/functional/test_install.py::test_double_install_fail
+		tests/functional/test_install.py::test_install_sdist_links
+		tests/functional/test_install_config.py::test_prompt_for_keyring_if_needed
+		# broken by system site-packages use
+		tests/functional/test_check.py::test_basic_check_clean
+		tests/functional/test_check.py::test_check_skip_work_dir_pkg
+		tests/functional/test_check.py::test_check_complicated_name_clean
+		tests/functional/test_check.py::test_check_development_versions_are_also_considered
+		tests/functional/test_freeze.py::test_freeze_with_setuptools
+		tests/functional/test_pip_runner_script.py::test_runner_work_in_environments_with_no_pip
+		tests/functional/test_uninstall.py::test_basic_uninstall_distutils
+		tests/unit/test_base_command.py::test_base_command_global_tempdir_cleanup
+		tests/unit/test_base_command.py::test_base_command_local_tempdir_cleanup
+		tests/unit/test_base_command.py::test_base_command_provides_tempdir_helpers
+		# broken by unbundling
+		"tests/functional/test_debug.py::test_debug[vendored library versions:]"
+		tests/functional/test_debug.py::test_debug__library_versions
+		tests/functional/test_python_option.py::test_python_interpreter
+		tests/functional/test_uninstall.py::test_uninstall_non_local_distutils
+	)
+	local EPYTEST_IGNORE=(
+		# requires proxy.py
+		tests/functional/test_proxy.py
+	)
+
+	if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/functional/test_install.py::test_install_sends_client_cert
+			tests/functional/test_install_config.py::test_do_not_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_keyring_if_needed
+		)
+	fi
+
+	local -x PIP_DISABLE_PIP_VERSION_CHECK=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_XDIST=1
+	# rerunfailures because test suite breaks if packages are installed
+	# in parallel
+	epytest -m "not network" -o tmp_path_retention_policy=all \
+		-p rerunfailures --reruns=5
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS.txt docs/html/**/*.rst )
+	distutils-r1_python_install_all
+
+	newbashcomp completion.bash pip
+
+	insinto /usr/share/zsh/site-functions
+	newins completion.zsh _pip
+}