gentoo resync : 13.06.2020

3 files changed, 476 insertions, 0 deletions

diff --git a/dev-util/perf/Manifest b/dev-util/perf/Manifest
index 760392388140..b9a01eabe67c 100644
--- a/dev-util/perf/Manifest
+++ b/dev-util/perf/Manifest
@@ -6,6 +6,7 @@ DIST linux-4.14.tar.xz 100770500 BLAKE2B 85dc4aa953fe65e273a24473d8de98e4f204f97
 DIST linux-4.20.tar.xz 104257836 BLAKE2B fb52cad2897da319299486fa8c3b9415cd0aee0842dbf353a5b269720dcb902db407bb55dd95a77b212dcb4a488c15363d561f3649d6bd16885561f2466d90b1 SHA512 e282399beea5da539701aed2bc131abd5bc74a970dcd344163e9d295106dfd700180e672ed546ae5e55bc6b9ac95efd5ca1de2039015c1b7a6fc9c01ea6583d4
 DIST linux-5.4.tar.xz 109441440 BLAKE2B 193bc4a3147e147d5529956164ec4912fad5d5c6fb07f909ff1056e57235834173194afc686993ccd785c1ff15804de0961b625f3008cca0e27493efc8f27b13 SHA512 9f60f77e8ab972b9438ac648bed17551c8491d6585a5e85f694b2eaa4c623fbc61eb18419b2656b6795eac5deec0edaa04547fc6723fbda52256bd7f3486898f
 DIST linux-5.6.tar.xz 111785252 BLAKE2B 8dbe02a8ca7fd3dcf512a15c5d8098c1e7f94257e65173fed43fcc45480e4ab790df8cd39bbbb4e2a21dc9a00385bc9bbe98215a31e7f7e1d9c8f21cd8ace69e SHA512 80846fe2b4e4a7ff471d2dde28a8216ae807a3209f959e93d39ea4fc9a189ea28ec3db9d303b3fe15a28c2cb90e7446876678e93e23353c2d6f262e364a06bc9
+DIST linux-5.7.tar.xz 112690468 BLAKE2B b2b71e231507429b178b6b89be546c4a3ee2757f5d2c58b6137d383f16034a587225a75a9dbca6a01a433056ebe078487132c224e909a2971c9634687e47b1d1 SHA512 45bde01593f6147c8c169b9e46b4b56eee998142552ae0ff82f1dd21b1fd54f3b32f6283f6bd77ea717d374672167849e468c157f235d2f12f7d7816e4623bf6
 DIST patch-4.14.33.xz 905284 BLAKE2B e67bd9a96708aaaf65eb0aa852493b2323c9e237bfcc6fa837f795e481943ead3e2d5005ee72e40fc247df01c50877d9da3848a05aba3c999c3cfb7678cbdbc9 SHA512 5c76be5171709c2df7df7d5a8e8f3d0f7ede47b433da3b0f1710f262c8fcf5cf6c744a96d4336ea397c2c88a5f0a7507a5ab08c7c82f08deeb7a6f887ad77cfd
 DIST patch-4.20.3.xz 91732 BLAKE2B bf99271bcb35508df239343fd6c9d57c246f88320b586e44e2d97771d08b249a24db230214d4957015a5ed35261e201f0680101b99d0e92f0f1f69bc53e21458 SHA512 47178b8e3bfe4ba09cb82bb1ce8b0742e6749d4be3412fb57518918f7109e74eac1d3d8eb32a43e21b3837a14f37d5eefd8cab819defd10cc2db61fb0ceddeaf
 DIST patch-5.4.20.xz 776552 BLAKE2B bad2a95ed8521ac5c379fe91e16d60b2a38de19b9239755084621e5230677b232ec4cf9e2e8161c0022daff43fdbb37d5b5b5bfdc9e932ef3a860bcd17f640f8 SHA512 65fbcdbd41e35c17601ff15bbe33933be2ab7a694aa181a0b802cc11c1c653c9b688dbb382076cbad05983a0c07467955c035ae25f5175f7ce5bc24339303d77
