gentoo resync : 25.08.2020

1 files changed, 47 insertions, 0 deletions

diff --git a/gnome-extra/gnome-color-manager/gnome-color-manager-3.36.0.ebuild b/gnome-extra/gnome-color-manager/gnome-color-manager-3.36.0.ebuild
new file mode 100644
index 000000000000..117633a19538
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/gnome-color-manager-3.36.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org meson virtualx xdg
+
+DESCRIPTION="GNOME color profile tools"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-color-manager/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Need gtk+-3.3.8 for https://bugzilla.gnome.org/show_bug.cgi?id=673331
+RDEPEND="
+	>=dev-libs/glib-2.31.10:2
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-misc/colord-1.3.1:0=
+	>=media-libs/lcms-2.2:2
+"
+DEPEND="${RDEPEND}"
+# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
+BDEPEND="
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-remove-libcanberra-include.patch # should be in next upstream release
+)
+
+src_configure() {
+	# Always enable tests since they are check_PROGRAMS anyway
+	local emesonargs=(
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}