gentoo auto-resync : 24:04:2023 - 12:10:01

3 files changed, 115 insertions, 3 deletions

diff --git a/games-emulation/mgba/Manifest b/games-emulation/mgba/Manifest
index d314d373f9de..b66504cfb681 100644
--- a/games-emulation/mgba/Manifest
+++ b/games-emulation/mgba/Manifest
@@ -1,5 +1,7 @@
 AUX mgba-0.10.0-optional-updater.patch 206 BLAKE2B 199a4305212e1974aa79ee728ab7b685b4b52602fe6447dd1b29513b526e101a306558b9a912bbb3c1438ea6a70df1c9e6368e2ca2ba5b50e6a59200b2a11daf SHA512 3227908dca7a2973ae5c7ec311b683362adf16ae5d5c801943322962d181ad046f43383bdf86441d81284f4f567a8d8ae387f4c15bf25b3d4189882fecd79d6b
 DIST mgba-0.10.1.tar.gz 14308454 BLAKE2B 5e28ac799cd9e5398508a65bec00dc1da9462e19dc18e0194368a8c57fff2b1af7578a595ab1a414741c1f68c795de3d55913302810d95298a4068b385613389 SHA512 bb79d2380a4708b70daf95c9b403427f77254391b1e11d68411384f265a670907e64b842c9978c9be558ffad337b738d9d83988d52890f08aed7e7fc124f19d4
+DIST mgba-0.10.2.tar.gz 14323388 BLAKE2B fb2e652b76871c9a9ffdbf049965ca4a62ee8fed48b547a4e7d514587535f172a7e3b21ec138b8660707a2fbdc19268985191d10eb268e7ed0f059c5a8c81216 SHA512 4063cde6dee9cc07025fa997e401ddd4b28240a9e53cee571ef8aec65cb6cf56b821f0020af1cf00d4f97353efbd4dc39ccd55bc6a3bdf0448ee34736bfd6499
 EBUILD mgba-0.10.1.ebuild 2616 BLAKE2B 2cb491281eae7df70ea19a6f848247b4645b55d5821f6b88f019db2aebde32a14c150cc968de4d0aa711b9095f702fc5cde2689421d185db0d282c6bac9806e4 SHA512 0aaa1205adc6eeefd6f63fa1e29f20d9c8d7d3e51acf774102af8ca156494142ae57e402f5631c9bd464f60956c068deff4f777f007c52f0f697a6f896ae47f2
-EBUILD mgba-9999.ebuild 2618 BLAKE2B 2a3cd7d8f3627e9bbc55d2b9cbb2311ff1110a0ec65a56b1d205577cf17fae84d494a8e8670fc58a2f6a6ef1a9485338a027c3427d34b94c6416e0790929f4c9 SHA512 1ae1336a426f6a3158143a1e73d143320fb3ec7873e9874819da697b7594b3fc17b67c8c1d43bd6a25660ade451cebc8035342aefdfa5558fdabcef322af72fb
+EBUILD mgba-0.10.2.ebuild 2654 BLAKE2B bb1da26068d9e6b6561b828d69495ad518c591c22c01499c6b24c22a71040a8ea66fb2fddeaa7ac6af460003bd793b88dc8c007de9a6780cddcd463f187f39c1 SHA512 48bf5513e03bea9514b26e4d8f08e05379b1678edf6f1797c597b415641cdf3dcb5beee0219d08ab4e83c71314ad3965578d2013a293e4ee62603ec49575a188
+EBUILD mgba-9999.ebuild 2654 BLAKE2B bb1da26068d9e6b6561b828d69495ad518c591c22c01499c6b24c22a71040a8ea66fb2fddeaa7ac6af460003bd793b88dc8c007de9a6780cddcd463f187f39c1 SHA512 48bf5513e03bea9514b26e4d8f08e05379b1678edf6f1797c597b415641cdf3dcb5beee0219d08ab4e83c71314ad3965578d2013a293e4ee62603ec49575a188
 MISC metadata.xml 686 BLAKE2B 14edb52fcb9e889ba151f05141d2f0b866a27ddb87943ee99a71223c747ae72423cbda0a8646b32ea175c13a67305bbba01c5062e3f73efba636f2d4a744de55 SHA512 3d671e43a9c0991131cce93bcc4b3c4da32fd67ebdbc57b404eafc4f235b3ad7af1417801bd84578d76553829b3ebfeb29d5a7f9871d11812e681759a2232698
