gentoo resync : 20.03.2022

1 files changed, 85 insertions, 0 deletions

diff --git a/games-emulation/melonds/melonds-0.9.4_p1-r1.ebuild b/games-emulation/melonds/melonds-0.9.4_p1-r1.ebuild
new file mode 100644
index 000000000000..706876b372f2
--- /dev/null
+++ b/games-emulation/melonds/melonds-0.9.4_p1-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="melonDS"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake readme.gentoo-r1 toolchain-funcs xdg
+
+DESCRIPTION="Nintendo DS emulator, sorta"
+HOMEPAGE="
+	http://melonds.kuribo64.net
+	https://github.com/Arisotura/melonDS
+"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arisotura/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/Arisotura/${MY_PN}/archive/0.9.4.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}"/${MY_PN}-0.9.4
+fi
+
+IUSE="+jit +opengl"
+LICENSE="BSD-2 GPL-2 GPL-3 Unlicense"
+SLOT="0"
+
+DEPEND="
+	app-arch/libarchive
+	dev-libs/teakra
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	media-libs/libsdl2[sound,video]
+	net-libs/libpcap
+	net-libs/libslirp
+	opengl? ( media-libs/libepoxy )
+"
+RDEPEND="${DEPEND}"
+
+# used for JIT recompiler
+QA_EXECSTACK="usr/bin/melonDS"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="You need the following files in order to run melonDS:
+- bios7.bin
+- bios9.bin
+- firmware.bin
+- romlist.bin
+Place them in ~/.config/melonDS
+Those files can be found somewhere on the Internet ;-)"
+
+PATCHES=( "${FILESDIR}"/melonds-system-teakra.patch )
+
+src_prepare() {
+	rm -r ./src/teakra || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_JIT=$(usex jit)
+		-DENABLE_OGLRENDERER=$(usex opengl)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	tc-export AR
+	cmake_src_compile
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}