gentoo resync : 09.07.2022

3 files changed, 133 insertions, 2 deletions

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
index e3a090feab8a..e31685d46ffc 100644
--- a/gnome-extra/gnome-boxes/Manifest
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -1,5 +1,7 @@
 DIST gnome-boxes-42.0.1.tar.xz 1231252 BLAKE2B e80503c1a2dbc4a4990ff8fb477f7e72fe1a880412a91d42fffd93c68226c91d254daf28301d816e3555f8a88c9b3f27b35df406bde7483a4a8e98dd3e83e756 SHA512 74968525943ff1a695f2d0cbcd3b9066f2b8c87d6b3b7dea5dab2911600fb09c961ee547a759eed2a23636c7b242a86b56e5ee579dc01e9e9c9caac67a845b03
 DIST gnome-boxes-42.1.tar.xz 1235760 BLAKE2B 4de67e369d2135acc2407789c06441840da32c2d13eb329ab874021a56685f64c66fcf47a00a9ddc287a5eeccc2fae799a26147a9ade6ab8b1877a3865407ac7 SHA512 8233c06abe7c6a3e816d599fd2f2729e19b356f130d0ec0cc9d3c47cab0d10ffcc9e8e3f263999ac50c17a7ea63bb417213465cca641fff60ea4bf1c79caaaa7
+DIST gnome-boxes-42.3.tar.xz 1235916 BLAKE2B 69a52117b0ef459b4f6c11287f3961283c0493522875958ae65cf1838d9359b60e1c376bf86c1bc1899e69b6b9aed72a32aa39c7e687afef6a23de50d599b8e8 SHA512 2c455830b76cffc647838b797dc7667d9dec0be45658972075b203553bd73bb54dd6b9b22891da9eb12bea7f157b26980a172685a10e1d252f32014f38eb8805
 EBUILD gnome-boxes-42.0.1.ebuild 3852 BLAKE2B f077a6d89ead04038dce83f85f0c7ee1d363fc26a0a2e07db5748d65f140cde0d55d2f89e57bd566dbdaefbac9e9dda8fba3173dbd918444d9d05c30b3db01d8 SHA512 6f1ebb0dd036865f817d0c3651b4d6739967814778aecfa7039a1f7e5eb04c9258f030d94924ec2ebb56ad14c42c774b29ea17396fed4d7d68cb3262fec0364c
