gentoo auto-resync : 15:02:2024 - 23:36:26

1 files changed, 66 insertions, 0 deletions

diff --git a/kde-misc/colord-kde/colord-kde-23.08.5.ebuild b/kde-misc/colord-kde/colord-kde-23.08.5.ebuild
new file mode 100644
index 000000000000..28c74f8cfdc6
--- /dev/null
+++ b/kde-misc/colord-kde/colord-kde-23.08.5.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY=graphics
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Provides interfaces and session daemon to colord"
+HOMEPAGE="https://invent.kde.org/graphics/colord-kde"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="X"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5[qml]
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	media-libs/lcms:2
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-libs/kirigami-addons:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	kde-plasma/kde-cli-tools:*
+	x11-misc/colord
+"
+
+PATCHES=( "${FILESDIR}/${PN}-23.08.3-without_x11.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITHOUT_X11=$(usex !X)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	if ! has_version "gnome-extra/gnome-color-manager"; then
+		elog "You may want to install gnome-extra/gnome-color-manager to add support for"
+		elog "colorhug calibration devices."
+	fi
+}