@@ -14,4 +15,6 @@ EBUILD perf-4.14.33-r1.ebuild 5059 BLAKE2B 3bae91131eb7c24b152dbeac414057d1e5ba0
 EBUILD perf-4.20.3.ebuild 6042 BLAKE2B e1498b914f8b135927f5e97211d5246dab4bfd5bafbcf9ba431c2f8d95cf1568a162d2704f6cf851951178287efdcc6d75391ede09ea101b18d88463a4586912 SHA512 3f45b1edfefd658eaa48b4e4ae02c09e39cd6f2f7235bbb8eb9d90d69028df6d53709dac1790f932c7a20e7e77fad8327867ccdec80f302c0d72958d3c1bb138
 EBUILD perf-5.4.20.ebuild 6651 BLAKE2B e1a091114d71ba1c01f838b8d5ff372e2adad012769b973a2e79d662f6c5f6ed6fd97b2f7be880bfc57fbb99c549c487a084bf2450a935dc34ef22725268047a SHA512 e14917b4e051d3734fa515f3dbf61a2fe2cfdbe5b3aed29b9ce3b05e70609a13276d5f8fd0522f0b4addca16abdd986fb70b16d2b51f1204d02df848b64e6138
 EBUILD perf-5.6.14.ebuild 6406 BLAKE2B 81ae8af3e1380ed33baf0260b6151280ce7eba072c5d2e12d379a4af7de3a394286a28781367317f7e61c3f4dc053d43df501e5df5e28981beec94e3f216849d SHA512 5a4013d3ba171c99c2454ab59e5ee4f603ecd2c5b8f46675eb41005554fcf0ce8abba103cff836febef9c8e12c19e3bebfdb20ea553de468b6de1a33fae6a75e
+EBUILD perf-5.7-r1.ebuild 6481 BLAKE2B 049d8502779dcc2b3f80cff18ab9795855495ce13342ab0394f29c22d552f45652c7faf0b19e24953180d5851167c875b397540375e3db0f66141863851387ab SHA512 66b7922dd0b77f2ee974695bbc6c2330c06b523b1cbc0d0dac0bf16f32489cb4266152267b70ee6130ad252075fac7f3858e5dc222e06d6ab2a8f2a10344f52e
+EBUILD perf-5.7.ebuild 6406 BLAKE2B 81ae8af3e1380ed33baf0260b6151280ce7eba072c5d2e12d379a4af7de3a394286a28781367317f7e61c3f4dc053d43df501e5df5e28981beec94e3f216849d SHA512 5a4013d3ba171c99c2454ab59e5ee4f603ecd2c5b8f46675eb41005554fcf0ce8abba103cff836febef9c8e12c19e3bebfdb20ea553de468b6de1a33fae6a75e
 MISC metadata.xml 1355 BLAKE2B adf93b8b750786b9c181b5f4b4477883a365a07201da711d9ea535321d45b9c656397c46bd5f64a740d83e8acf4f2fea837a5a1eac754e9aa9f09692fe1d4d2b SHA512 3e489bb5b3556255d68bcffb3d7a377951da0470ea8e0a89dbc952d0029083fba7f7fd3c6f8a725bfa44c6e4d51871e2376b251f44a4295302be167d55dffb9f
