gentoo auto-resync : 17:02:2024 - 11:37:14

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-ruby/async/async-2.8.1.ebuild b/dev-ruby/async/async-2.8.1.ebuild
new file mode 100644
index 000000000000..6a5daa5e4abb
--- /dev/null
+++ b/dev-ruby/async/async-2.8.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_RECIPE_TEST="sus"
+RUBY_FAKEGEM_EXTRADOC="readme.md"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A concurrency framework for Ruby"
+HOMEPAGE="https://github.com/socketry/async"
+SRC_URI="https://github.com/socketry/async/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+ruby_add_rdepend "
+	>=dev-ruby/console-1.10:1
+	dev-ruby/fiber-annotation
+	dev-ruby/io-event:1
+	>=dev-ruby/timers-4.1:4
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/benchmark-ips
+	dev-ruby/sus-fixtures-async
+)"
+
+all_ruby_prepare() {
+	sed -i -E 's/require_relative "(.+)"/require File.expand_path("\1")/g' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# network tests
+	rm test/net/http.rb \
+		test/async/scheduler/address.rb \
+		test/async/scheduler/io.rb || die
+
+	sed -i -e '/covered/Id' config/sus.rb || die
+}