reinit the tree, so we can have metadata

4 files changed, 176 insertions, 0 deletions

diff --git a/games-roguelike/crossfire-client/Manifest b/games-roguelike/crossfire-client/Manifest
new file mode 100644
index 000000000000..e0620c10fbc3
--- /dev/null
+++ b/games-roguelike/crossfire-client/Manifest
@@ -0,0 +1,6 @@
+DIST crossfire-client-1.71.0.tar.bz2 761156 SHA256 5427655e756ffb48e75c1d9dc3200afab81efa7f2f00ffdf5dfee51918d5819d SHA512 86710d684fd7908ea9aaf5ba20bff0f1ba01ff0ba90c3e2847afff9d0db6f60c7b671413c8888b513c992fbf27474e744b79df185d5e2c04afc9d2dce3d8665e WHIRLPOOL 7a51aac98d4df3f057e201f900faa2fc5f46c180cc57e11db063307fce4510823cc8ef4da62c72bff9dc9a66756de71b93b2dd2e7e759b02c376c7d973d10f9e
+EBUILD crossfire-client-1.71.0-r1.ebuild 1626 SHA256 2b09588990af89adb643a95d343bb0bca71d1706ccec39ca9e8e6c96c5023cc1 SHA512 64427a93782a97f1b36b06ffedd281787690b208f14a7f0d1ed452a94e9c9e4ad8d7bda0f4e46b14915a96bd3d0d780d4e9ae9faab1eff3ba99818b8c7b0ff19 WHIRLPOOL 21c1ca4044e7b64fdb5d916f0e4c50fdf28fc683ea5437d64b16639e27bc77348c4ad8624ee709dd8b857c55b46dab809b2b6b14825624accba2b5abecee31b3
+EBUILD crossfire-client-1.71.0-r2.ebuild 1573 SHA256 5dfe068b179461586cfd65baf61656c0b8ce94347f14ee96bb7529df0942c957 SHA512 488691c905c146e25847cd2839197167abfa860cd5875ce0cd4337932f585ebb9e870c4d52f79e904d2dcbbaa5c1316419afc41bd67ec563974530d1950f3f33 WHIRLPOOL 1e9da63b1a420417778ef3766515473f5480621f3281868da3d36f850396bc1933bb64c64ba90fc0e9823aaacf0b9470ff0a31a7bc1aa799133660005576c7d5
+MISC ChangeLog 4023 SHA256 b3a4c67caeb835520c003e0e7d704296b959ab78312103edc72964830996a050 SHA512 c4eda484e60368ebbecd6379961bcd8983af5990f32e5c9e79e2870677c6fe36399472cd944ffa156c0c9a00d452384f242ef7b4125bd319fa7b7f97268f1957 WHIRLPOOL d9b72fdd29f5b2853e1f66741624981e69579d3b1a729f44edc142c42c6dc07f5052b1548a8ab3639ddb0bae2db8fb61bbfc78a11c6197a21aa52b66af382771
+MISC ChangeLog-2015 7180 SHA256 d90318520beeb0a23a6e5935381447d4e1e2b76952a227e5ccda3a30de12d47a SHA512 59ebee90cba10e5dba1e377034b183d9cd6eec41cc9377a8a18cdf0c5cba68d528d8c3cf470a6bd5c8805c8d9399a69d15a83ee7f3294e3cfb631fc00944a332 WHIRLPOOL c7244a0f9b0573149cc4214954c15b5614b3abc531bb668f1d3461c84b38ed302667d9502500ca83d7d83fb560c64298f5e2b7fda6975e9c94d08257e85976b2
+MISC metadata.xml 332 SHA256 4ea4ae6026d15105c7d28db5172539c34cc0b15e479ec0a3218ca9562fa606fe SHA512 cf046be69b614cd43deba574e8fbd23b566507c694b9f7cbda92d7009d727ac4087de411bf63463561beb3160ecfe7f9fb685574b018466b473535184529ccf7 WHIRLPOOL 56d933d8733f4ebd3738af985542e85599044bbfe140a394d3eb2cfe802904b30133128b3f6ddaf9b9c8b867050e0556ccaf708177156a478ed94ee9d6254366
diff --git a/games-roguelike/crossfire-client/crossfire-client-1.71.0-r1.ebuild b/games-roguelike/crossfire-client/crossfire-client-1.71.0-r1.ebuild
new file mode 100644
index 000000000000..092aa3bb809b
--- /dev/null
+++ b/games-roguelike/crossfire-client/crossfire-client-1.71.0-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools toolchain-funcs gnome2-utils games
+
+DESCRIPTION="Client for the nethack-style but more in the line of UO"
+HOMEPAGE="http://crossfire.real-time.com/"
+SRC_URI="mirror://sourceforge/crossfire/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="lua opengl sdl sound"
+
+RDEPEND="
+	sound? ( media-libs/sdl-mixer[vorbis] )
+	opengl? ( virtual/opengl
+		media-libs/freeglut )
+	sdl? ( media-libs/libsdl[video]
+		media-libs/sdl-image[png] )
+	lua? ( dev-lang/lua:0= )
+	x11-libs/gtk+:2
+	net-misc/curl
+	media-libs/libpng:0
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	sed -ri -e '/^.TH/s:$: 6:' $(find . -name "*man") || die
+	sed -i -e 's/lua-5.1/lua/' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	# bugs in configure script so we cant use $(use_enable ...)
+	local myconf
+
+	use lua    && myconf="${myconf} --enable-lua"
+	use sdl    || myconf="${myconf} --disable-sdl"
+	use opengl || myconf="${myconf} --disable-opengl"
+	use sound  || myconf="${myconf} --disable-sound"
+
+	egamesconf ${myconf}
+}
+
+src_compile() {
+	# bug 139785
+	if use sound ; then
+		emake -C sound-src AR="$(tc-getAR)"
+	fi
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	local s
+
+	default
+	domenu gtk-v2/crossfire-client.desktop
+	for s in 16 32 48
+	do
+		newicon -s ${s} pixmaps/${s}x${s}.png ${PN}.png
+	done
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-roguelike/crossfire-client/crossfire-client-1.71.0-r2.ebuild b/games-roguelike/crossfire-client/crossfire-client-1.71.0-r2.ebuild
new file mode 100644
index 000000000000..0292fdf40be5
--- /dev/null
+++ b/games-roguelike/crossfire-client/crossfire-client-1.71.0-r2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools toolchain-funcs gnome2-utils
+
+DESCRIPTION="Client for the nethack-style but more in the line of UO"
+HOMEPAGE="http://crossfire.real-time.com/"
+SRC_URI="mirror://sourceforge/crossfire/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="lua opengl sdl sound"
+
+RDEPEND="
+	lua? ( dev-lang/lua:0= )
+	media-libs/libpng:0
+	net-misc/curl
+	opengl? ( virtual/opengl
+		media-libs/freeglut )
+	sdl? ( media-libs/libsdl[video]
+		media-libs/sdl-image[png] )
+	sound? ( media-libs/sdl-mixer[vorbis] )
+	sys-libs/zlib
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -ri -e '/^.TH/s:$: 6:' $(find . -name "*man") || die
+	sed -i -e 's/lua-5.1/lua/' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	# bugs in configure script so we cant use $(use_enable ...)
+	local myconf
+
+	use lua    && myconf="${myconf} --enable-lua"
+	use sdl    || myconf="${myconf} --disable-sdl"
+	use opengl || myconf="${myconf} --disable-opengl"
+	use sound  || myconf="${myconf} --disable-sound"
+
+	econf ${myconf}
+}
+
+src_compile() {
+	# bug 139785
+	if use sound ; then
+		emake -C sound-src AR="$(tc-getAR)"
+	fi
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	local s
+
+	default
+	domenu gtk-v2/crossfire-client.desktop
+	for s in 16 32 48
+	do
+		newicon -s ${s} pixmaps/${s}x${s}.png ${PN}.png
+	done
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-roguelike/crossfire-client/metadata.xml b/games-roguelike/crossfire-client/metadata.xml
new file mode 100644
index 000000000000..baf8c3afc277
--- /dev/null
+++ b/games-roguelike/crossfire-client/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">crossfire</remote-id>
+	</upstream>
+</pkgmetadata>