gentoo auto-resync : 17:09:2024 - 12:11:34

2 files changed, 130 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 94780daae677..84a81d1485c4 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -3,8 +3,10 @@ DIST setuptools-73.0.1.tar.gz 2526506 BLAKE2B 766453a7f6f3e34bdc63628b8c0321730c
 DIST setuptools-74.1.2.tar.gz 1356467 BLAKE2B bc625e323f94ba9166f2c9747610d71c0ef7ad2a07f6b3e0cedabcbac67bba6d05679a7bce3c3e761807727c10e111801d486c01f3cdb7e22ca4324370c2cfb9 SHA512 581cc51bf70fe378ca8dcdb2cbed6056de4c335c7e997ed126cc707a84c52571dfa0379f34e2f8bebf50ab27f4c20c718dd854f1378e3c6d4cf75a094e57a77c
 DIST setuptools-74.1.3.tar.gz 1356471 BLAKE2B c59476710f10aae77f8b466ce2b072966a889b13c3e2e2a9524497ce43893bcd296412f8e0be8a3ccaa9be46b429680c11fe291095a65a185243701fa667be6c SHA512 7892d1ff0a1cd90f6cd367536392bf2933d354eb61d5177a01218b253bc254b51e74c040601adf35aff1652f1e1c6dbffca3cdce3f4fc32b8bd23c36cd885ddc
 DIST setuptools-75.0.0.tar.gz 1347819 BLAKE2B db2745fecb86a0747acab21371ea0714b2c97694490f3e71bb59a51d05b782af60f044cbb9ad29c4798644cd986119d98592ae857ccfd9b3a3fc98199291568b SHA512 78955967c23450822a154db99f9a4cb5d45bfb2fe42797ea39c784e23004172d75fbbba6a6b89fa8c0d63c6b9ffb45e791e48b3d8201cfffc84bd75769cd02ef
+DIST setuptools-75.1.0.tar.gz 1348057 BLAKE2B a749260ee2b3162ce102204d89b00bcb6d69c84a7785dee443467946b4fe275f080917b204e65d8abd9e629e5ebef311825a1a472b3e5a09815373ab172b1ca4 SHA512 5003e81c7988dd522cfba233ac643ade9a1ff074a13182a81da7fe3f40565b97dd2696c96b8a0694fcd3417e527e2cf6d6ea5e21d29ff927c1ab5916a2607239
 EBUILD setuptools-73.0.1.ebuild 4358 BLAKE2B 2fa89835b4e7a29756cf52387f2b1ab043a8712d0679349ec32784e6d15819d776174dda8e34fa9986d610040fe63e7dda7e2092f4835fb033223d9669322950 SHA512 f6fd13e19bfd3fb605a0fb0bb5808192716c01382d720c4fe1d7f77abec2e61f258da6d4776f9f8f66c5d557167492b285b68fc2f54d4a313918d94fc157e4e4
 EBUILD setuptools-74.1.2.ebuild 4468 BLAKE2B 4fb18def603a5d09ae3e52570624f26b5f5613983154a6451b881ebd076d0b21c10dabaca170de6d0d1dc2baa29df6cf5d9f6b82ee12d7b9c3243b2a68624fba SHA512 46401be8b5bcfb31e1b56ab28aaa4a457903221e4151fc54d66c39061773c9a0020fdb7fbf1f67aaf279a68a0eb56a0a9706277047a89045866e1678121195be
 EBUILD setuptools-74.1.3.ebuild 4468 BLAKE2B 4fb18def603a5d09ae3e52570624f26b5f5613983154a6451b881ebd076d0b21c10dabaca170de6d0d1dc2baa29df6cf5d9f6b82ee12d7b9c3243b2a68624fba SHA512 46401be8b5bcfb31e1b56ab28aaa4a457903221e4151fc54d66c39061773c9a0020fdb7fbf1f67aaf279a68a0eb56a0a9706277047a89045866e1678121195be
 EBUILD setuptools-75.0.0.ebuild 4564 BLAKE2B 49f1f3b6674ce61b4e8cb5e33eab79dad2e48d8c18c7900152ba613bcd82f0af70ac543825d4f5e9f9034954d0a9658c7f8e12c165d542cf5ee6fe5c272de890 SHA512 92acd26cf58c7ebf199411d146bb6683da60f7cd096ce8cf723f258ca7a2cf8f0f6bd2038a1e57a65c566a6263235ea46140492e0959bb50491002306d6bdce2
+EBUILD setuptools-75.1.0.ebuild 4564 BLAKE2B 49f1f3b6674ce61b4e8cb5e33eab79dad2e48d8c18c7900152ba613bcd82f0af70ac543825d4f5e9f9034954d0a9658c7f8e12c165d542cf5ee6fe5c272de890 SHA512 92acd26cf58c7ebf199411d146bb6683da60f7cd096ce8cf723f258ca7a2cf8f0f6bd2038a1e57a65c566a6263235ea46140492e0959bb50491002306d6bdce2
 MISC metadata.xml 469 BLAKE2B 4a26769b09a3785586b22db850b7fc5c4818f31c3ace9cc94476d35df05e50edf6721f3c95ec615c3b2efe071ef284a54ea2d53566316ba653f7830bb48f80bf SHA512 dd682c4ad2e59a97094ebdabe4d1063e2319ed05e1fe9d8c2fafe069badb3b4cf8bb6d9f50e09d2128e2a081c1c69827407ac8aed644ebf70eb4ca1bc9a57319
diff --git a/dev-python/setuptools/setuptools-75.1.0.ebuild b/dev-python/setuptools/setuptools-75.1.0.ebuild
new file mode 100644
index 000000000000..3b8c9465b6c3
--- /dev/null
+++ b/dev-python/setuptools/setuptools-75.1.0.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!!<dev-python/setuptools-rust-1.8.0
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.44.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+	!!<=dev-libs/gobject-introspection-1.76.1-r0
+	!!=dev-libs/gobject-introspection-1.78.1-r0
+	!!=dev-libs/gobject-introspection-1.80.1-r1
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/jaraco-test[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-subprocess[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+#
+# trove-classifiers are optionally used in validation, if they are
+# installed.  Since we really oughtn't block them, let's always enforce
+# the newest version for the time being to avoid errors.
+# https://github.com/pypa/setuptools/issues/4459
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2024.7.2[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}/setuptools-62.4.0-py-compile.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# breaks tests
+	sed -i -e '/--import-mode/d' pytest.ini || die
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# broken by unbundling
+		setuptools/tests/test_setuptools.py::test_wheel_includes_vendored_metadata
+		# fails on normalized metadata, perhaps different dep version?
+		setuptools/tests/test_build_meta.py::TestBuildMetaBackend::test_build_with_pyproject_config
+		# TODO
+		setuptools/tests/test_sdist.py::test_sanity_check_setuptools_own_sdist
+	)
+
+	local EPYTEST_XDIST=1
+	local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
+	epytest -o tmp_path_retention_policy=all \
+		-m "not uses_network" setuptools
+}