gentoo resync : 25.11.2020

3 files changed, 57 insertions, 49 deletions

diff --git a/games-board/mah-jong/Manifest b/games-board/mah-jong/Manifest
index c873e9d44562..104427689e51 100644
--- a/games-board/mah-jong/Manifest
+++ b/games-board/mah-jong/Manifest
@@ -1,3 +1,3 @@
-DIST mj-1.14-src.tar.gz 414414 BLAKE2B 88aa315e629dd6c1155de38897925c99a742054778721f23c4e95b0b82667ad737246a92a1e9e18aa72e8e5b118d7c5bc5e8eb7ac9d0aab51b946a154627a584 SHA512 b4c631ce388041475b877cd4b413fda200932aea19212c00cb606d2ef0bb6a498fe12b7b52b04ef744b296c37c531bc44d9e35f9aed44edf89651580acde91e5
-EBUILD mah-jong-1.14-r1.ebuild 1219 BLAKE2B ba5e9fb1fffb94dd03ffc11d2c2edd281aa78d65d3c86032e7f7d27ad102aeeb13a85ea79144242a3b8f04c832b16f6193d036a1398b0b893c53d8b9575f505a SHA512 283b0885ac17f19f76cc78047f2387c4085c92ee2c6382363f66a6efc87118ec823b7373e59a053fa1951bf17bafb069eab92d6abd2f92e6a386e312b74d72ee
+DIST mj-1.16-src.tar.gz 403981 BLAKE2B fe04caa61c6b2b16be1799903ba222fe4ea6b177fa68c76c66a24fbf3ac8c02420f32a253fc1f7bc7fdb9bd371b294c2debd0492ae1071570f28dc69f22ba5f4 SHA512 9a4a4947670facaea6230aa9b143dab4bc7546b6e8b9c85726ac0b5e4d1f1760736072a27075cf2cce82cd8fdf2eb031f81e604fa0da6c05c7ac68c7da4b497e
+EBUILD mah-jong-1.16.ebuild 1181 BLAKE2B 71e3574f1f2a8f9c484d31b17cd1c8fa10739d1b33d2decc1cc275ca664b4bc5293d60b9731dc39b14396ccb29ed01637768fec09e09da7c4bd1565b82b2941a SHA512 8af4b75a3b8ee8cc7d28a3acebaff55172c03fef80f18e3576ec1afe4abe29e598f9e9676038e976e9b574f9508ab13f85dc19c13301b133bb431af5adf377d5
 MISC metadata.xml 249 BLAKE2B 7113a758d7abc93accec998a8843d8ef51ca8b72d72e659e224d5cec2a1a6a63e6c0605958091532ac6e51fa0d501ca4fd9f3f4a9e55baeb31519a02971b465f SHA512 895577c3a805c40581da03057b94e3f28f05f23012bf350c1e3575847d1a0fe40bb044a46f909012a200d991a400f6389358a60e9c2b5bef0da01fb26f846118
diff --git a/games-board/mah-jong/mah-jong-1.14-r1.ebuild b/games-board/mah-jong/mah-jong-1.14-r1.ebuild
deleted file mode 100644
index 3f7a81b7f8e5..000000000000
--- a/games-board/mah-jong/mah-jong-1.14-r1.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit eutils toolchain-funcs
-
-MY_P="mj-${PV}-src"
-DESCRIPTION="A networked Mah Jong program, together with a computer player"
-HOMEPAGE="http://www.stevens-bradfield.com/MahJong/"
-SRC_URI="http://mahjong.julianbradfield.org/Source/${MY_P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
-	dev-lang/perl"
-
-S=${WORKDIR}/${MY_P}
-
-src_prepare() {
-	default
-
-	sed -i -e '/^.TH/ s/1/6/' xmj.man || die
-	sed -i \
-		-e "/^DESTDIR =/ s:=.*:= ${D}:" \
-		-e "/^BINDIR =/ s:=.*:= /usr/bin:" \
-		-e '/^MANDIR =/ s:man/man1:/usr/share/man/man6:' \
-		-e '/^MANSUFFIX =/ s:1:6:' \
-		-e "/^CC =/ s:gcc:$(tc-getCC):" \
-		-e "/^CFLAGS =/ s:=:= ${CFLAGS}:" \
-		-e "/^LDLIBS =/ s:$:${LDFLAGS}:" \
-		-e '/^INSTPGMFLAGS =/ s:-s::' \
-		-e '/^CDEBUGFLAGS =/d' \
-		-e "/^TILESETPATH=/ s:NULL:\"/usr/share/${PN}/\":" Makefile || die
-}
-
-src_install() {
-	emake install install.man
-	insinto /usr/share/${PN}
-	doins -r fallbacktiles/ tiles-numbered/ tiles-small/
-	newicon tiles-v1/tongE.xpm ${PN}.xpm
-	make_desktop_entry xmj Mah-Jong ${PN}
-	dodoc CHANGES ChangeLog *.txt
-}
diff --git a/games-board/mah-jong/mah-jong-1.16.ebuild b/games-board/mah-jong/mah-jong-1.16.ebuild
new file mode 100644
index 000000000000..0d457c6c2d37
--- /dev/null
+++ b/games-board/mah-jong/mah-jong-1.16.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs xdg
+
+MY_P="mj-${PV}-src"
+DESCRIPTION="A networked Mah Jong program, together with a computer player"
+HOMEPAGE="https://mahjong.julianbradfield.org/"
+SRC_URI="https://mahjong.julianbradfield.org/Source/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+	sed -i -e '/^.TH/ s/1/6/' xmj.man || die
+}
+
+src_compile() {
+	# TILESETPATH value is passed as "char*" into "gui.c"
+	emake \
+		CC="$(tc-getCC)" \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}" \
+		CDEBUGFLAGS= \
+		TILESETPATH="\"${EPREFIX}/usr/share/${PN}/\""
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		BINDIR="/usr/bin" \
+		MANDIR="/usr/share/man/man6" \
+		MANSUFFIX=6 \
+		INSTPGMFLAGS= \
+		install install.man
+
+	insinto "/usr/share/${PN}"
+	doins -r fallbacktiles/ tiles-numbered/ tiles-small/
+	newicon tiles-v1/tongE.xpm "${PN}.xpm"
+	make_desktop_entry xmj Mah-Jong "${PN}"
+	dodoc CHANGES ChangeLog *.txt
+}