gentoo auto-resync : 23:01:2025 - 06:45:02

2 files changed, 100 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 9667b010e99f..fc3f6f14b608 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,5 @@
 DIST tox-4.23.2.tar.gz 189998 BLAKE2B 776b653388a4b0578b5e5fd7957e97e1b3591d6239a23fe232238a7ce64a9adc641bbd5d3d4585ebb094da7c487da2b0875a466d62e27a9686317cc38a9b2491 SHA512 5008964ebed3c94a6ad5f0985150c7bf73fd3996b91171b16323d195bf0288102aac0dc38848bd4c63e5c5678ab1a82c170579139eda97132a4555eb11d381a0
+DIST tox-4.24.1.tar.gz 194742 BLAKE2B d0f383b42c9c0e05ef08598ec32a6096c6e8dcb49108e0ecd755fabe613dee4c1b5d3d687841ac96478f7a1bde781ec83fda5f757982f459bad31a5b1bb7d249 SHA512 8d7a3cd9c6140463dd2d2e1df7845c676f750ca23c0a9d528ee4fc7923bcadea94cfc0e7a1d70bd436d867be5f2edddd1576569777f2c15a0e11768cd932b6dd
 EBUILD tox-4.23.2.ebuild 3055 BLAKE2B 813a197827b6b650bfe6a9f496187a5b077f6f7484dbc7f84ceb1ee6f2e7980618e95f359de6c3061e2da3c360ec14c160794eee6039b998a5841294862cbdf1 SHA512 c2ed003c124324fffed498d969bb1bea231c16f9ff004f2c073cacbfbb49b677f975a3fd4aefd756dd70831663a2d3567e577cb5cc2974560efaa75a80fe05f0
+EBUILD tox-4.24.1.ebuild 3063 BLAKE2B e4c4193f67fa8dcd3bd9e4ae6119bfa64fb372e1feb6a9a542770d53313d9ef2ceef17591b7a268f2833e4dceb4df0aa84ad8dae9a6812cb38e8f44ead89cf89 SHA512 70a873f40d1f217fe7438aef2f8150619438a82a58f24c3ae852d288a910586796b3dab8eecab487ec7a7d61f9d9db000747049538c25cb3ca09b7b9c7da0264
 MISC metadata.xml 382 BLAKE2B 7c0704c5c187ce4a7972fe0372b23c5537a81a8d62fd83436d9558a61761f10764adb5a4d5f6795f0dd1fe905afa604c0be77fe1d48d291847f6ae65dc1b032c SHA512 9d0ced4df9352a81034a50d5766a01534ae8fa889985d99cc9e2a8d0889e31c6c11550677d9a5a74e2aab57c320192ce3a42708a6d23b0419ee34a6054398344
diff --git a/dev-python/tox/tox-4.24.1.ebuild b/dev-python/tox/tox-4.24.1.ebuild
new file mode 100644
index 000000000000..73a9b829f156
--- /dev/null
+++ b/dev-python/tox/tox-4.24.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# https://github.com/tox-dev/tox/issues/3290
+				'tests/config/loader/test_str_convert.py::test_str_convert_ok_py39[1,2-value1-Optional]'
+			)
+			;;
+	esac
+
+	epytest
+}