diff --git a/games-emulation/mgba/mgba-0.10.2.ebuild b/games-emulation/mgba/mgba-0.10.2.ebuild
new file mode 100644
index 000000000000..2878b50c65f2
--- /dev/null
+++ b/games-emulation/mgba/mgba-0.10.2.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{3..4} )
+inherit cmake lua-single xdg
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
+else
+	SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Game Boy Advance Emulator"
+HOMEPAGE="https://mgba.io/"
+
+LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="debug discord elf ffmpeg gles2 gles3 gui libretro lua +opengl +sdl +sqlite test"
+REQUIRED_USE="
+	gui? ( || ( gles2 gles3 opengl ) sqlite )
+	lua? ( ${LUA_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	media-libs/libpng:=
+	sys-libs/zlib:=[minizip]
+	debug? ( dev-libs/libedit )
+	elf? ( dev-libs/elfutils )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gles2? ( media-libs/libglvnd )
+	gles3? ( media-libs/libglvnd )
+	lua? ( ${LUA_DEPS} )
+	opengl? ( media-libs/libglvnd )
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )"
+BDEPEND="
+	gui? ( dev-qt/linguist-tools:5 )
+	lua? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CINEMA=$(usex test)
+		-DBUILD_GL=$(usex opengl)
+		-DBUILD_GLES2=$(usex gles2)
+		-DBUILD_GLES3=$(usex gles3)
+		-DBUILD_LIBRETRO=$(usex libretro)
+		-DBUILD_QT=$(usex gui)
+		-DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
+		-DBUILD_SUITE=$(usex test)
+		-DBUILD_UPDATER=OFF
+		-DENABLE_SCRIPTING=$(usex lua)
+		-DMARKDOWN=OFF #752048
+		-DUSE_DEBUGGERS=$(usex debug)
+		-DUSE_DISCORD_RPC=$(usex discord)
+		-DUSE_EDITLINE=$(usex debug)
+		-DUSE_ELF=$(usex elf)
+		-DUSE_EPOXY=OFF
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_GDB_STUB=$(usex debug)
+		-DUSE_LIBZIP=OFF
+		-DUSE_LZMA=ON
+		-DUSE_MINIZIP=ON
+		-DUSE_PNG=ON
+		-DUSE_SQLITE3=$(usex sqlite)
+		-DUSE_ZLIB=ON
+		$(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
+	)
+	use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
+
+	cmake_src_configure
+}
+
+src_test() {
+	# CMakeLists.txt forces SKIP_RPATH=ON when PREFIX=/usr
+	local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	use !test || rm "${ED}"/usr/bin/mgba-cinema || die
+
+	rm -r "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
+}
diff --git a/games-emulation/mgba/mgba-9999.ebuild b/games-emulation/mgba/mgba-9999.ebuild
index a2fb0f2ce948..2878b50c65f2 100644
--- a/games-emulation/mgba/mgba-9999.ebuild
+++ b/games-emulation/mgba/mgba-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -47,7 +47,9 @@ RDEPEND="
 DEPEND="
 	${RDEPEND}
 	test? ( dev-util/cmocka )"
-BDEPEND="lua? ( virtual/pkgconfig )"
+BDEPEND="
+	gui? ( dev-qt/linguist-tools:5 )
+	lua? ( virtual/pkgconfig )"
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch