gentoo auto-resync : 23:03:2024 - 13:01:09

2 files changed, 89 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 1c5846cc943e..1a61b6605edc 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,5 @@
 DIST tox-4.14.1.tar.gz 178268 BLAKE2B e30e2bfbf3ee70ff217dd482abfddfe271c5158ffda3639ed6cd400e75b2c8bdf494b0ca73039ea1e9eaafa0f8431b98250981c659ae68e92968865d0b2ef8d4 SHA512 6ad0f82fa7c9599ade526179ee6bd417bc2309b1b5cb002dac7f48032b8889eda9164f0d05724c8846ddf887029e55d1dab7ae220722fd02b42f89421bc43c52
+DIST tox-4.14.2.tar.gz 178515 BLAKE2B 812a4e0ffe218c5799a5bdf76cc5f1f99f60c7de464953349283e3951c91aded247941cb173bfdff670c9c079b9efb3645220ff7126b7e0cf341071d561a375b SHA512 45bbd3f8d00eee05158452295230321947ec16a8bfff43e84ea9825d514976526f3889709255ed042cfb7a7ebfed020707cfc2d25b69ce90c148f4472092350d
 EBUILD tox-4.14.1.ebuild 2799 BLAKE2B ad0a398168b082140f4d427b00440d4035fd6cfee4cebb862ca5c04fa4828a46b81580dbab259332c03a555a16a521cd143cc72fd6064074143d98fc5374dd40 SHA512 b305b5c5d41811ec6fb7040f51fec39fd9bf3aceb63b723fd09c4ab0fc1305db2fa5301812c4076968bc83876a48a8ecffbab01b6c970f25678b525a486f1fff
+EBUILD tox-4.14.2.ebuild 2807 BLAKE2B 4414565dedce0995d86e380eb8750ab2605dbe1caedc9d79e3a1909f49e5ebbcce4658dfb70adff4c92f829f6f5c1980d4f8c9ac9090856349532baea06095f7 SHA512 24e201053d9ddd01c6b08ba954bbf158bd66f2e115bb7aff2909b7f84b01be129d806e5138670d27f2bc9d36046b583bdd29449cc17d5dd0a76a922a80f3e657
 MISC metadata.xml 382 BLAKE2B 7c0704c5c187ce4a7972fe0372b23c5537a81a8d62fd83436d9558a61761f10764adb5a4d5f6795f0dd1fe905afa604c0be77fe1d48d291847f6ae65dc1b032c SHA512 9d0ced4df9352a81034a50d5766a01534ae8fa889985d99cc9e2a8d0889e31c6c11550677d9a5a74e2aab57c320192ce3a42708a6d23b0419ee34a6054398344
diff --git a/dev-python/tox/tox-4.14.2.ebuild b/dev-python/tox/tox-4.14.2.ebuild
new file mode 100644
index 000000000000..e80094cd0dd9
--- /dev/null
+++ b/dev-python/tox/tox-4.14.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}