-EBUILD gnome-boxes-42.1.ebuild 3853 BLAKE2B 9d3dab4e21c33ecdb5ef733afa2614b31bb89117a777fc3ea89bfec730ac046d4ef2c2216bbddcd71844bcfe2a19a270f8bc75286aa5748772479b7c7a26d064 SHA512 ef898a44103bcc5219833dd786702e72aa49aaf40d69a2f5a00981f22065a3a93f4f300a0416eab67150d1a0127e8685979c63c5198ac74bda61ecd61cad9227
+EBUILD gnome-boxes-42.1.ebuild 3852 BLAKE2B f077a6d89ead04038dce83f85f0c7ee1d363fc26a0a2e07db5748d65f140cde0d55d2f89e57bd566dbdaefbac9e9dda8fba3173dbd918444d9d05c30b3db01d8 SHA512 6f1ebb0dd036865f817d0c3651b4d6739967814778aecfa7039a1f7e5eb04c9258f030d94924ec2ebb56ad14c42c774b29ea17396fed4d7d68cb3262fec0364c
+EBUILD gnome-boxes-42.3.ebuild 3853 BLAKE2B 9d3dab4e21c33ecdb5ef733afa2614b31bb89117a777fc3ea89bfec730ac046d4ef2c2216bbddcd71844bcfe2a19a270f8bc75286aa5748772479b7c7a26d064 SHA512 ef898a44103bcc5219833dd786702e72aa49aaf40d69a2f5a00981f22065a3a93f4f300a0416eab67150d1a0127e8685979c63c5198ac74bda61ecd61cad9227
 MISC metadata.xml 254 BLAKE2B de7a97001e5947704f42973c8a0c3a23c2d80afb976254f5fd21e9d372a946e055d4cdc3c0eaed010505f87929b56e8b1e650c945e2a302644adbc9440833be8 SHA512 c81da4f9b80e5691a167f4590906952e25356604ec17689c005be14efb394c0634776bbe84df936edde239480bdf46db41216b00da4a3a45f670e9ca18ab0132
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-42.1.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-42.1.ebuild
index 52f6b07c7db3..4d6d803a385d 100644
--- a/gnome-extra/gnome-boxes/gnome-boxes-42.1.ebuild
+++ b/gnome-extra/gnome-boxes/gnome-boxes-42.1.ebuild
@@ -13,7 +13,7 @@ LICENSE="LGPL-2+ CC-BY-2.0"
 SLOT="0"
 
 IUSE="rdp"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 
 # FIXME: qemu probably needs to depend on spice[smartcard] directly with USE=spice
 # FIXME: Check over libvirt USE=libvirtd,qemu and the smartcard/usbredir requirements
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-42.3.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-42.3.ebuild
new file mode 100644
index 000000000000..52f6b07c7db3
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-42.3.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils linux-info meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Simple GNOME application to access remote or virtual systems"
+HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
+
+LICENSE="LGPL-2+ CC-BY-2.0"
+SLOT="0"
+
+IUSE="rdp"
+KEYWORDS="~amd64"
+
+# FIXME: qemu probably needs to depend on spice[smartcard] directly with USE=spice
+# FIXME: Check over libvirt USE=libvirtd,qemu and the smartcard/usbredir requirements
+# Technically vala itself still ships a libsoup vapi, but that may change, and it should be better to use the .vapi from the same libsoup version
+# gtk-vnc raised due to missing vala bindings in earlier ebuilds
+DEPEND="
+	>=app-arch/libarchive-3.0.0:=
+	>=dev-libs/glib-2.52:2
+	>=x11-libs/gtk+-3.24.1:3
+	>=net-libs/gtk-vnc-0.8.0-r1[gtk3(+)]
+	>=gui-libs/libhandy-1.5.0:1=
+	>=sys-libs/libosinfo-1.7.0
+	app-crypt/libsecret
+	>=net-libs/libsoup-2.44:2.4
+	virtual/libusb:1
+	>=app-emulation/libvirt-glib-4.0.0
+	>=dev-libs/libxml2-2.7.8:2
+	>=net-misc/spice-gtk-0.32[gtk3(+),smartcard,usbredir]
+	app-misc/tracker:3
+	>=net-libs/webkit-gtk-2.26.0:4
+
+	>=dev-libs/gobject-introspection-1.56:=
+	>=dev-libs/libgudev-165:=
+	rdp? ( >=net-misc/freerdp-2.0.0:= )
+" # gobject-introspection needed for libovf subproject (and gtk-frdp subproject with USE=rdp)
+# These are called via exec():
+# sys-fs/mtools mcopy for unattended file copying for files that libarchive doesn't support
+# app-cdr/cdrtools mkisofs is needed for unattended installer secondary disk image creation
+# app-emulation/libguestfs virt-sysprep is used for VM cloing, if not there, it logs debug and doesn't function
+# sys-apps/policycoreutils restorecon is used for checking selinux context
+# app-emulation/libvirt virsh used for various checks (and we need the library anyways)
+# sys-auth/polkit used for making all libvirt system disks readable via "pkexec chmod a+r" that aren't already readable to the user (libvirt system importer)
+# app-emulation/qemu qemu-img used to convert image to QCOW2 format during copy
+RDEPEND="${DEPEND}
+	app-cdr/cdrtools
+	app-misc/tracker-miners:3[iso]
+	app-emulation/spice[smartcard]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
+	sys-fs/mtools
+	sys-auth/polkit
+"
+# gtk-frdp generates gir and needs gtk+ introspection for it
+# This is only needed for creating the .vapi file, but gnome-boxes needs it
+BDEPEND="
+	$(vala_depend)
+	net-libs/gtk-vnc[vala]
+	sys-libs/libosinfo[vala]
+	app-crypt/libsecret[vala]
+	net-libs/libsoup:2.4[vala]
+	app-emulation/libvirt-glib[vala]
+	net-misc/spice-gtk[vala]
+	x11-libs/vte:2.91[vala]
+	dev-libs/appstream-glib
+	rdp? ( x11-libs/gtk+:3[introspection] )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Before running gnome-boxes for local VMs, you will need to load the KVM modules.
+If you have an Intel Processor, run:
+# modprobe kvm-intel
+
+If you have an AMD Processor, run:
+# modprobe kvm-amd"
+
+pkg_pretend() {
+	linux-info_get_any_version
+
+	if linux_config_exists; then
+		if ! { linux_chkconfig_present KVM_AMD || \
+			linux_chkconfig_present KVM_INTEL; }; then
+			ewarn "You need KVM support in your kernel to use GNOME Boxes local VM support!"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddistributor_name=Gentoo
+		-Ddistributor_version=${PVR}
+		$(meson_use rdp)
+		-Dinstalled_tests=false
+		-Dflatpak=false
+		-Dprofile=default
+		-Duefi=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}