reinit the tree, so we can have metadata

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-util/dialog/dialog-1.3.20170509.ebuild b/dev-util/dialog/dialog-1.3.20170509.ebuild
new file mode 100644
index 000000000000..7e7ae2ee659f
--- /dev/null
+++ b/dev-util/dialog/dialog-1.3.20170509.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils multilib versionator
+
+MY_P="${PN}-$(replace_version_separator 2 '-')"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
+SRC_URI="ftp://invisible-island.net/${PN}/${MY_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0/14"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.2-r5:=[unicode?]
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	!minimal? ( sys-devel/libtool )
+	!<=sys-freebsd/freebsd-contrib-8.9999
+"
+
+src_prepare() {
+	default
+	sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
+	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-rpath-hack \
+		$(use_enable nls) \
+		$(use_with !minimal libtool) \
+		--with-libtool-opts=$(usex static-libs '' '-shared') \
+		--with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+	use minimal && default || emake DESTDIR="${D}" install-full
+
+	use examples && dodoc -r samples
+
+	dodoc CHANGES README
+
+	prune_libtool_files
+}