gentoo resync : 03.03.2019

2 files changed, 133 insertions, 0 deletions

diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index 4c4cd0a4a143..a3a628d4ced3 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -3,6 +3,9 @@ DIST gnome-settings-daemon-3.24.4-patchset.tar.xz 5224 BLAKE2B f01db03ce3980a743
 DIST gnome-settings-daemon-3.24.4.tar.xz 1632700 BLAKE2B 616aad6984df726c438117ab98e8c5a35bd02a6ebbc3c24fc46b50e8b3ca3f3d5bede0588cfe9bbdfcaccc70ff5799feeabf020ec4beb03d653ae81abc6325f8 SHA512 4a3b1069d80263a92ae2c2a420f7dc70a1ff92346d5cbeb1e7dd4af0419e039ebe958550594d87929c0333c19aa9a3ef7ca9b9751109a9da64a40d81ba067cc0
 DIST gnome-settings-daemon-3.26.2-patchset.tar.xz 42408 BLAKE2B 3b54dd1b161f4137eeb7c110be70444e3b8eb602a7d1c12ec6aaa32d887d46c3e1dc61df2a04895b7c6e2d67a68edeced5f758f688533caa9900deace7b6d542 SHA512 3ab36a03e2892ad193f420722025753990158ac450c686b9fba490cda4e7e1be69574dd4d3b9c8ed5e238f23933065abc28aee480ff1e2e5dad28e364c04fc0b
 DIST gnome-settings-daemon-3.26.2.tar.xz 1589696 BLAKE2B f1fd18e80caf5badb0da1f07cbe994b73a99ace004bf3b568114d6cd6110ebd092ee3a023a1ec818f3946f6f7cdb7ee21417782e271c8aa9ebd9d1d4c35ea286 SHA512 7785ebcb7df466c50557b75a3092f568e375adcf5a40f73e31d5cc69fa63bc556a4447a96e6e612c3bf523735e67168afae0b9c1fab32912d41014436d33b7ff
+DIST gnome-settings-daemon-3.28.1-patchset.tar.xz 5216 BLAKE2B eab85f6475c1da9c8beb1dea7d7d79bdaf2e57ac82e90a4ab877e5ffbd8423df8ed5dbd03ac6586a3aadf2be16b89e2955267be24af71db8c89cc407241e0bc9 SHA512 f56a5d62ba45976a01c8fcab63c4d7afd21dbe7a4c75158cc54fc60552faf875b0ca1be7a882c11d814566e7a4ded63ce52d10d214bd1f7926c2d7b0dbaf1590
+DIST gnome-settings-daemon-3.28.1.tar.xz 1362420 BLAKE2B d809696ea7a2df3b89b1e2badbd015623e624c38f44a087e26d167c7ba9a5499a33e6e4ebb12448f69d8aa645154bc176a156f1b9e4a749684e5a497a7be6fc6 SHA512 22e42ce92a6f3ad67a0ef7d1676a6dd3d533b0bc91193d8b2a19a51d7c9601c87caf391c233bb1b96e8a1270d610aca52523d0ae12a38b0e3911065c3a67e10f
 EBUILD gnome-settings-daemon-3.24.4.ebuild 4721 BLAKE2B 8e8933764655357514fca45a002376d2de3dea4eb5df7ce4bf1bdbc4b465d8d351aabf4f91aabdda46bfe3f72812137e8fc8423d30060e99e07ce045e7fed3dc SHA512 f4382da6b22932620ccb995a166ed3b6d1006bec9c2e96cabc42269d73e0508d945d4803efa5b84ccd4167d72a6c7c44f6173a5670af60895fc577e18cf98e5e
 EBUILD gnome-settings-daemon-3.26.2-r1.ebuild 3841 BLAKE2B fe70ab9081814d5bc8f81db2de1dfb4d31aebd98c2aa10ac566560f11013ce64d2a21957b96adafebc4802f84ae845f7535509d0100e662468798791dec15b24 SHA512 2555b73ae173cb3c5bde8f53081582f951334a0048e216cfc50ce509dc5346dba86925aff6d51b77c8e10e93384e9f57d6ed741ec1f650aa614b61e590149794
