reinit the tree, so we can have metadata

5 files changed, 228 insertions, 0 deletions

diff --git a/games-strategy/defcon-demo/Manifest b/games-strategy/defcon-demo/Manifest
new file mode 100644
index 000000000000..d4c7af13d7af
--- /dev/null
+++ b/games-strategy/defcon-demo/Manifest
@@ -0,0 +1,8 @@
+AUX defcon 400 SHA256 132840e1a669b6e5fc31eb3ad67bc2e95f0b34970a25e1b9fae13578cdf933d1 SHA512 d417fcf9560a3b3a7232e3c86b4315f0de6ed86ce8263348520910ff6bc1d14e649f31d500f52c70c2be655836261219ca9dce4f8df9a32d5ca2b00421667058 WHIRLPOOL e6cc0a31324cfc965cc9279a8bd7d43d5ddd52393786aeb9c244ec9bcfec14c375b436cca14abbd47342a96f73248a57e596cc7e185ed4b534433feff8828dea
+DIST defcon_1.6-1_amd64.deb 62377900 SHA256 52142cf3684f054f2449bb0dae96a3b9e0a9d5bb003ea479b25f8a55daffcb26 SHA512 b71aacc3cd94eec8f1ea19ee03d8098fcdd96191c12d614f55076826ef0bb44c8ada66dfd3df7d94d042b33bdd8fa5f0f58e69fc980d6213c320ab4ce2d682a9 WHIRLPOOL 8c9813764b412f4b2d2f1d75530e60800e49b98668bce11e931d898404ec10d45bc42e3c5478154b696c41b9dff93bcb0c72817ece38aedb50cc11bbc53265f1
+DIST defcon_1.6-1_i386.deb 62311684 SHA256 e61f1ebe93eaf821b6313b37e080a76a9444c2c46afc8e2386a0f2b644b8d1d3 SHA512 0e60e8fbca2f3046228b656990e3adb471de4f64a99d435c96b1e5a8cc49b1250c48ceeb19a4bcb58354e750398de2559256d26a38b20286dec3c0ce7f97ebb8 WHIRLPOOL 0d5fed7be50abaa2dd29434aae986bb63851a208f394b950a55c89d02cc36faf571209730641842a7af1cde0f33501cd6cb0dcb33c8287ef591d5675c67d3cbe
+EBUILD defcon-demo-1.60-r1.ebuild 2178 SHA256 3026f4fd1e0e9849188bf33cb0114e2b754c22abb38c305a871703e1856312d5 SHA512 76deacb77ad8d5959a750bc74e71cd30d16b70394065879ea34ad7c0eb39204e7326e5efc777928b9544ad68e50534bb76ddcf605c2263b137dfea9c345f7dae WHIRLPOOL 422b4955003513ad98ae9505de15bde94d49bd311bffa3868d9935f157b581e23a7ffee1a30bf0a6dcbd36440bc191ead1ca7f3979a987d3235305d0acc6b98e
+EBUILD defcon-demo-1.60.ebuild 2277 SHA256 54bd697b6a5729ab2ad13e10675e9c88bc29085c81b5da58e53e4e881fcd2caa SHA512 40ebf679cd1ef98dfac3f2219c16d5d1c486673d752c0649437ffe6fa1ba8ec0e7897ce20dae43921ed5652822cba4708be96533bda2a1ac20b0437798d47f2f WHIRLPOOL ea1654080412641ad25a2f0551008eb26ecb545fca9959214f870f20f99c243b1d07cddca08e97e0403a59f26eb824d261084ebefe6d8aaa8bdca73c7e435d52
+MISC ChangeLog 2719 SHA256 69d4f7575e12a2f44f35d49cd970cee92384704f42f208d854e0a0a26977ac90 SHA512 c84ad6dd2f9915ea13e2c3c11abc0af562e3233bbdda954aa8c8cb730adbe9ef1ff53aa8397b85006b80413377937caa61b8c7482c98259d54a376f1a8f8ee13 WHIRLPOOL 32051f369cf2b5802274526d98d8ccbbb488f6877f8a5130f1e9c34167053aa87449e0bbc0def694dabe7a00f9ce25d4ca646882822a284aaab5757e4e7fdba9
+MISC ChangeLog-2015 1244 SHA256 9ec5dccb675ca654cba02db18db69d494bb43e94bfe83aa77aa59402bf9bc5b6 SHA512 342a237cb70dd6f5195548769f7f1fdfd801607e1616a288f029a23d0385a217b9ab0a04d36f3f18dd7be46dafc9c51b4206bd4921d00e946b164770d1b349b1 WHIRLPOOL 2b61884e90b27adf508582941d188bcbd00072e9768bc609e53b30f07625b66321692181abb312a3bdc05f7c7e6e1219ce5f8ad30720de7f6696005179863d9c
+MISC metadata.xml 390 SHA256 ad3dedcf03e5e1bf2e2007bba0f9ea119071066bcb56f9d7bb14b9073a941733 SHA512 afc01361f043a0267f09fc1a83571ade9a3cb3633744ff18e5b5c5f14ac061b5e9d6876c0b3805664a8321a6572bb6c2c3c1f3f0d9f0762d306b80a1b517ea5b WHIRLPOOL 07d1f82b8bebaa1eecd95192968b266cf7c64473bee701f2a8e0765c4ad62ca7824a78fa7a4a7406b3eea592eb8ec07e467781cd57df8a9005021fbb197cd7c3
diff --git a/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild b/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild
new file mode 100644
index 000000000000..486a654236bb
--- /dev/null
+++ b/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs gnome2-utils
+
+MY_PN=defcon
+MY_PV=${PV:0:3}
+MY_PVR=1
+MY_P=defcon_${MY_PV}-${MY_PVR}
+
+DESCRIPTION="Global thermonuclear war simulation with multiplayer support"
+HOMEPAGE="http://www.introversion.co.uk/defcon/"
+SRC_URI="x86? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_i386.deb )
+	amd64? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_amd64.deb )"
+
+LICENSE="Introversion"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+system-libs"
+RESTRICT="mirror strip"
+
+# glibc discussion:
+# http://forums.introversion.co.uk/defcon/viewtopic.php?t=4016
+RDEPEND="
+	media-libs/libogg
+	media-libs/libvorbis
+	>=sys-libs/glibc-2.3
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	system-libs? ( media-libs/libsdl[sound,video] )"
+DEPEND=""
+
+QA_PREBUILT="/opt/${PN}/lib/${MY_PN}.bin.x86"
+
+S="${WORKDIR}/usr/local/games/${MY_PN}"
+
+src_unpack() {
+	default
+	unpack ./data.tar.gz
+
+	cd "${S}" || die
+	# maintain compatibility with old installation/script
+	[[ -e lib64 ]] && { mv lib64 lib || die ;}
+	[[ -e ${MY_PN}.bin.x86_64 ]] && { mv ${MY_PN}.bin.x86_64 ${MY_PN}.bin.x86 || die ;}
+}
+
+src_prepare() {
+	default
+
+	# FindPath scripts are ugly and unnecessary
+	if use system-libs ; then
+		rm -f lib/lib*
+	fi
+	sed \
+		-e "s:GAMEDIR:/opt/${PN}:g" \
+		"${FILESDIR}"/${MY_PN} > "${T}"/${MY_PN} || die
+	echo "int chdir(const char *d) { return 0; }" > chdir.c || die
+}
+
+src_compile() {
+	echo "$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c"
+	$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c || die
+}
+
+src_install() {
+	local dir="/opt/${PN}"
+
+	insinto "${dir}/lib"
+	doins *.dat
+
+	exeinto "${dir}"/lib
+	doexe lib/*.so
+	doexe ${MY_PN}.bin.x86
+
+	doicon -s 128 ${MY_PN}.png
+
+	# Can be upgraded to full version, so is not installed as "demo"
+	dobin "${T}"/${MY_PN}
+	make_desktop_entry ${MY_PN} "Defcon"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	elog "Screenshots will appear in ~/.${MY_PN}/lib"
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/defcon-demo/defcon-demo-1.60.ebuild b/games-strategy/defcon-demo/defcon-demo-1.60.ebuild
new file mode 100644
index 000000000000..8dde409344d1
--- /dev/null
+++ b/games-strategy/defcon-demo/defcon-demo-1.60.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils toolchain-funcs gnome2-utils games
+
+MY_PN=defcon
+MY_PV=${PV:0:3}
+MY_PVR=1
+MY_P=defcon_${MY_PV}-${MY_PVR}
+
+DESCRIPTION="Global thermonuclear war simulation with multiplayer support"
+HOMEPAGE="http://www.introversion.co.uk/defcon/"
+SRC_URI="x86? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_i386.deb )
+	amd64? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_amd64.deb )"
+
+LICENSE="Introversion"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+system-libs"
+RESTRICT="mirror strip"
+
+# glibc discussion:
+# http://forums.introversion.co.uk/defcon/viewtopic.php?t=4016
+RDEPEND="
+	media-libs/libogg
+	media-libs/libvorbis
+	>=sys-libs/glibc-2.3
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXext
+	x11-libs/libXdmcp
+	system-libs? ( media-libs/libsdl[sound,video] )"
+DEPEND=""
+
+QA_PREBUILT="${GAMES_PREFIX_OPT:1}/${PN}/lib/${MY_PN}.bin.x86"
+
+S=${WORKDIR}/usr/local/games/${MY_PN}
+
+src_unpack() {
+	default
+	unpack ./data.tar.gz
+
+	cd "${S}" || die
+	# maintain compatibility with old installation/script
+	[[ -e lib64 ]] && { mv lib64 lib || die ;}
+	[[ -e ${MY_PN}.bin.x86_64 ]] && { mv ${MY_PN}.bin.x86_64 ${MY_PN}.bin.x86 || die ;}
+}
+
+src_prepare() {
+	# FindPath scripts are ugly and unnecessary
+	if use system-libs ; then
+		rm -f lib/lib*
+	fi
+	sed \
+		-e "s:GAMEDIR:${GAMES_PREFIX_OPT}/${PN}:g" \
+		"${FILESDIR}"/${MY_PN} > "${T}"/${MY_PN} || die
+	echo "int chdir(const char *d) { return 0; }" > chdir.c || die
+}
+
+src_compile() {
+	echo "$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c"
+	$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c || die
+}
+
+src_install() {
+	local dir=${GAMES_PREFIX_OPT}/${PN}
+
+	insinto "${dir}/lib"
+	doins *.dat
+
+	exeinto "${dir}"/lib
+	doexe lib/*.so
+	doexe ${MY_PN}.bin.x86
+
+	doicon -s 128 ${MY_PN}.png
+
+	# Can be upgraded to full version, so is not installed as "demo"
+	dogamesbin "${T}"/${MY_PN}
+	make_desktop_entry ${MY_PN} "Defcon"
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+	elog "Screenshots will appear in ~/.${MY_PN}/lib"
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/defcon-demo/files/defcon b/games-strategy/defcon-demo/files/defcon
new file mode 100644
index 000000000000..6e9dd3b5307c
--- /dev/null
+++ b/games-strategy/defcon-demo/files/defcon
@@ -0,0 +1,15 @@
+#!/bin/sh
+if [ -n "GAMEDIR/lib" ] ; then
+	if [ "${LD_LIBRARY_PATH+set}" = "set" ] ; then
+		export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:GAMEDIR/lib"
+	else
+		export LD_LIBRARY_PATH="GAMEDIR/lib"
+	fi
+fi
+if [[ ! -e ~/.defcon/lib ]] ; then
+	mkdir -p ~/.defcon/lib \
+	    && cd ~/.defcon/lib \
+	    && ln -s "GAMEDIR"/lib/* .
+fi
+cd ~/.defcon/lib
+LD_PRELOAD="GAMEDIR/lib/chdir.so" exec ./defcon.bin.x86 "$@"
diff --git a/games-strategy/defcon-demo/metadata.xml b/games-strategy/defcon-demo/metadata.xml
new file mode 100644
index 000000000000..6e48df8a7f4f
--- /dev/null
+++ b/games-strategy/defcon-demo/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+    <email>games@gentoo.org</email>
+    <name>Gentoo Games Project</name>
+  </maintainer>
+  <use>
+    <flag name="system-libs">Use system libraries instead of the ones included in the upstream distribution.</flag>
+  </use>
+</pkgmetadata>