gentoo resync : 07.01.2022

2 files changed, 133 insertions, 0 deletions

diff --git a/dev-util/bcc/Manifest b/dev-util/bcc/Manifest
index fb672189c749..e2d4aace7085 100644
--- a/dev-util/bcc/Manifest
+++ b/dev-util/bcc/Manifest
@@ -7,4 +7,5 @@ DIST bcc-0.23.0.tar.gz 5254103 BLAKE2B 011559f081dd8f95b45b64e347ed191f585f6f5e3
 EBUILD bcc-0.22.0-r1.ebuild 2502 BLAKE2B 4b48547c387bcf109adf746eb57eb04d93c41c6116b481beb9654dfaf82470ec34f5998cd9da0badbc308d4b0409ee7efcc4b2f1874265e5f12ca22fda4e9fbd SHA512 44f531b55f2a27be716276bf646ae2652b7e55134636c0c229fb1d327332842e8ec7211a8a9a4402e2362e17574e6fcbc375d2e0697c96250f35f5b02f554bee
 EBUILD bcc-0.22.0.ebuild 2533 BLAKE2B 948441d97a61b7ef0925bc6c03c130ebb56d25ada7be353bd087efaf8d37423c2b9ea407b93efffa963cd09c999e941f9f24efa20c863f07f3dc8b8b9a7084f8 SHA512 180d12f060eda41a33e57539f22eb7334e116a7d3227a2bc041e897213f19344ccb499b5d9e7ec4d455aac66e896ff88d989c866a727aad8ba304dc9dd4c4a29
 EBUILD bcc-0.23.0-r3.ebuild 2969 BLAKE2B 803465e0955b7e896c1baf05d4eed95879439407b248df17e738a61ec1b863f400166113ab7ff65fab0c58ebcd5667cc8b7683e939ee675578a89a8393a8da3f SHA512 309fc7d9c8e710bc7a2311b513352225a13049bc93abf6fa7b641c3b474c8b298c5275222eebc9aedb54fd70057a165ecf245b9847355814b4c64d33d4e9089b
+EBUILD bcc-0.23.0-r4.ebuild 3069 BLAKE2B 4317e7c2ba6be3721f07296b5dc7f877ef3394f236b056ea39f6e10a9a9705f59f6173401299cfca0b5c2cdc6a321caac1b601572433d7c9b02277b2b7f7bbe2 SHA512 4f6f09c1cab99e29fdc3985e273d719e2455d3c4bd30a1793aec6329683ffb3fe931ca9c98516960b3c48ebb441b2da23edda1cb0649637e24ee3d8f496bbc30
 MISC metadata.xml 501 BLAKE2B b958c89640d4cfe0cd5951fbfe65394b84a606c2ac4e73893b46fb950ce7a53f9a9623636bb8f3926c0637539c1aed3107cbf1e6aa52fc0d8a9b948977fab747 SHA512 32e576ce7431409c9c3a69f3ac1d5f757b6ec9807fa86d38a93db02721b0e10771dea786c646513f952fc6603e64df2eefa5797ef2103c55a9b1be60bee522b9
diff --git a/dev-util/bcc/bcc-0.23.0-r4.ebuild b/dev-util/bcc/bcc-0.23.0-r4.ebuild
new file mode 100644
index 000000000000..4f45cf6e2a90
--- /dev/null
+++ b/dev-util/bcc/bcc-0.23.0-r4.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{7..10} )
+LLVM_MAX_SLOT=13
+
+inherit cmake eapi8-dosym linux-info llvm lua-single python-r1 toolchain-funcs
+
+DESCRIPTION="Tools for BPF-based Linux IO analysis, networking, monitoring, and more"
+HOMEPAGE="https://iovisor.github.io/bcc/"
+SRC_URI="https://github.com/iovisor/bcc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+lua test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	lua? ( ${LUA_REQUIRED_USE} )"
+# tests need root access
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-libs/elfutils-0.166:=
+	>=dev-libs/libbpf-0.5.0:=[static-libs(-)]
+	sys-kernel/linux-headers
+	<sys-devel/clang-$((${LLVM_MAX_SLOT} + 1)):=
+	<sys-devel/llvm-$((${LLVM_MAX_SLOT} + 1)):=[llvm_targets_BPF(+)]
+	${PYTHON_DEPS}
+	lua? ( ${LUA_DEPS} )
+"
+DEPEND="${RDEPEND}
+	test? (
+		|| (
+			net-misc/iputils[arping]
+			net-analyzer/arping
+		)
+		net-analyzer/netperf
+		net-misc/iperf:*
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/bcc-0.9.0-no-luajit-automagic-dep.patch"
+	"${FILESDIR}/bcc-0.14.0-cmakelists.patch"
+	"${FILESDIR}/bcc-0.23.0-man-compress.patch"
+)
+
+pkg_pretend() {
+	local CONFIG_CHECK="~BPF ~BPF_SYSCALL ~NET_CLS_BPF ~NET_ACT_BPF
+		~HAVE_EBPF_JIT ~BPF_EVENTS ~DEBUG_INFO ~FUNCTION_TRACER ~KALLSYMS_ALL
+		~KPROBES"
+
+	check_extra_config
+}
+
+pkg_setup() {
+	llvm_pkg_setup
+	python_setup
+}
+
+src_prepare() {
+	local bpf_link_path
+
+	# this avoids bundling
+	bpf_link_path="$(realpath --relative-to="${S}/src/cc/libbpf" /usr/include/bpf)" || die
+	ln -sfn "${bpf_link_path}" src/cc/libbpf/include || die
+
+	# bug 811288
+	local script scriptname
+	for script in $(find tools/old -type f -name "*.py" || die); do
+		scriptname=$(basename ${script} || die)
+		mv ${script} tools/old/old-${scriptname} || die
+	done
+
+	cmake_src_prepare
+}
+
+python_add_impl() {
+	bcc_python_impls+="${EPYTHON};"
+}
+
+src_configure() {
+	local bcc_python_impls
+	python_foreach_impl python_add_impl
+
+	local -a mycmakeargs=(
+		-DREVISION=${PV%%_*}
+		-DENABLE_LLVM_SHARED=ON
+		-DCMAKE_USE_LIBBPF_PACKAGE=ON
+		-DLIBBPF_INCLUDE_DIRS="$($(tc-getPKG_CONFIG) --cflags-only-I libbpf | sed 's:-I::g')"
+		-DKERNEL_INCLUDE_DIRS="${KERNEL_DIR}"
+		-DPYTHON_CMD="${bcc_python_impls%;}"
+		-Wno-dev
+	)
+	if use lua && use lua_single_target_luajit; then
+		mycmakeargs+=( -DWITH_LUAJIT=1 )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	python_replicate_script $(grep -Flr '#!/usr/bin/python' "${ED}/usr/share/bcc/tools")
+	python_foreach_impl python_optimize
+
+	newenvd "${FILESDIR}"/60bcc.env 60bcc.env
+	local -A rename_tools=(
+		[trace]=1
+	)
+
+	local tool name
+	for tool in "${ED}"/usr/share/bcc/tools/*; do
+		[[ ! -x ${tool} && ! -L ${tool} || -d ${tool} ]] && continue
+		name=${tool##*/}
+		[[ -n ${rename_tools[${tool##*/}]} ]] && name=bcc-${tool}
+		dosym8 -r "${tool#${ED}}" /usr/sbin/${name}
+	done
+
+	docompress /usr/share/${PN}/man
+
+	newenvd - "70${P}" <<-_EOF_
+		MANPATH="${EPREFIX}/usr/share/${PN}/man"
+	_EOF_
+}