gentoo auto-resync : 28:02:2025 - 19:27:52HEADmaster

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/qtawesome/qtawesome-1.4.0.ebuild b/dev-python/qtawesome/qtawesome-1.4.0.ebuild
new file mode 100644
index 000000000000..6ccf8b9151b2
--- /dev/null
+++ b/dev-python/qtawesome/qtawesome-1.4.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Enables iconic fonts such as Font Awesome in PyQt"
+HOMEPAGE="
+	https://github.com/spyder-ide/qtawesome/
+	https://pypi.org/project/QtAwesome/
+"
+
+LICENSE="MIT"
+# bundled fonts
+# -------------
+# Font Awesome, Elusive Icons: OFL-1.1
+# Phosphor: MIT
+# Material Design Icons, Remix Icon: Apache-2.0
+# Codicons: CC-BY-4.0
+LICENSE+=" Apache-2.0 CC-BY-4.0 MIT OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	media-fonts/fontawesome
+	dev-python/qtpy[gui,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx-rtd-theme
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	nonfatal epytest || die -n "Tests failed with ${EPYTHON}"
+}