gentoo auto-resync : 28:01:2023 - 02:49:59

2 files changed, 0 insertions, 198 deletions

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 4ca41d44e227..f5937b64b652 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,9 +1,7 @@
 AUX spyder-5.0.0-build.patch 1147 BLAKE2B 68e62f6bd7a021d82f1da8d86c16e2289faac7f760f9bb5dc975053c7f8bb409c79b90eeaf06c5121ca5833442b61929cc640e4f25e6cc27f6118f0fa8f27b5e SHA512 e88cbbeca42ac2720f4e0888df9432d912d3907af267d3fe6a5e658d18d1242c998a70dee88fa0efe9edfcf87a46a40cf75685037d75fce1d596b708acc32096
 AUX spyder-5.2.0-doc-theme-renamed.patch 356 BLAKE2B 666ba289498026ab0679776b8af8f6efe7561a9a736ff19b32eaefcac87d142a55a055556c09f94373869711e81a35ef90832fbfe68acc6cee0f2023742de0be SHA512 396944e6f242bf3b6a27ac9d47f0cc07fd99a55c50f174dbee2fccd1f0b3edf355347bf6291943c3003f55996304d96ce2d2fe45ae7c4291e8425bff73a3a861
 AUX spyder-5.4.0-unpin-qdarkstyle.patch 835 BLAKE2B 75ce544c6932d090dfee0ae06e37a960462943c93f36b235a9261eadc3105e0357ef2ee28898dd896b2c2e0d6a3eb25e36f4e77ab7439bd942e09fa1447a8ab1 SHA512 a6fa1cedf079dcf1c9f8c0c33b4be2de911ceff526e73412ee95a8b0806baf5dbaafc06ad5f49c91154106c76a85281f83ef9890aaa2c4778e8c3260eb0a53b8
-DIST spyder-5.4.1.gh.tar.gz 24518322 BLAKE2B d19c28abf17872163d43e81d1a34e2f09cfb6d47738609352b0252de3eafbd63992e57059e965e5e9f668b44ba594d2a240130d9f10112bdea3f1d97568ca081 SHA512 f8dc629552957d4ddcbe849388a6b5b53acd17248ea247fd3c27e0a6b93c411102b12f427f9f41824709bceda8687f09efa0310ae4ce798ae9ebc389bbb8253c
 DIST spyder-5.4.2.gh.tar.gz 24523453 BLAKE2B 9ec3652fc60c483b96f287ad39f3280e963b8bb24a6e1326f5248373ee53465b67c5660e42b4f7d876498a8ee1652fa058b038386a3dd788d46452ba1475760c SHA512 e3650cd43d14d2ce7e6f90557904d6ac1e5db5f7846e87e8a1fd8173cdef97cdee485250caf00768482611b8318eaba60259efcaccf41f0308e888ac85eeb88d
 DIST spyder-docs-3ae8705d3eba8fc30d4600d6d1e29ce0da8cd0c6.gh.tar.gz 95448945 BLAKE2B 5e130bff9fbca71e61ed96236a6964e8f34602efbb930dbc928a22eec59ebb2d2bee39f679c27dbbf88686345e5db5894f931e7ab95a3e007444b17c4e021176 SHA512 a6ebe6b6ff057616951c0075ba7c8039dc3a304b6e1bbbb40f80bb54018cee374df230e491493f18070273dded2942e14bfecc9439d33ae1bc3edd5b47067d77
-EBUILD spyder-5.4.1.ebuild 7623 BLAKE2B 079e1b2e466df248a42259e9210e86bd52b30f756e37d254c159011df6f01c79f16b99c703c5fef490db1c53bff09e72b2511789047101ed0d6a305bfc30a322 SHA512 3320610793fc3095a3f0816b506903b7b27832771a234d034f0940c7f891c85426900597d79121f1fc9778c57877bbb6453130780f9d53c55b0252f51a64c5c4
 EBUILD spyder-5.4.2.ebuild 7623 BLAKE2B 17d6ef262a9d12ed42484db4b8233846bccb231f0b9fdb1735abf38c351cdad02f76ad4572943a21601b356334776f1ae2ef45cf5d117cab9b9d79e5a8c55777 SHA512 d0df13edc7c71c91db54e9beff7a8e47dd6141f0cafdf4c28b90efd35ebbb670fd5b92146faf4f4cfc14c08e2682b75ea9bb874ea1ada5eed5ceb527f58b9ed2
 MISC metadata.xml 1251 BLAKE2B 81f007eda89ddc66841771a949f76da6f015b49bfbf27b47a7557ab70f1241087f06a5c6675ea8da6aa871937cd705aea888989b468ac11d33420cbe34a27f27 SHA512 24977ed6053ad254748ba4c368bed7f8428d1e5928b586f57e48c01733934894fb1f94df077a71fcd7a00e891e24b776b9e57279f90c2f94728f709a94a90121