diff --git a/dev-util/perf/perf-5.7-r1.ebuild b/dev-util/perf/perf-5.7-r1.ebuild
new file mode 100644
index 000000000000..d0b9058a60c1
--- /dev/null
+++ b/dev-util/perf/perf-5.7-r1.ebuild
@@ -0,0 +1,237 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit bash-completion-r1 estack eutils llvm toolchain-funcs prefix python-r1 linux-info
+
+MY_PV="${PV/_/-}"
+MY_PV="${MY_PV/-pre/-git}"
+
+DESCRIPTION="Userland tools for Linux Performance Counters"
+HOMEPAGE="https://perf.wiki.kernel.org/"
+
+LINUX_V="${PV:0:1}.x"
+if [[ ${PV} == *_rc* ]] ; then
+	LINUX_VER=$(ver_cut 1-2).$(($(ver_cut 3)-1))
+	PATCH_VERSION=$(ver_cut 1-3)
+	LINUX_PATCH=patch-${PV//_/-}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/${LINUX_PATCH}
+		https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/v${PATCH_VERSION}/${LINUX_PATCH}"
+elif [[ ${PV} == *.*.* ]] ; then
+	# stable-release series
+	LINUX_VER=$(ver_cut 1-2)
+	LINUX_PATCH=patch-${PV}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
+else
+	LINUX_VER=${PV}
+	SRC_URI=""
+fi
+
+LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
+SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="audit clang crypt debug +demangle +doc gtk java lzma numa perl python slang systemtap unwind zlib"
+# TODO babeltrace
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="audit? ( sys-process/audit )
+	crypt? ( dev-libs/openssl:0= )
+	clang? (
+		<sys-devel/clang-10:*
+		<sys-devel/llvm-10:*
+	)
+	demangle? ( sys-libs/binutils-libs:= )
+	gtk? ( x11-libs/gtk+:2 )
+	java? ( virtual/jre:* )
+	lzma? ( app-arch/xz-utils )
+	numa? ( sys-process/numactl )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	slang? ( sys-libs/slang )
+	systemtap? ( dev-util/systemtap )
+	unwind? ( sys-libs/libunwind )
+	zlib? ( sys-libs/zlib )
+	dev-libs/elfutils"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-4.19
+	${LINUX_PATCH+dev-util/patchutils}
+	sys-devel/bison
+	sys-devel/flex
+	java? ( virtual/jdk )
+	doc? (
+		app-text/asciidoc
+		app-text/sgml-common
+		app-text/xmlto
+		sys-process/time
+	)"
+
+S_K="${WORKDIR}/linux-${LINUX_VER}"
+S="${S_K}/tools/perf"
+
+CONFIG_CHECK="~PERF_EVENTS ~KALLSYMS"
+
+pkg_setup() {
+	use clang && LLVM_MAX_SLOT=9 llvm_pkg_setup
+}
+
+src_unpack() {
+	local paths=(
+		tools/arch tools/build tools/include tools/lib tools/perf tools/scripts
+		scripts include lib "arch/*/lib"
+	)
+
+	# We expect the tar implementation to support the -j option (both
+	# GNU tar and libarchive's tar support that).
+	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
+	tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
+		"${paths[@]/#/linux-${LINUX_VER}/}" || die
+
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		eshopts_push -o noglob
+		ebegin "Filtering partial source patch"
+		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
+			> ${P}.patch
+		eend $? || die "filterdiff failed"
+		eshopts_pop
+	fi
+
+	local a
+	for a in ${A}; do
+		[[ ${a} == ${LINUX_SOURCES} ]] && continue
+		[[ ${a} == ${LINUX_PATCH} ]] && continue
+		unpack ${a}
+	done
+}
+
+src_prepare() {
+	default
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		pushd "${S_K}" >/dev/null || die
+		eapply "${WORKDIR}"/${P}.patch
+		popd || die
+	fi
+
+	# Drop some upstream too-developer-oriented flags and fix the
+	# Makefile in general
+	sed -i \
+		-e "s:\$(sysconfdir_SQ)/bash_completion.d:$(get_bashcompdir):" \
+		"${S}"/Makefile.perf || die
+	# A few places still use -Werror w/out $(WERROR) protection.
+	sed -i -e 's:-Werror::' \
+		"${S}"/Makefile.perf "${S_K}"/tools/lib/bpf/Makefile || die
+
+	# Avoid the call to make kernelversion
+	echo "#define PERF_VERSION \"${MY_PV}\"" > PERF-VERSION-FILE
+
+	# The code likes to compile local assembly files which lack ELF markings.
+	find -name '*.S' -exec sed -i '$a.section .note.GNU-stack,"",%progbits' {} +
+
+	# Fix shebang to use python from prefix
+	if [[ -n "${EPREFIX}" ]]; then
+		hprefixify ${S_K}/scripts/bpf_helpers_doc.py
+	fi
+}
+
+puse() { usex $1 "" no; }
+perf_make() {
+	# The arch parsing is a bit funky.  The perf tools package is integrated
+	# into the kernel, so it wants an ARCH that looks like the kernel arch,
+	# but it also wants to know about the split value -- i386/x86_64 vs just
+	# x86.  We can get that by telling the func to use an older linux version.
+	# It's kind of a hack, but not that bad ...
+
+	# LIBDIR sets a search path of perf-gtk.so. Bug 515954
+
+	local arch=$(tc-arch-kernel)
+	local java_dir
+	use java && java_dir="/etc/java-config-2/current-system-vm"
+	# FIXME: NO_CORESIGHT
+	# FIXME: NO_LIBBABELTRACE
+	emake V=1 VF=1 \
+		HOSTCC="$(tc-getBUILD_CC)" HOSTLD="$(tc-getBUILD_LD)" \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" AR="$(tc-getAR)" LD="$(tc-getLD)" NM="$(tc-getNM)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		prefix="${EPREFIX}/usr" bindir_relative="bin" \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		ARCH="${arch}" \
+		JDIR="${java_dir}" \
+		LIBCLANGLLVM=$(usex clang 1 "") \
+		NO_AUXTRACE="" \
+		NO_BACKTRACE="" \
+		NO_CORESIGHT=1 \
+		NO_DEMANGLE=$(puse demangle) \
+		NO_GTK2=$(puse gtk) \
+		NO_JVMTI=$(puse java) \
+		NO_LIBAUDIT=$(puse audit) \
+		NO_LIBBABELTRACE=1 \
+		NO_LIBBIONIC=1 \
+		NO_LIBBPF="" \
+		NO_LIBCRYPTO=$(puse crypt) \
+		NO_LIBDW_DWARF_UNWIND="" \
+		NO_LIBELF="" \
+		NO_LIBNUMA=$(puse numa) \
+		NO_LIBPERL=$(puse perl) \
+		NO_LIBPYTHON=$(puse python) \
+		NO_LIBUNWIND=$(puse unwind) \
+		NO_SDT=$(puse systemtap) \
+		NO_SLANG=$(puse slang) \
+		NO_LZMA=$(puse lzma) \
+		NO_ZLIB= \
+		WERROR=0 \
+		LIBDIR="/usr/libexec/perf-core" \
+		"$@"
+}
+
+src_compile() {
+	# test-clang.bin not build with g++
+	if use clang; then
+		pushd "${S_K}/tools/build/feature/" || die
+		make V=1 CXX=${CHOST}-clang++ test-clang.bin || die
+		popd
+	fi
+	perf_make -f Makefile.perf
+	use doc && perf_make -C Documentation
+}
+
+src_test() {
+	:
+}
+
+src_install() {
+	_install_python_ext() {
+		perf_make -f Makefile.perf install-python_ext DESTDIR="${D}"
+	}
+
+	perf_make -f Makefile.perf install DESTDIR="${D}"
+	if use python; then
+		python_foreach_impl _install_python_ext
+	fi
+
+	rm -rv "${ED}"/usr/share/doc/perf-tip || die
+
+	if use gtk; then
+		mv "${ED}"/usr/$(get_libdir)/libperf-gtk.so \
+			"${ED}"/usr/libexec/perf-core || die
+	fi
+
+	dodoc CREDITS
+
+	dodoc *txt Documentation/*.txt
+	if use doc ; then
+		HTML_DOCS="Documentation/*.html" einstalldocs
+		doman Documentation/*.1
+	fi
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Without the doc USE flag you won't get any documentation nor man pages."
+		elog "And without man pages, you won't get any --help output for perf and its"
+		elog "sub-tools."
+	fi
+}
diff --git a/dev-util/perf/perf-5.7.ebuild b/dev-util/perf/perf-5.7.ebuild
new file mode 100644
index 000000000000..afc8951d08d5
--- /dev/null
+++ b/dev-util/perf/perf-5.7.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit bash-completion-r1 estack eutils llvm toolchain-funcs prefix python-r1 linux-info
+
+MY_PV="${PV/_/-}"
+MY_PV="${MY_PV/-pre/-git}"
+
+DESCRIPTION="Userland tools for Linux Performance Counters"
+HOMEPAGE="https://perf.wiki.kernel.org/"
+
+LINUX_V="${PV:0:1}.x"
+if [[ ${PV} == *_rc* ]] ; then
+	LINUX_VER=$(ver_cut 1-2).$(($(ver_cut 3)-1))
+	PATCH_VERSION=$(ver_cut 1-3)
+	LINUX_PATCH=patch-${PV//_/-}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/${LINUX_PATCH}
+		https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/v${PATCH_VERSION}/${LINUX_PATCH}"
+elif [[ ${PV} == *.*.* ]] ; then
+	# stable-release series
+	LINUX_VER=$(ver_cut 1-2)
+	LINUX_PATCH=patch-${PV}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
+else
+	LINUX_VER=${PV}
+	SRC_URI=""
+fi
+
+LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
+SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="audit clang crypt debug +demangle +doc gtk java lzma numa perl python slang systemtap unwind zlib"
+# TODO babeltrace
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="audit? ( sys-process/audit )
+	crypt? ( dev-libs/openssl:0= )
+	clang? (
+		<sys-devel/clang-10:*
+		<sys-devel/llvm-10:*
+	)
+	demangle? ( sys-libs/binutils-libs:= )
+	gtk? ( x11-libs/gtk+:2 )
+	java? ( virtual/jre:* )
+	lzma? ( app-arch/xz-utils )
+	numa? ( sys-process/numactl )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	slang? ( sys-libs/slang )
+	systemtap? ( dev-util/systemtap )
+	unwind? ( sys-libs/libunwind )
+	zlib? ( sys-libs/zlib )
+	dev-libs/elfutils"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-4.19
+	${LINUX_PATCH+dev-util/patchutils}
+	sys-devel/bison
+	sys-devel/flex
+	java? ( virtual/jdk )
+	doc? (
+		app-text/asciidoc
+		app-text/sgml-common
+		app-text/xmlto
+		sys-process/time
+	)"
+
+S_K="${WORKDIR}/linux-${LINUX_VER}"
+S="${S_K}/tools/perf"
+
+CONFIG_CHECK="~PERF_EVENTS ~KALLSYMS"
+
+pkg_setup() {
+	use clang && LLVM_MAX_SLOT=9 llvm_pkg_setup
+}
+
+src_unpack() {
+	local paths=(
+		tools/arch tools/build tools/include tools/lib tools/perf tools/scripts
+		scripts include lib "arch/*/lib"
+	)
+
+	# We expect the tar implementation to support the -j option (both
+	# GNU tar and libarchive's tar support that).
+	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
+	tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
+		"${paths[@]/#/linux-${LINUX_VER}/}" || die
+
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		eshopts_push -o noglob
+		ebegin "Filtering partial source patch"
+		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
+			> ${P}.patch
+		eend $? || die "filterdiff failed"
+		eshopts_pop
+	fi
+
+	local a
+	for a in ${A}; do
+		[[ ${a} == ${LINUX_SOURCES} ]] && continue
+		[[ ${a} == ${LINUX_PATCH} ]] && continue
+		unpack ${a}
+	done
+}
+
+src_prepare() {
+	default
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		pushd "${S_K}" >/dev/null || die
+		eapply "${WORKDIR}"/${P}.patch
+		popd || die
+	fi
+
+	# Drop some upstream too-developer-oriented flags and fix the
+	# Makefile in general
+	sed -i \
+		-e "s:\$(sysconfdir_SQ)/bash_completion.d:$(get_bashcompdir):" \
+		"${S}"/Makefile.perf || die
+	# A few places still use -Werror w/out $(WERROR) protection.
+	sed -i -e 's:-Werror::' \
+		"${S}"/Makefile.perf "${S_K}"/tools/lib/bpf/Makefile || die
+
+	# Avoid the call to make kernelversion
+	echo "#define PERF_VERSION \"${MY_PV}\"" > PERF-VERSION-FILE
+
+	# The code likes to compile local assembly files which lack ELF markings.
+	find -name '*.S' -exec sed -i '$a.section .note.GNU-stack,"",%progbits' {} +
+
+	# Fix shebang to use python from prefix
+	if [[ -n "${EPREFIX}" ]]; then
+		hprefixify ${S_K}/scripts/bpf_helpers_doc.py
+	fi
+}
+
+puse() { usex $1 "" no; }
+perf_make() {
+	# The arch parsing is a bit funky.  The perf tools package is integrated
+	# into the kernel, so it wants an ARCH that looks like the kernel arch,
+	# but it also wants to know about the split value -- i386/x86_64 vs just
+	# x86.  We can get that by telling the func to use an older linux version.
+	# It's kind of a hack, but not that bad ...
+
+	# LIBDIR sets a search path of perf-gtk.so. Bug 515954
+
+	local arch=$(tc-arch-kernel)
+	local java_dir
+	use java && java_dir="/etc/java-config-2/current-system-vm"
+	# FIXME: NO_CORESIGHT
+	# FIXME: NO_LIBBABELTRACE
+	emake V=1 VF=1 \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" AR="$(tc-getAR)" LD="$(tc-getLD)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		prefix="${EPREFIX}/usr" bindir_relative="bin" \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		ARCH="${arch}" \
+		JDIR="${java_dir}" \
+		LIBCLANGLLVM=$(usex clang 1 "") \
+		NO_AUXTRACE="" \
+		NO_BACKTRACE="" \
+		NO_CORESIGHT=1 \
+		NO_DEMANGLE=$(puse demangle) \
+		NO_GTK2=$(puse gtk) \
+		NO_JVMTI=$(puse java) \
+		NO_LIBAUDIT=$(puse audit) \
+		NO_LIBBABELTRACE=1 \
+		NO_LIBBIONIC=1 \
+		NO_LIBBPF="" \
+		NO_LIBCRYPTO=$(puse crypt) \
+		NO_LIBDW_DWARF_UNWIND="" \
+		NO_LIBELF="" \
+		NO_LIBNUMA=$(puse numa) \
+		NO_LIBPERL=$(puse perl) \
+		NO_LIBPYTHON=$(puse python) \
+		NO_LIBUNWIND=$(puse unwind) \
+		NO_SDT=$(puse systemtap) \
+		NO_SLANG=$(puse slang) \
+		NO_LZMA=$(puse lzma) \
+		NO_ZLIB= \
+		WERROR=0 \
+		LIBDIR="/usr/libexec/perf-core" \
+		"$@"
+}
+
+src_compile() {
+	# test-clang.bin not build with g++
+	if use clang; then
+		pushd "${S_K}/tools/build/feature/" || die
+		make V=1 CXX=${CHOST}-clang++ test-clang.bin || die
+		popd
+	fi
+	perf_make -f Makefile.perf
+	use doc && perf_make -C Documentation
+}
+
+src_test() {
+	:
+}
+
+src_install() {
+	_install_python_ext() {
+		perf_make -f Makefile.perf install-python_ext DESTDIR="${D}"
+	}
+
+	perf_make -f Makefile.perf install DESTDIR="${D}"
+	if use python; then
+		python_foreach_impl _install_python_ext
+	fi
+
+	rm -rv "${ED}"/usr/share/doc/perf-tip || die
+
+	if use gtk; then
+		mv "${ED}"/usr/$(get_libdir)/libperf-gtk.so \
+			"${ED}"/usr/libexec/perf-core || die
+	fi
+
+	dodoc CREDITS
+
+	dodoc *txt Documentation/*.txt
+	if use doc ; then
+		HTML_DOCS="Documentation/*.html" einstalldocs
+		doman Documentation/*.1
+	fi
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Without the doc USE flag you won't get any documentation nor man pages."
+		elog "And without man pages, you won't get any --help output for perf and its"
+		elog "sub-tools."
+	fi
+}