gentoo auto-resync : 30:08:2024 - 12:00:55

2 files changed, 121 insertions, 0 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index 46655e3318fb..cc4c9723455e 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1,5 +1,7 @@
 AUX plotly-5.23.0-numpy-2.patch 3564 BLAKE2B c45b31eaf9a6621780ef8a85b6aed4190bcb26c950554c2bf9c2e8bcf8c158952dfb917b8625bbd61a2a1837a871e9d8a3ae37b387c9408ceeaa655384b11e98 SHA512 deb96bdf408c58edfdba724708e527653939d353ecdeee1b9a8494eee313dc3a2ac21680349b20738b58744fafbaa2e5ac3dde2b6150ed4a1e61407a9222ea4b
 AUX plotly-5.8.0-fix-versioneer-import.patch 541 BLAKE2B 51ff6cbab8d9124243445f758aa4b976b7c26e1d3ce633e943bff133b81c0a7587feeb9d5e98a63f319c6afed8dc06e06fafe765ffd51fec245215c849fb4955 SHA512 db4743e538dddfe66e4c9c766698844af4d09c68188afefe92b6419adfe7cc0b1e9c1266d702d590b0b8dfc14bffbc8f08262ead0bff4dae3b5c71fa1259a4b9
 DIST plotly.py-5.23.0.gh.tar.gz 31606651 BLAKE2B f34d1df464cac49ab834674be8815b97535d8f59e4263d8f68d82f2c2c52976a26b13fe9275f4a90fe0c0848449807dcd8342c0e5309d4b39d61b39cb31d8db5 SHA512 96573bf5952b29a75d2c87029c1041f05d08f4f891d63d5999372d64c211abc5982308dcfbf7590981cd0666ae84ccbee8c9a22e8e2b97571fc8c6a4e634cdbc
+DIST plotly.py-5.24.0.gh.tar.gz 32084853 BLAKE2B 87371902c0f654a16e0d2b97655614b99e05511a298839b244d3147bd2330b70275d1235f4b75eb3bb1dc13289e4d6dab71ec68710d59f1cec467e05e998c609 SHA512 42071af552f666dcc98efe4995a156212971ca92a6320e18861c6e804ab5cd0641c8b772958d3080780aab48e779fc02a13c327c18b36c5077cd137f59f86aff
 EBUILD plotly-5.23.0.ebuild 3259 BLAKE2B b2c27f40284de1ef4c198048fa51827c4d369ea28c63635be36e8ff3654f96ebeda984fe88b1d2b594cd3210fb30b5e3ac2f172e43f50c5a07975dd22af1c153 SHA512 b692b4ba981169be69be3f255d54fcfabcaafcd5f84a9543131001663628923c4d6433b73133f1038869ca1abf7b1a652f663470fab5db8e67b63e6a5122e65b
+EBUILD plotly-5.24.0.ebuild 3312 BLAKE2B f1af97627771591ddd9cf23dfbb302bc4afa1eb37d389f7850242e411829e1df2bc304fa58507b3cdd1a65b668eb72f547ff02b0c032679793b843319ee01db0 SHA512 8d02865e8505ca4dab0d3316d4a3ca637f68b3ae9fd277bf17bcb650112c5b51958d85199dfd6d56b8805132fe12e05c46877eea7bba0138f76a056af087d229
 MISC metadata.xml 627 BLAKE2B 453adb04f4caba9790fe5223635245c8bca7ca5c6dc1930f09537045580b88b5fa1649e47158b13be6cc5cb09b4479a47690e37ef13208b47a95f82d14793a91 SHA512 a5183e9d217d1312e8d383ccb4ade66b92575492b6c8ed8987e3af18e9e456836b62b2d572ce62f9e01aae47b4a2bcbd12f79b4bb6acabfe69c2b63b20315bd3
diff --git a/dev-python/plotly/plotly-5.24.0.ebuild b/dev-python/plotly/plotly-5.24.0.ebuild
new file mode 100644
index 000000000000..1c80d1f50eae
--- /dev/null
+++ b/dev-python/plotly/plotly-5.24.0.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/packages/python/plotly"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		dev-python/scikit-image[${PYTHON_USEDEP}]
+	)
+"
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+distutils_enable_tests pytest
+
+# README ends up a broken symlink
+DOCS=()
+
+python_prepare_all() {
+	local PATCHES=(
+		# https://github.com/plotly/plotly.py/pull/4622
+		"${FILESDIR}/${PN}-5.23.0-numpy-2.patch"
+	)
+
+	distutils-r1_python_prepare_all
+
+	# unbundle versioneer
+	rm versioneer.py || die
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# kaleido not packaged
+		plotly/tests/test_optional/test_kaleido
+
+		# plotly-orca not packaged
+		plotly/tests/test_orca
+	)
+
+	local EPYTEST_DESELECT=(
+		# kaleido not packaged
+		plotly/tests/test_orca/test_to_image.py::test_bytesio
+
+		# fails in non-isolated env
+		test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+		test_init/test_lazy_imports.py::test_lazy_imports
+
+		# Minor matplotlib incompatibility
+		plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+		plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+		# TODO
+		plotly/tests/test_io/test_to_from_plotly_json.py::test_sanitize_json
+
+		# two subtests that require 'vaex' and 'polars' respectively
+		plotly/tests/test_optional/test_px/test_px_input.py::test_build_df_from_vaex_and_polars
+		plotly/tests/test_optional/test_px/test_px_input.py::test_build_df_with_hover_data_from_vaex_and_polars
+
+		# the usual recursion problem
+		plotly/tests/test_optional/test_utils/test_utils.py::test_masked_constants_example
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	mv "${ED}"/{usr/etc,etc} || die
+}