reinit the tree, so we can have metadata

4 files changed, 263 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
new file mode 100644
index 000000000000..23a929000aed
--- /dev/null
+++ b/kde-apps/k3b/Manifest
@@ -0,0 +1,5 @@
+DIST k3b-17.04.3.tar.xz 10568048 SHA256 d3d5ef74df0f6a15e4d0238d502d49af09909f4392fe80f35e5cc7a223983028 SHA512 4bcd9977c46da66172b30c69922698a4f1f60176c6435a99969cca215bf3baf72f9f70e25da0500145b7a377f5b80b02f0fcf1a3a8145d8d51e1ae54370c9be7 WHIRLPOOL 34f31f542ecf022f4f99fb2f4acb185573a00b6df29413a61c1f6da3c07eb574498e0090f6db1b84824640e162c9550c7aa8f60dd07e88bf635cdef33659df58
+DIST k3b-17.08.1.tar.xz 10565672 SHA256 41ba0753b295e22bffade095e9fe665a2018d295fffa763cbbee644cd57568df SHA512 3cbe1deb85f5b641866948949e051e1d7452917a83d7d4dbe7ef8764d2e13457eb8461f548ba0b4394ddf33491995af5e85fd092636d394d1f15157f9f9837ca WHIRLPOOL b7e6e270bb3c76bc31dd965b0aeac549135f58bac82df05d4e31e74fef4e31f11c291f3a2a5dae96b11906dbe2459557deff1fc5bce2c8906e1cfd84f9b9ec98
+EBUILD k3b-17.04.3-r1.ebuild 3321 SHA256 4bc4e19837e8bd3e31fe1957ebdcafcfc3ab777502cc533f28606c76187dad7f SHA512 8bce8952193c12d48473d354c6fa3db7cf19f8bb8ecf1c6ef87a7f7381e98c7d28df298d7c09ecd5f4fc84690dfb21fb84530ffa6464fa378ade8575bd88f1b2 WHIRLPOOL 8a2d3a2ef98bd3f7e54bd87aa56b4378b1da4b18919bff706badd38d970766cbc09b64dcb3ac758ae209e4472a3528a122bd6ced505bf8603a3b7b3a64ebea83
+EBUILD k3b-17.08.1.ebuild 3409 SHA256 eea7dc14692ce733372e0a731edeaef010341769c83c78db76a17f0a2d160b95 SHA512 7d572fedae467d32ebc20f6cd20c29fe26c3373608eba1182f93aa5f19383ec4e3def6afc6265ae42a39941dab791cebcf4e1171a380c75299485444251bd081 WHIRLPOOL 9aad9187619841e6d29d217afaf6b6ec84e4deef23ebc5e0407874cdaf8b6051e332c108f464606b586cdf5d8499ec20679a871ee5d1533e90d9d670e313ecc8
+MISC metadata.xml 334 SHA256 6e29a2f1763d1446464c819b9e66cb7bdc3a1739e66efbd6628169ce93cfdf62 SHA512 16203cd75177004bb4844f67659dc7370c12e216871272ff8f781ed11172e72271b15f347ad6d59354ef077ebab1fad2bc150f3e2388f370b660b2d2adcb0faa WHIRLPOOL 3ea8e67fea8881df690d03780fb8a6a19d4884fbec30ec034e91d4bd20ec07fb50acf4afbdf2da471a7a032e72b9ba84da13796520661302f84de02d58fe842f
diff --git a/kde-apps/k3b/k3b-17.04.3-r1.ebuild b/kde-apps/k3b/k3b-17.04.3-r1.ebuild
new file mode 100644
index 000000000000..03384a4c09b1
--- /dev/null
+++ b/kde-apps/k3b/k3b-17.04.3-r1.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="http://www.k3b.org/"
+
+LICENSE="GPL-2 FDL-1.2"
+KEYWORDS="amd64 x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kfilemetadata 'taglib?')
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? ( media-libs/libvorbis )
+	webkit? ( $(add_qt_dep qtwebkit) )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}
diff --git a/kde-apps/k3b/k3b-17.08.1.ebuild b/kde-apps/k3b/k3b-17.08.1.ebuild
new file mode 100644
index 000000000000..dea185af5a78
--- /dev/null
+++ b/kde-apps/k3b/k3b-17.08.1.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+KEYWORDS="~amd64 ~x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kfilemetadata 'taglib?')
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? ( media-libs/libvorbis )
+	webkit? ( $(add_qt_dep qtwebkit) )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	kde5_src_configure
+}
+
+src_test() {
+	# 628166
+	local myctestargs=(
+		-E "(k3bdeviceglobalstest)"
+	)
+
+	kde5_src_test
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}
diff --git a/kde-apps/k3b/metadata.xml b/kde-apps/k3b/metadata.xml
new file mode 100644
index 000000000000..cc7344ef5c21
--- /dev/null
+++ b/kde-apps/k3b/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<use>
+		<flag name="emovix">Enable burning support for eMoviX images</flag>
+	</use>
+</pkgmetadata>