diff --git a/dev-python/spyder/spyder-5.4.1.ebuild b/dev-python/spyder/spyder-5.4.1.ebuild
deleted file mode 100644
index e4c9f318be91..000000000000
--- a/dev-python/spyder/spyder-5.4.1.ebuild
+++ /dev/null
@@ -1,196 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..11} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit optfeature xdg distutils-r1
-
-# Commit of documentation to fetch
-DOCS_PV="3ae8705d3eba8fc30d4600d6d1e29ce0da8cd0c6"
-
-DESCRIPTION="The Scientific Python Development Environment"
-HOMEPAGE="
-	https://www.spyder-ide.org/
-	https://github.com/spyder-ide/spyder/
-	https://pypi.org/project/spyder/
-"
-SRC_URI="
-	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
-	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-# The test suite often hangs or does not work. RESTRICTing because IMO it is
-# not worth the several hours I would have to spend every single version bump
-# checking which tests do and do not work.
-RESTRICT="test"
-
-RDEPEND="
-	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
-	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
-	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
-	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
-	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
-	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
-	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
-	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/pylint-venv-2.1.1[${PYTHON_USEDEP}]
-	>=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
-	>=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
-	>=dev-python/qtawesome-1.2.1[${PYTHON_USEDEP}]
-	>=dev-python/qtconsole-5.4.0[${PYTHON_USEDEP}]
-	<dev-python/qtconsole-5.5.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},svg,webengine]
-	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
-	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
-	>=dev-python/spyder-kernels-2.4.1[${PYTHON_USEDEP}]
-	<dev-python/spyder-kernels-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
-	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
-"
-
-# Tests are broken anyway, so lets comment this out so we can enable py3.11
-# BDEPEND="
-# 	test? (
-# 		dev-python/cython[${PYTHON_USEDEP}]
-# 		dev-python/flaky[${PYTHON_USEDEP}]
-# 		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
-# 		dev-python/pandas[${PYTHON_USEDEP}]
-# 		dev-python/pillow[${PYTHON_USEDEP}]
-# 		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-# 		dev-python/pytest-mock[${PYTHON_USEDEP}]
-# 		dev-python/pytest-ordering[${PYTHON_USEDEP}]
-# 		dev-python/pytest-qt[${PYTHON_USEDEP}]
-# 		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
-# 		dev-python/pyyaml[${PYTHON_USEDEP}]
-# 		dev-python/scipy[${PYTHON_USEDEP}]
-# 		dev-python/sympy[${PYTHON_USEDEP}]
-# 	)"
-
-# Based on the courtesy of Arfrever
-# This patch removes a call to update-desktop-database during build
-# This fails because access is denied to this command during build
-PATCHES=(
-	"${FILESDIR}/${PN}-5.0.0-build.patch"
-	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
-	"${FILESDIR}/${PN}-5.4.0-unpin-qdarkstyle.patch"
-)
-
-DOCS=(
-	"AUTHORS.txt"
-	"Announcements.md"
-	"CHANGELOG.md"
-	"CODE_OF_CONDUCT.md"
-	"CONTRIBUTING.md"
-	"NOTICE.txt"
-	"README.md"
-	"RELEASE.md"
-)
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs/doc \
-	dev-python/sphinx-panels \
-	dev-python/pydata-sphinx-theme \
-	dev-python/sphinx-multiversion
-
-python_prepare_all() {
-	# move docs into workdir
-	mv ../spyder-docs-${DOCS_PV}* docs || die
-
-	# these dependencies are packaged separately:
-	#    dev-python/spyder-kernels,
-	#    dev-python/python-lsp-server,
-	#    dev-python/qdarkstyle
-	rm -r external-deps/* || die
-	# runs against things packaged in external-deps dir
-	rm conftest.py || die
-
-	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
-	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
-	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
-	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
-	# Do not depend on ipython, this dependency is carried in spyder-kernels
-	# The explicit version requirements only make things more complicated, if e.g.
-	# pyls-spyder gains compatibility with a newer version of python-lsp-server
-	# in a new release it will take time for this information to propagate into
-	# the next spyder release. So just remove the dependency and let the other
-	# ebuilds handle the version requirements to speed things up and prevent
-	# issues such as Bug 803269.
-	sed -i \
-		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
-		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
-		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
-		-e "/'parso[ 0-9<=>.,]*',/d" \
-		-e "/'jedi[ 0-9<=>.,]*',/d" \
-		-e "/'pylint[ 0-9<=>.,]*',/d" \
-		-e "/'ipython[ 0-9<=>.,]*',/d" \
-			setup.py || die
-	sed -i \
-		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
-		-e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
-			spyder/dependencies.py || die
-
-	# do not check deps, fails because we removed dependencies above
-	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
-		spyder/tests/test_dependencies_in_sync.py || die
-
-	# can't check for update, need network
-	rm spyder/workers/tests/test_update.py || die
-
-	# skip online test
-	rm spyder/widgets/github/tests/test_github_backend.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-# Calling pytest directly makes the tests freeze after completing even if successful
-# Exit code is nonzero even upon success, so can't add || die here test results
-# should be checked for success manually
-python_test() {
-	"${EPYTHON}" runtests.py
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
-	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
-	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
-	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
-	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
-	optfeature "Run Cython files in the IPython console" dev-python/cython
-	optfeature "The hdf5/h5py plugin" dev-python/h5py
-	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
-	optfeature "Vim key bindings" dev-python/spyder-vim
-	optfeature "Unittest support" dev-python/spyder-unittest
-	optfeature "System terminal inside spyder" dev-python/spyder-terminal
-	optfeature "Jupyter notebook support" dev-python/spyder-notebook
-	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
-	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
-	# spyder-reports not yet updated to >=spyder-4.0.0
-	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
-	# Plugins with no release yet:
-	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
-	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
-}