gentoo resync : 02.02.2022

2 files changed, 119 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 7d76eddd2b1f..674fa04b9c04 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,3 +1,5 @@
 DIST lxqt-panel-0.17.1.tar.xz 510212 BLAKE2B fec84d1758ba1824c5c77ba730040e2d662f97c08b48378acc2efff53237cb993d1543918429224be1e5ba539a8de96b91f3a9ba4e1095fa69fe3c72e26d5156 SHA512 439905144029518e46efdd72eb3db17203678e243ca5f7090bf5db902805deaded41f6c59d02bf538fbf24b7951d6da6a924331c685b69d162812249fb9a4e72
+DIST lxqt-panel-1.0.0.tar.xz 539116 BLAKE2B b11a51ad448331bd58c87cdc2596f83a472301981e57f962b9da883cfd2465b024b64932252a3a575af250e37a313dbf1bf36dd52d265272e01c9e60c41456bd SHA512 8ee7593beb5a863f71e6314f03981ef769b6f64605e4212a2b2ae147959bf30d2137415477d6f23afc2591a639c7f21651ac844d95226af18a2d8ae141f29b62
 EBUILD lxqt-panel-0.17.1-r1.ebuild 2914 BLAKE2B 12cd45ab2e86b9ee2ad7cd7457f69ecc92de6d17f6a3d28806de4cf16c3a7450786744bc1e7556348c7d7ba2a385a032adfbecc29368ca4add098984cc483085 SHA512 fd23b6650eb8eee3599b81dacde5fa07429a43c9cd01c27d903b7f12cba6c5a98ff2ab8a11a5966b62b7ddf8537e0ede1cc8f2c12c6e3d9f50b4dd38e89e6b13
+EBUILD lxqt-panel-1.0.0.ebuild 2987 BLAKE2B e09dd2d116d8b262bf79c6d2af4abaa6eb841755531df351ea8f3b1d581bd0190308b39931ebf068358a7dfc8b250eacaa059866e20dffcc1843381c20e8d088 SHA512 d7f27fdfa13430cef3311a23e3933109d056ab97df77a07edb525d7940cbbc93bdaeead2a3628cddc7e04312c77c719223caeb71dd7ee11c2cd8f5617d4910d6
 MISC metadata.xml 1320 BLAKE2B 3e932f653506f6ad90453214383eaa94eb32da594c76af60270426544a3bac1ef87dd34204a6c786510e3a00f9e143c92e956b46d7613da343f2030f01b8d9aa SHA512 b68531439f0600dbc28389ee25548dbaa8f85109ea45ba4f6e588c1d49b374d5b27745a517ac508d15d0c48c3b003fa97243cb50eb81177bea6ebcd2713d5809
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-1.0.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-1.0.0.ebuild
new file mode 100644
index 000000000000..4d81053dc420
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-1.0.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
++mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
++spacer +statusnotifier sysstat +taskbar tray +volume +worldclock"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.10.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-qt[qt5(+)]
+		>=dev-qt/qtconcurrent-5.15:5
+	)
+	sysstat? ( >=lxqt-base/libsysstat-0.4.6 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}