gentoo auto-resync : 05:09:2022 - 04:23:36

2 files changed, 274 insertions, 0 deletions

diff --git a/dev-util/perf/Manifest b/dev-util/perf/Manifest
index d68351a0f906..b163c870e75f 100644
--- a/dev-util/perf/Manifest
+++ b/dev-util/perf/Manifest
@@ -4,8 +4,11 @@ AUX perf-5.18-clang.patch 1858 BLAKE2B 04c8306f29f2fbb273f622ff046162a2e41eac9e5
 DIST linux-5.15.tar.xz 121913744 BLAKE2B 3921274b23f7938abdf3ed9334534b4581e13d7484303d3a5280eddb038999aaa8b836666a487472d9c4a219af0f06b9fecccaf348fb5510ab8762f4ef4b7e83 SHA512 d25ad40b5bcd6a4c6042fd0fd84e196e7a58024734c3e9a484fd0d5d54a0c1d87db8a3c784eff55e43b6f021709dc685eb0efa18d2aec327e4f88a79f405705a
 DIST linux-5.17.tar.xz 128399340 BLAKE2B 82dc4a45cc25c781ac67aa6ed1e4c369544154960f41c4634d47621f381159687a227054976d078524cda28884d395a15f7542fe44ca74ce98ca6ff54a81d6d0 SHA512 89f0a7ca69d20a539d4b612a7028a30a5e98b402e4b6b88516f14237e5da4b626d7929eab8b40fccc90766e8f3bae87e9858a19077ffad20d8204acf18794f5b
 DIST linux-5.18.tar.xz 129790264 BLAKE2B e2745a69eb70169e90505a9318a3993046eab3020496eecde7d8352ecda0eb71a25b21becf7ce93fc593507dce7d1cd61b94ddcdf82b3094d79c0d3d48508eeb SHA512 dbbc9d1395898a498fa4947fceda1781344fa5d360240f753810daa4fa88e519833e2186c4e582a8f1836e6413e9e85f6563c7770523b704e8702d67622f98b5
+DIST linux-5.19.tar.xz 131581464 BLAKE2B 4db03a6830a3b3bbf0837e1912182a443d9a4aa8af20a12e6ec814ed708038452d3c0ccee1258cca671c464d76461536363a8adc56e9d098c9a44ae3484a297a SHA512 00313b2f9b82d2dc3fb8294007cf7d7599d254b717ed2de23c81fa7a1bbcbc2798ad286cb94e2f7f5bd54132d1d764facd90d30f79dbcc6616cc7f926adc2623
 DIST patch-5.17.1.xz 15244 BLAKE2B f340b8a103754122153dd381fe210b18ba37b7262dae4fc7a1f99c5a62868c9bdb178e83865b35f00b82bd2d67ae127c440515d1740093825f7ec7fa4c4a490d SHA512 fb9a28ce7c68daeca82586e7631dc0be00a1a8393b4cef4c659fc1f9dac6e1f941bd60671c0350d1dea9cb035f56d627f64a394a9acb00b2b5dea8a1d44c065f
+DIST perf-5.19-binutils-2.39-patches.tar.xz 5612 BLAKE2B ec3aeadc3e2508f33dddbb419f434885b39b8220d294f3845f0bc96282923ff46dca126a04c732b8286752e56087ba5b2c5ad9526884f6d0b8b6df5665121e5e SHA512 af676e5a600e227d85f89a5ee0cfacfe1845aa56c27ef9da3ebaf578362d7e741375d30565759123b33b86d36bc9981c8c4cda113af32745cc59cf4a9275e73b
 EBUILD perf-5.15-r1.ebuild 7402 BLAKE2B 34680ee1fa303907add5dec4f041a978e41c5812bdef05141b6e4d3f8a31d984166788c6250f18ebcf6e4f6b4b4b55a71187d6084c149c7b2e684a470658a30b SHA512 c9395d36355c5bb83a28cfbefeab508baf1fd1a35fc817107a28000ef46f4c631893077d82218b9bc9949d5bf28ea633f657b40e91b1974a0093619388f410d7
 EBUILD perf-5.17.1.ebuild 7333 BLAKE2B 0d41316a6c0b736f5250af84d7e39ac69e9670b54ee46965f7a80de5bb64eb0e7b45e9e1ec8288850c853db035506269bba409ce4900481532f2c0384e84d77f SHA512 459add81f9fe2b917908286186bbad5e65253483b5b9e40983e6edb2cb1a1eba42682c815f73b25ae31e7ef8fd2a8b54efe4c1f3464677517d80b5a2282c1d72
 EBUILD perf-5.18.ebuild 7333 BLAKE2B 0d41316a6c0b736f5250af84d7e39ac69e9670b54ee46965f7a80de5bb64eb0e7b45e9e1ec8288850c853db035506269bba409ce4900481532f2c0384e84d77f SHA512 459add81f9fe2b917908286186bbad5e65253483b5b9e40983e6edb2cb1a1eba42682c815f73b25ae31e7ef8fd2a8b54efe4c1f3464677517d80b5a2282c1d72
