gentoo auto-resync : 21:06:2023 - 01:17:50

2 files changed, 180 insertions, 0 deletions

diff --git a/kde-plasma/plasma-desktop/Manifest b/kde-plasma/plasma-desktop/Manifest
index 9c759ac03ea2..b63819370c56 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,4 +1,6 @@
 DIST plasma-desktop-5.27.5.tar.xz 14361248 BLAKE2B cf8efedc79c9ca24c7f267c02fa51af2680ef130eba702855e6a1a75537b55b266206bd1c0b5ca4c99779ff5d9a567c5da74d3c58f5320c39c9bd322e642f9e9 SHA512 2dee9d068b0a4ffaccffe6175f8c9833451d2235837d3187ee3f5bf62e0024d48ff50884b7708b914e0e383471e83b9ba969c84103d5351e1b8583a04ec703fb
+DIST plasma-desktop-5.27.6.tar.xz 14359772 BLAKE2B 56ad1ccdaaf0f84ff10b42af2a01dd80bff3f4a476827eab38eae70a295962fde498aee403da310af3fc409a33dac00f2e45a317ad2b8e6455e3f4257539e065 SHA512 b1524c54b1ff5d45ae56883fef2fe34927991eba4b28e697867a1097baa8d6a235fc38e11385b1f02c78c5700e669ad902a721c089bb571accb13fd734c1fdb1
 DIST plasma-desktop-override-include-dirs-2.tar.xz 8324 BLAKE2B 5ddf9340edf6b6fa76e80158a982ac887b0fb464bc40d5bc4dcd3d6b8f5a87c2d6ecdd153e67e168454aa7faff8d84defb90ba16096b64f3af1e7a74570a00c6 SHA512 452923555bd419d3e389e808c4c9ea35e48795d4f0d78c5845aea677e21f594068540538a8968c2d4034aacb11e910a7b69908e10518eba486ebcc0dda39221a
 EBUILD plasma-desktop-5.27.5.ebuild 5273 BLAKE2B 7313589d6a538dcf38de9df757f08b5fc8db469cf32fe73b9fdea873a2d463e97f788e5831b5366d29dc0225c6d28bbc3cbbc3b2d8dd81ec6bf5d8fc06d98fa3 SHA512 d3c0438eb9ae23357b6b3d320af9e8694ad1a4a7e7c42e453937725552806be41cafc831edc13a8454644b0d0e118a0cda828438c8cd52a3eb2670c36c78279b
+EBUILD plasma-desktop-5.27.6.ebuild 5251 BLAKE2B fa13416ed0c4a63c987d41243fda530700153546a0df4350a9c35702fb2efad880b8d6da182133e6d6f7e8f662ad7e6aa13f32bf143ecfddeca9bde0d08e25d7 SHA512 6cf013fb7c142268c138c4015667028c5a22a9d33302f1211e3743a18584d362128b29a714560e1bfa988480eae68d3ed047a1ece65af0c79c948fb38fc013d7
 MISC metadata.xml 560 BLAKE2B bf6910f40706c17989a0961c39073bd1bb00575b0bbd12c9a44c5ae8c699b33451dac36512afe8310c4bff5432864d16adb0f5b6b3f933b39705409547b05ee5 SHA512 0f34c3e91789674538cbac7f857ef57db8e1ca9b85b7e5d512b1a6af10fb218bfae01f65ae1825d26bb31103e7b95c0cf68fc3965c40952392afafcbf5877a25
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.27.6.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.27.6.ebuild
new file mode 100644
index 000000000000..cbde53a26fd7
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.27.6.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-2"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="ibus +kaccounts scim screencast +semantic-desktop"
+
+# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5[screencast?]
+	>=media-libs/phonon-4.11.0
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	kaccounts? (
+		kde-apps/kaccounts-integration:5
+		net-libs/accounts-qt
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/wayland-protocols-1.25
+	dev-libs/boost
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/kdeplasma-addons-5.25.50
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	media-fonts/noto-emoji
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	x11-misc/xdg-user-dirs
+	kaccounts? ( net-libs/signon-oauth2 )
+	screencast? ( >=kde-plasma/kpipewire-${PVCUT}:5 )
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${WORKDIR}/${XORGHDRS}/${PN}-5.25.80-override-include-dirs.patch" # downstream patch
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use ibus; then
+		sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+			-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use scim; then
+		sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON # not packaged
+		-DEVDEV_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		-DSYNAPTICS_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+		$(cmake_use_find_package ibus GLIB2)
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# test_kio_fonts needs D-Bus, bug #634166
+	# lookandfeel-kcmTest is unreliable for a long time, bug #607918
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "screen reader support" app-accessibility/orca
+	fi
+	ecm_pkg_postinst
+}