gentoo resync : 25.04.2020

1 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/step/step-20.04.0.ebuild b/kde-apps/step/step-20.04.0.ebuild
new file mode 100644
index 000000000000..71820cdce4f1
--- /dev/null
+++ b/kde-apps/step/step-20.04.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=5.69.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Interactive physics simulator"
+HOMEPAGE="https://kde.org/applications/education/org.kde.step
+https://edu.kde.org/step/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="+gsl nls +qalculate"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtopengl-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-cpp/eigen-3.2:3
+	sci-libs/cln
+	gsl? ( sci-libs/gsl:= )
+	qalculate? ( >=sci-libs/libqalculate-0.9.5:= )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# FIXME: Drop duplicate upstream
+	sed -e '/find_package.*Xml Test/ s/^/#/' \
+		-i stepcore/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package gsl GSL)
+		$(cmake_use_find_package qalculate Qalculate)
+	)
+	ecm_src_configure
+}