gentoo resync : 17.07.2021

2 files changed, 115 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 2ece204ea9db..2d87ddfe6de4 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,5 @@
 DIST diffoscope-177.tar.gz 1590984 BLAKE2B 94daf9528c8fd0ad6ed89bdbee7b21352bf33dcef2ae7e526ea3b1036d92b6fecefcb0da46b7eedf7af1c8bd7995e73b8f0a5104c02f4db534f7bcc465c803aa SHA512 674a5cc364927437a79420b0965eb6958bd09df58a1238ea4d953bb2bc0fbdde75e42817370dd3cdab0bcc59551e1cff70db72298087af551d5dfaee57995811
+DIST diffoscope-178.tar.gz 1600094 BLAKE2B b40e45748be56e49736a826decfb3a8c3ebd91983755719f2665733ceb6ec4e860265c33b5a3c15bc501abe4efdbecbdf177431bbbc79f1ad758c7deef83e1ae SHA512 706c95f5c04cfe081fed7e3e5ed73579949c948b15eaf0f984fc7d406b74007859f7946c44e4ca13e1210b105ed65ea68fd1f03452a50f161ed27f996f4f2540
 EBUILD diffoscope-177-r1.ebuild 3327 BLAKE2B 5a02d7069b31bd8db1f2f590c9825da2acfe7ce7c37e49a184f1add658ad415c4c008e959926ea470d4e0f1f3247e8ffe0613148e292c345eceba1bcb53d7082 SHA512 d1cdef68e7565fd3635d3cacf2c5617acf66dd1e7fb53c3fd72fd0bd7c9d6b48f167c83d385fcb3f38c0efd5a60b053a1fc3dc91b0876a3f6065cb168f416053
+EBUILD diffoscope-178.ebuild 3328 BLAKE2B 7711971921a72b58027c472d38f78cfcc3e493ec5c7ce6de6fd75d8194c3858a496b647e77d8b8e89cba86177c006619e9a9b66501aa14cf7c02533a54672821 SHA512 d7f3ec25d7831bf5cb38c4fdee047e246965dbbe135509c932af77edbaab29384342cd6ff2f7efb1f0aa176d6cde6f752696a60d420bfa70e03cbaab6c7f468d
 MISC metadata.xml 2077 BLAKE2B 2f4d188accf1f75c139a388f564ef5130ea8e74e403072871e4b73b848eaf405076bae7190565f374c193cb4f3fd0be16e3c781ac73df1d1cfb36101142b59eb SHA512 683e181724871d636610c7cfa93c714ceddba7e95b80fda8837e04b396f63049307b23b0471cfc19c46de5bd8b6f7bc868412f8f1c817933ac9507e7280b2272
diff --git a/dev-util/diffoscope/diffoscope-178.ebuild b/dev-util/diffoscope/diffoscope-178.ebuild
new file mode 100644
index 000000000000..b89f0d3a344a
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-178.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/docx2txt
+		media-libs/libcaca
+	)
+"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local exclude=(
+		# test seems to use different tarball
+		tests/test_presenters.py::test_text_proper_indentation
+
+		# needs triage
+		tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+		# needs triage
+		tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+		# img2txt based failures, bug #797688
+		tests/comparators/test_ico_image.py::test_diff
+		tests/comparators/test_ico_image.py::test_diff_meta
+		tests/comparators/test_ico_image.py::test_diff_meta2
+		tests/comparators/test_ico_image.py::test_has_visuals
+		tests/comparators/test_jpeg_image.py::test_diff
+		tests/comparators/test_jpeg_image.py::test_compare_non_existing
+		tests/comparators/test_jpeg_image.py::test_diff_meta
+		tests/comparators/test_jpeg_image.py::test_has_visuals
+
+		# docx2txt based falures, bug #797688
+		tests/comparators/test_docx.py::test_diff
+	)
+	epytest ${exclude[@]/#/--deselect }
+}