+EBUILD perf-5.19.ebuild 7961 BLAKE2B 504f3aa853e6b4346bb3924b0341f88b380ccc18dc15f08c8a2011050ddd1192c6f6157d8d58ec287f51632be6963720422d43f9c95c23dffe4e785225db65ac SHA512 d3826cf38eb7a8890b55f2ab9c39991559e2067eee4ef1371ff7a659895a0e153ec87e5734138a6d95ad0435da8cea37b541e6dac16633a753de5a754463d229
 MISC metadata.xml 1495 BLAKE2B a85be66bde5edad744c83a0fd90bc9c93f87c96b804509ce21514915f02a4b32be0f2383105a25b2d076509b0bd902f9d630204f3bcb59e777426d88d50dfed7 SHA512 c672503c31391f0411de15996a22968a6a1301fd63675329649e8fe0304c32b2c008270a8d923650a60809026426439807e54ab41501497ac6a81e81adc23b44
diff --git a/dev-util/perf/perf-5.19.ebuild b/dev-util/perf/perf-5.19.ebuild
new file mode 100644
index 000000000000..c0b17711b75c
--- /dev/null
+++ b/dev-util/perf/perf-5.19.ebuild
@@ -0,0 +1,271 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit bash-completion-r1 estack llvm toolchain-funcs python-r1 linux-info
+
+DESCRIPTION="Userland tools for Linux Performance Counters"
+HOMEPAGE="https://perf.wiki.kernel.org/"
+
+LINUX_V="${PV:0:1}.x"
+if [[ ${PV} == *_rc* ]] ; then
+	LINUX_VER=$(ver_cut 1-2).$(($(ver_cut 3)-1))
+	PATCH_VERSION=$(ver_cut 1-3)
+	LINUX_PATCH=patch-${PV//_/-}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/${LINUX_PATCH}
+		https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/v${PATCH_VERSION}/${LINUX_PATCH}"
+elif [[ ${PV} == *.*.* ]] ; then
+	# stable-release series
+	LINUX_VER=$(ver_cut 1-2)
+	LINUX_PATCH=patch-${PV}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
+else
+	LINUX_VER=${PV}
+	SRC_URI=""
+	SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-binutils-2.39-patches.tar.xz"
+fi
+
+LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
+SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="audit babeltrace clang crypt debug +doc gtk java libpfm lzma numa perl python slang systemtap unwind zlib zstd"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	${LINUX_PATCH+dev-util/patchutils}
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+		app-text/sgml-common
+		app-text/xmlto
+		sys-process/time
+	)
+	${PYTHON_DEPS}
+"
+
+RDEPEND="audit? ( sys-process/audit )
+	babeltrace? ( dev-util/babeltrace )
+	crypt? ( virtual/libcrypt:= )
+	clang? (
+		sys-devel/clang:=
+		sys-devel/llvm:=
+	)
+	gtk? ( x11-libs/gtk+:2 )
+	java? ( virtual/jre:* )
+	libpfm? ( dev-libs/libpfm )
+	lzma? ( app-arch/xz-utils )
+	numa? ( sys-process/numactl )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	slang? ( sys-libs/slang )
+	systemtap? ( dev-util/systemtap )
+	unwind? ( sys-libs/libunwind )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )
+	dev-libs/elfutils
+	sys-libs/binutils-libs:="
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-5.10
+	java? ( virtual/jdk )
+"
+
+S_K="${WORKDIR}/linux-${LINUX_VER}"
+S="${S_K}/tools/perf"
+
+CONFIG_CHECK="~PERF_EVENTS ~KALLSYMS"
+
+QA_FLAGS_IGNORED=(
+	'usr/bin/perf-read-vdso32' # not linked with anything except for libc
+	'usr/libexec/perf-core/dlfilters/.*' # plugins
+)
+
+pkg_pretend() {
+	if ! use doc ; then
+		ewarn "Without the doc USE flag you won't get any documentation nor man pages."
+		ewarn "And without man pages, you won't get any --help output for perf and its"
+		ewarn "sub-tools."
+	fi
+}
+
+pkg_setup() {
+	use clang && llvm_pkg_setup
+	# We enable python unconditionally as libbpf always generates
+	# API headers using python script
+	python_setup
+}
+
+# src_unpack and src_prepare are copied to dev-util/bpftool since
+# it's building from the same tarball, please keep it in sync with bpftool
+src_unpack() {
+	local paths=(
+		tools/arch tools/build tools/include tools/lib tools/perf tools/scripts
+		scripts include lib "arch/*/lib"
+	)
+
+	# We expect the tar implementation to support the -j option (both
+	# GNU tar and libarchive's tar support that).
+	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
+	tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
+		"${paths[@]/#/linux-${LINUX_VER}/}" || die
+
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		eshopts_push -o noglob
+		ebegin "Filtering partial source patch"
+		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
+			> ${P}.patch
+		eend $? || die "filterdiff failed"
+		eshopts_pop
+	fi
+
+	local a
+	for a in ${A}; do
+		[[ ${a} == ${LINUX_SOURCES} ]] && continue
+		[[ ${a} == ${LINUX_PATCH} ]] && continue
+		unpack ${a}
+	done
+}
+
+src_prepare() {
+	default
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		pushd "${S_K}" >/dev/null || die
+		eapply "${WORKDIR}"/${P}.patch
+		popd || die
+	fi
+
+	pushd "${S_K}" >/dev/null || die
+	eapply "${FILESDIR}"/${PN}-5.18-clang.patch
+	# Used `git format-patch 00b32625982e0c796f0abb8effcac9c05ef55bd3...600b7b26c07a070d0153daa76b3806c1e52c9e00`
+	# bug #868129
+	rm "${WORKDIR}"/${P}-binutils-2.39-patches/0005-tools-bpf_jit_disasm-Fix-compilation-error-with-new-.patch || die
+	rm "${WORKDIR}"/${P}-binutils-2.39-patches/0006-tools-bpf_jit_disasm-Don-t-display-disassembler-four.patch || die
+	rm "${WORKDIR}"/${P}-binutils-2.39-patches/0007-tools-bpftool-Fix-compilation-error-with-new-binutil.patch || die
+	eapply "${WORKDIR}"/${P}-binutils-2.39-patches
+	popd || die
+
+	# Drop some upstream too-developer-oriented flags and fix the
+	# Makefile in general
+	sed -i \
+		-e "s@\$(sysconfdir_SQ)/bash_completion.d@$(get_bashcompdir)@" \
+		"${S}"/Makefile.perf || die
+	# A few places still use -Werror w/out $(WERROR) protection.
+	sed -i -e 's@-Werror@@' \
+		"${S}"/Makefile.perf "${S_K}"/tools/lib/bpf/Makefile || die
+
+	# Avoid the call to make kernelversion
+	sed -i -e '/PERF-VERSION-GEN/d' Makefile.perf || die
+	echo "#define PERF_VERSION \"${PV}\"" > PERF-VERSION-FILE
+
+	# The code likes to compile local assembly files which lack ELF markings.
+	find -name '*.S' -exec sed -i '$a.section .note.GNU-stack,"",%progbits' {} +
+}
+
+puse() { usex $1 "" no; }
+perf_make() {
+	# The arch parsing is a bit funky.  The perf tools package is integrated
+	# into the kernel, so it wants an ARCH that looks like the kernel arch,
+	# but it also wants to know about the split value -- i386/x86_64 vs just
+	# x86.  We can get that by telling the func to use an older linux version.
+	# It's kind of a hack, but not that bad ...
+
+	# LIBDIR sets a search path of perf-gtk.so. Bug 515954
+
+	local arch=$(tc-arch-kernel)
+	local java_dir
+	use java && java_dir="${EPREFIX}/etc/java-config-2/current-system-vm"
+	# FIXME: NO_CORESIGHT
+	emake V=1 VF=1 \
+		HOSTCC="$(tc-getBUILD_CC)" HOSTLD="$(tc-getBUILD_LD)" \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" AR="$(tc-getAR)" LD="$(tc-getLD)" NM="$(tc-getNM)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		prefix="${EPREFIX}/usr" bindir_relative="bin" \
+		tipdir="share/doc/${PF}" \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		ARCH="${arch}" \
+		JDIR="${java_dir}" \
+		LIBCLANGLLVM=$(usex clang 1 "") \
+		LIBPFM4=$(usex libpfm 1 "") \
+		NO_AUXTRACE="" \
+		NO_BACKTRACE="" \
+		NO_CORESIGHT=1 \
+		NO_DEMANGLE= \
+		GTK2=$(usex gtk 1 "") \
+		feature-gtk2-infobar=$(usex gtk 1 "") \
+		NO_JVMTI=$(puse java) \
+		NO_LIBAUDIT=$(puse audit) \
+		NO_LIBBABELTRACE=$(puse babeltrace) \
+		NO_LIBBIONIC=1 \
+		NO_LIBBPF= \
+		NO_LIBCRYPTO=$(puse crypt) \
+		NO_LIBDW_DWARF_UNWIND= \
+		NO_LIBELF= \
+		NO_LIBNUMA=$(puse numa) \
+		NO_LIBPERL=$(puse perl) \
+		NO_LIBPYTHON=$(puse python) \
+		NO_LIBUNWIND=$(puse unwind) \
+		NO_LIBZSTD=$(puse zstd) \
+		NO_SDT=$(puse systemtap) \
+		NO_SLANG=$(puse slang) \
+		NO_LZMA=$(puse lzma) \
+		NO_ZLIB=$(puse zlib) \
+		WERROR=0 \
+		LIBDIR="/usr/libexec/perf-core" \
+		libdir="${EPREFIX}/usr/$(get_libdir)" \
+		plugindir="${EPREFIX}/usr/$(get_libdir)/perf/plugins" \
+		"$@"
+}
+
+src_compile() {
+	# test-clang.bin not build with g++
+	if use clang; then
+		make -C "${S_K}/tools/build/feature" V=1 CXX=${CHOST}-clang++ test-clang.bin || die
+	fi
+	perf_make -f Makefile.perf
+	use doc && perf_make -C Documentation man
+}
+
+src_test() {
+	:
+}
+
+src_install() {
+	_install_python_ext() {
+		perf_make -f Makefile.perf install-python_ext DESTDIR="${D}"
+	}
+
+	perf_make -f Makefile.perf install DESTDIR="${D}"
+
+	if use python; then
+		python_foreach_impl _install_python_ext
+	fi
+
+	if use gtk; then
+		local libdir
+		libdir="$(get_libdir)"
+		# on some arches it ends up in lib even on 64bit, ppc64 for instance.
+		[[ -f "${ED}"/usr/lib/libperf-gtk.so ]] && libdir="lib"
+		mv "${ED}"/usr/${libdir}/libperf-gtk.so \
+			"${ED}"/usr/libexec/perf-core || die
+	fi
+
+	dodoc CREDITS
+
+	dodoc *txt Documentation/*.txt
+
+	# perf needs this decompressed to print out tips for users
+	docompress -x /usr/share/doc/${PF}/tips.txt
+
+	if use doc ; then
+		doman Documentation/*.1
+	fi
+}