gentoo auto-resync : 13:11:2024 - 03:02:42

2 files changed, 130 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index ede8d8e17b11..37b5b1676b37 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,7 +2,9 @@ AUX setuptools-62.4.0-py-compile.patch 3704 BLAKE2B 9a5e70d2556b059be0ef060abd1d
 DIST setuptools-74.1.3.tar.gz 1356471 BLAKE2B c59476710f10aae77f8b466ce2b072966a889b13c3e2e2a9524497ce43893bcd296412f8e0be8a3ccaa9be46b429680c11fe291095a65a185243701fa667be6c SHA512 7892d1ff0a1cd90f6cd367536392bf2933d354eb61d5177a01218b253bc254b51e74c040601adf35aff1652f1e1c6dbffca3cdce3f4fc32b8bd23c36cd885ddc
 DIST setuptools-75.2.0.tar.gz 1350308 BLAKE2B ec4e91f12a76075c26f14c82109258d285840a5ac49a57f3b7e96160ef126e477ba969483d8afc3d35874e14d9d3804f5009d62cb2e1a5245d24d31800d48a4a SHA512 1c508ae3028ae991215b1953398aee5fcf6df0ae2294cc2e31bf8f3c67a306b6cbe2b78e4d855271be8df8a82135fccc8baa05df905fe964d45e5888abf51add
 DIST setuptools-75.3.0.tar.gz 1351577 BLAKE2B 1f3812a3b6dea6df6a8b3bec2d570405075dc3ed386d8e4fec0d37f2a3c39e93149b8f01b6044a7fa85578e8d39151f1fe1b896d09a87cde9574b98641b8d510 SHA512 281f5cce6fd4aa51b3642a6aae3dce29551ccef083994f0bd267367d3f8b1f81c92cb8f858d7d052ebd7197295316918b3d16a58c6986bdf59bc1d32c7b6277a
+DIST setuptools-75.4.0.tar.gz 1336593 BLAKE2B c784244ca3bfe2e0cab48a8debd921532a154bd860b53cf6f3b9fee401f2cebc9befcdabb8a5cb9f3a41744870485380f3172af29ce53e2df185038895813d8e SHA512 8a25106010cda63b28d982f8258eed5dcebd027c1766fff6e3e6d1fec9422723d1da0acc78a05d3c2432edc7dfd8bbe28fdd87226d8ac47d32404ec4d9d1caaf
 EBUILD setuptools-74.1.3-r1.ebuild 4470 BLAKE2B 2d82fe6ef9827cb2e6e4be0df31ba27fc52be1f68e3e1401155048ff4941e88f17a8242baaeceef4968eb8db77a000ec91454de8ff920cacd308f860efac64aa SHA512 6d08c4a600c286ac315ba05d9949c9bda01f84017bd0226b24e2599fea090d1b926c5210ba639849dd841c4ff22f5610cba8e73e702a7e1e663f10c94e659926
 EBUILD setuptools-75.2.0.ebuild 4574 BLAKE2B dc56e81487af010f31d0813d85f2c1ff9a3bb0bac0b791e4fe74fc799ea08d36919ea92afdc2e51d41c7380bc11227d9a216f03815f76e53ae3f2ecad08fc7c9 SHA512 c43a1b1255fd810d59edd29c66d7ad1fb8911c6c4e581d01096c06cd978362964e791b081743a54b6db81847d095b36e047e1dad04c419fa37eb5da1c387ae75
 EBUILD setuptools-75.3.0.ebuild 4577 BLAKE2B 411c734ac9122023af126ed6e9032302394512fcf804a71a8e98676f338712b2c3c9111523331fc1fe630a148b90dbbe6d074fc6194ab8f0d0a02e6063fb3b6f SHA512 70663cd505276549f6a3d627d590b4b6b83d7314dc4f71be9b57e441560dec25be695bb270fa6f3bcd7397ab5e3db6ab35bc920656e690c3fac8738e1e870bef
+EBUILD setuptools-75.4.0.ebuild 4583 BLAKE2B 44454c89580bd4b79a2edb138a787145b783d005f00b581a0e0ce406b92d4f8f5336f830f3c14119a81b818bf240278f9f940a0199c8162ccb86a481dec44f66 SHA512 9513f25796d2135df67d93097edf7a203c91526aa5b508f4cd5deac590d4600f2dbd23fed7d9b1c50a2e5f912e3e1d355458979b5fe9fc2027a9cf969a070db9
 MISC metadata.xml 469 BLAKE2B 4a26769b09a3785586b22db850b7fc5c4818f31c3ace9cc94476d35df05e50edf6721f3c95ec615c3b2efe071ef284a54ea2d53566316ba653f7830bb48f80bf SHA512 dd682c4ad2e59a97094ebdabe4d1063e2319ed05e1fe9d8c2fafe069badb3b4cf8bb6d9f50e09d2128e2a081c1c69827407ac8aed644ebf70eb4ca1bc9a57319
diff --git a/dev-python/setuptools/setuptools-75.4.0.ebuild b/dev-python/setuptools/setuptools-75.4.0.ebuild
new file mode 100644
index 000000000000..8bd616a1e315
--- /dev/null
+++ b/dev-python/setuptools/setuptools-75.4.0.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_13t )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!<dev-python/setuptools-rust-1.8.0
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-4[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2.2[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.44.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+	!<=dev-libs/gobject-introspection-1.76.1-r0
+	!=dev-libs/gobject-introspection-1.78.1-r0
+	!=dev-libs/gobject-introspection-1.80.1-r1
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-test-5.5[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-subprocess[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+#
+# trove-classifiers are optionally used in validation, if they are
+# installed.  Since we really oughtn't block them, let's always enforce
+# the newest version for the time being to avoid errors.
+# https://github.com/pypa/setuptools/issues/4459
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2024.10.16[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}/setuptools-62.4.0-py-compile.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# breaks tests
+	sed -i -e '/--import-mode/d' pytest.ini || die
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# broken by unbundling
+		setuptools/tests/test_setuptools.py::test_wheel_includes_vendored_metadata
+		# fails on normalized metadata, perhaps different dep version?
+		setuptools/tests/test_build_meta.py::TestBuildMetaBackend::test_build_with_pyproject_config
+		# TODO
+		setuptools/tests/test_sdist.py::test_sanity_check_setuptools_own_sdist
+	)
+
+	local EPYTEST_XDIST=1
+	local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
+	epytest -o tmp_path_retention_policy=all \
+		-m "not uses_network" setuptools
+}