+EBUILD gnome-settings-daemon-3.28.1.ebuild 3749 BLAKE2B 8489ced21d928ca25a467908b5a3c4f7e0e274c75a777c16175de07ae22a1aa0f5a3c4a53370989d801e89ffdd169a9d122421bc5f43732feb0b8745ede7b4c6 SHA512 8d2d7070b9e257052e2bddfda038e31c958fed6345a13eb062d58774f415ee16573ccc7fa14a8904bb92b57ed2e6d05f3c49b90e9c2f28634db721557987704c
 MISC metadata.xml 774 BLAKE2B 94211f84287a451ef68bddcae9824b5345379600b3761067267d8c127bc083337e9bdf41162308efd47f419f13ed790221f082ea6282aa0038a85d13c9edc902 SHA512 4de08b4c743a03dfbb7e9e39cff7473c0f9529ba897b78d0adef9fb980b584a65274b617d1cf50b824e9c35722f6f6ab0565da37ae5fb4c820bdae37b5832833
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.28.1.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.28.1.ebuild
new file mode 100644
index 000000000000..0786e730078b
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.28.1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://git.gnome.org/browse/gnome-settings-daemon"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom networkmanager policykit smartcard systemd test +udev wayland"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+	input_devices_wacom? ( udev )
+	wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# >=polkit-0.114 for ITS translation rules of .policy files
+COMMON_DEPEND="
+	>=sci-geosciences/geocode-glib-3.10
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gnome-desktop-3.11.1:3=
+	>=gnome-base/gsettings-desktop-schemas-3.23.3
+	>=x11-libs/gtk+-3.15.3:3[X]
+	>=dev-libs/libgweather-3.9.5:2=
+	colord? (
+		>=x11-misc/colord-1.0.2:=
+		>=media-libs/lcms-2.2:2 )
+	media-libs/libcanberra[gtk3]
+	>=app-misc/geoclue-2.3.1:2.0
+	>=x11-libs/libnotify-0.7.3
+	>=media-sound/pulseaudio-2[glib]
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99:=
+	x11-libs/libX11
+	x11-libs/libXtst
+	udev? ( virtual/libgudev:= )
+	wayland? ( dev-libs/wayland )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.7
+		>=x11-libs/pango-1.20.0
+		x11-libs/gdk-pixbuf:2 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	media-libs/alsa-lib
+	x11-libs/libXi
+	x11-libs/libXext
+	media-libs/fontconfig
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.27.90 and gdm-3.27.9 adapt to A11yKeyboard component removal (moved to shell dealing with it)
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+	!<gnome-base/gnome-session-3.27.90
+	!<gnome-base/gdm-3.27.90
+"
+# rfkill requires linux/rfkill.h, thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+DEPEND="${COMMON_DEPEND}
+	sys-kernel/linux-headers
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	x11-base/xorg-proto
+	${PYTHON_DEPS}
+	test? (
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]')
+		gnome-base/gnome-session )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+# Tests go a bit better in 3.26, but still fail some for me; revisit with 3.30+ (incompatible build system python needs until then as well)
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	# upstream gnome-3-28 branch up to its abandonment in August 2018 (small bug fixes)
+	# Allow disabling udev and networkmanager on Linux
+	# Make colord and wacom optional
+	# glib 2.58 compatibility fix; included in 3.29.1+
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+		-Dudev_dir="$(get_udevdir)"
+		-Dalsa=true
+		$(meson_use udev gudev)
+		$(meson_use colord)
+		$(meson_use cups)
+		$(meson_use networkmanager network_manager)
+		-Drfkill=true
+		$(meson_use smartcard)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}