gentoo auto-resync : 11:04:2023 - 23:39:54

1 files changed, 57 insertions, 0 deletions

diff --git a/games-util/sc-controller/sc-controller-0.4.8.9-r1.ebuild b/games-util/sc-controller/sc-controller-0.4.8.9-r1.ebuild
new file mode 100644
index 000000000000..6c49de8ca581
--- /dev/null
+++ b/games-util/sc-controller/sc-controller-0.4.8.9-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 linux-info xdg
+
+DESCRIPTION="User-mode driver and GTK-based GUI for Steam Controllers and others"
+HOMEPAGE="https://github.com/Ryochan7/sc-controller/"
+SRC_URI="https://github.com/Ryochan7/sc-controller/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 BSD CC-BY-3.0 CC0-1.0 LGPL-2.1 MIT PSF-2 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+udev wayland"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject[${PYTHON_USEDEP},cairo]
+		dev-python/pylibacl[${PYTHON_USEDEP}]
+		dev-python/python-evdev[${PYTHON_USEDEP}]
+		dev-python/vdf[${PYTHON_USEDEP}]')
+	gnome-base/librsvg[introspection]
+	virtual/libusb
+	x11-libs/gtk+:3[introspection]
+	udev? ( games-util/game-device-udev-rules )
+	wayland? ( gui-libs/gtk-layer-shell[introspection(+)] )
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/Ryochan7/sc-controller/pull/82
+	"${FILESDIR}/${P}-python3_11.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="~INPUT_UINPUT"
+
+	linux-info_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# This test fails. Don't know why but seems unimportant.
+	rm -v tests/test_glade.py || die
+}
+
+src_install() {
+	distutils-r1_src_install
+	rm -r "${ED}"/usr/lib/udev/ || die
+}