gentoo resync : 28.04.2021

1 files changed, 55 insertions, 0 deletions

diff --git a/games-arcade/bomns/bomns-0.99.2-r1.ebuild b/games-arcade/bomns/bomns-0.99.2-r1.ebuild
new file mode 100644
index 000000000000..bd574f113189
--- /dev/null
+++ b/games-arcade/bomns/bomns-0.99.2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="A fast-paced multiplayer deathmatch arcade game"
+HOMEPAGE="http://greenridge.sourceforge.net"
+SRC_URI="mirror://sourceforge/greenridge/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk editor"
+
+DEPEND="
+	media-libs/libsdl[video]
+	media-libs/sdl-mixer
+	gtk? ( x11-libs/gtk+:2 )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fpe.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/appicondir/s:\$(prefix):/usr:" \
+		-e "/desktopdir/s:\$(prefix):/usr:" \
+		$(find icons -name Makefile.am) \
+		Makefile.am || die
+
+	sed -i \
+		-e "s:\$*[({]prefix[})]/share:/var/lib/:" \
+		configure.in \
+		graphics/Makefile.am \
+		levels/Makefile.am \
+		sounds/Makefile.am || die
+
+	mv configure.{in,ac} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	filter-flags -fforce-addr
+	econf \
+		--disable-launcher1 \
+		$(use_enable gtk launcher2) \
+		$(use_enable editor)
+}