gentoo resync : 14.07.2018

3 files changed, 89 insertions, 0 deletions

diff --git a/games-misc/little-inferno/Manifest b/games-misc/little-inferno/Manifest
new file mode 100644
index 000000000000..7e36af69ab9d
--- /dev/null
+++ b/games-misc/little-inferno/Manifest
@@ -0,0 +1,3 @@
+DIST LittleInferno-20130509.sh 194304242 BLAKE2B 993d387c31cca0a92b7c1cf06581f60dfc31ba001250cfac00036204143350764d5ab023d6cc432e477219ac9cb24223fae21a422ecb501e58f499ae38469aac SHA512 19e2e616b1b1a6e7f8974ba12756c4b54c1daa99c99056891c56f7ed578f20a15143d683960efbb69f3d680243dd219051fc0bdac60ab74dcddc1c69df7d00dd
+EBUILD little-inferno-20130509.ebuild 1604 BLAKE2B 6693c55878933622cdc93be1f6954239cc40b7f9fc809e86e3ce51f2ac288282298a5dee749098ece5fa251b5cb966a2d02e312a51e1eb250bf4c37ceb1d691a SHA512 c9f2bf4c3953d10876b1cb8936e22e4b7614f10979d2955604b14d166af4defb66355f2fd2829f0c3c271678bb4e787cfbf2868805bc1b1f4a82007eba6b0725
+MISC metadata.xml 326 BLAKE2B 20c0a3a6cbb19e457c09b386a837b4202cf279231a681f3da7d604f3bffcfe6761f849ce82bc0169cc498d9bab565ff75216f4b749068e6663f5acbace935f7b SHA512 87eee3f514c290aba519dad7fdb335424ebd7ed7bb1cfa8650d293136ad2a6efdb44eff2c1c48973e9a587f282a2114866d9e4d66adb857b61a085d5635ecfd2
diff --git a/games-misc/little-inferno/little-inferno-20130509.ebuild b/games-misc/little-inferno/little-inferno-20130509.ebuild
new file mode 100644
index 000000000000..8461d5670943
--- /dev/null
+++ b/games-misc/little-inferno/little-inferno-20130509.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils gnome2-utils unpacker games
+
+DESCRIPTION="Throw your toys into your fire, and play with them as they burn"
+HOMEPAGE="http://tomorrowcorporation.com/"
+SRC_URI="LittleInferno-${PV}.sh"
+
+LICENSE="Gameplay-Group-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="bundled-libs"
+RESTRICT="bindist fetch bundled-libs? ( splitdebug )"
+
+MYGAMEDIR=${GAMES_PREFIX_OPT}/${PN}
+QA_PREBUILT="${MYGAMEDIR#/}/LittleInferno.bin.x86
+	${MYGAMEDIR#/}/lib/*"
+
+RDEPEND="
+	>=net-misc/curl-7.37.0-r1[abi_x86_32(-)]
+	x11-libs/libX11[abi_x86_32(-)]
+	virtual/opengl[abi_x86_32(-)]
+	!bundled-libs? (
+		>=media-libs/libogg-1.3.1[abi_x86_32(-)]
+		>=media-libs/libvorbis-1.3.3-r1[abi_x86_32(-)]
+		>=media-libs/openal-1.15.1-r1[abi_x86_32(-)] )"
+DEPEND="app-arch/xz-utils"
+
+src_unpack() {
+	unpack_makeself ${A}
+
+	mkdir ${P} || die
+	cd ${P} || die
+
+	local i
+	for i in instarchive_{,linux_}all ; do
+		mv ../"${i}" ../"${i}".tar.xz || die
+		unpack ./../"${i}".tar.xz
+	done
+}
+
+src_prepare() {
+	if use !bundled-libs ; then
+		rm -rv lib || die
+	fi
+}
+
+src_install() {
+	insinto "${MYGAMEDIR}"
+	doins -r *
+
+	doicon -s 128 LittleInferno.png
+	make_desktop_entry ${PN} "Little Inferno" LittleInferno
+	games_make_wrapper ${PN} "./LittleInferno.bin.x86" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
+
+	fperms +x "${MYGAMEDIR}"/LittleInferno.bin.x86
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-misc/little-inferno/metadata.xml b/games-misc/little-inferno/metadata.xml
new file mode 100644
index 000000000000..befc8c80e0b1
--- /dev/null
+++ b/games-misc/little-inferno/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="bundled-libs">Use bundled libraries.</flag>
+	</use>
+</pkgmetadata>