gentoo resync : 14.07.2018

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/traitlets/traitlets-4.3.2.ebuild b/dev-python/traitlets/traitlets-4.3.2.ebuild
new file mode 100644
index 000000000000..51bc865fd59b
--- /dev/null
+++ b/dev-python/traitlets/traitlets-4.3.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="A configuration system for Python applications"
+HOMEPAGE="https://github.com/ipython/traitlets"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc ppc64 x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' 'python2*')
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	"
+DEPEND="
+	doc? (
+		dev-python/ipython_genutils[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' 'python2*')
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	py.test --cov traitlets -v traitlets || die
+}