gentoo auto-resync : 15:07:2024 - 12:27:33

3 files changed, 315 insertions, 0 deletions

diff --git a/mail-mta/Manifest.gz b/mail-mta/Manifest.gz
index 36af55cf767f..ce65992f9bb3 100644
--- a/mail-mta/Manifest.gz
+++ b/mail-mta/Manifest.gz
diff --git a/mail-mta/courier/Manifest b/mail-mta/courier/Manifest
index e5d8635b7bb8..95d179854d3e 100644
--- a/mail-mta/courier/Manifest
+++ b/mail-mta/courier/Manifest
@@ -6,9 +6,11 @@ DIST courier-1.2.3.tar.bz2 7842828 BLAKE2B eac13d5c36279df1533af1e62e6b7b9fe0d50
 DIST courier-1.3.5.tar.bz2 7901040 BLAKE2B 5a79d02d1d40967f98f2a1942fee6786d8e6e2ddc7dea6677a85db0480f71e4b974a671adc81c4bafd66c888c5b54012eb5684f2936f5164496699939d179fc4 SHA512 5f51383356f4a36f9c114be6aa69d694c82bb95b1a336d2948d486d582bd6559da69be93b7c20aee2ff57826ab7eeb265aa20794074456d036b22da7f280f95d
 DIST courier-1.3.7.tar.bz2 7900951 BLAKE2B 4be8194554f27d3d8cb822c5f8451dc61afca1255cbb0c92289314a953ea2a173b3dfd59b44f1f8bbcb6ef67367420cc6f6c44327527efee01e49ecee40ae789 SHA512 ee73120cc6f7bf54480af575f3cb522e5035ba4d3e957a1799bcf064c06159c9c888f4f26334464ba088e06d6e13a96611f93123439bda12200a1a71860b8d6a
 DIST courier-1.3.8.tar.bz2 7901606 BLAKE2B 2c8da2e905fa4aa273715dd84f80b76d8f095414169b3454a9b1cacfeae6d4c89ad6db95a3ac2927b709395ac7119b1c21df1b140f5cb393e431fec10b2e60f9 SHA512 30d09e9c0ae729ed5e7f3f28ef98841db3c71fabb61017319e76a8a8cc6e77b91a6a6dc40515c645f48dcd1d9b144d2c84c78df955b50cb9a0856e4734c0a265
+DIST courier-1.3.9.tar.bz2 7900486 BLAKE2B 18fc3573b75c3ac08fd88eead16a604d0e32fd8ba5390a35baa38cf86d5f99814979e76b74345c2c29d76d92b6331f7481dab9197ba008714b4e1e31f1c7135e SHA512 9b6b503efbcbe847bfb7211954a78a820f549b5c6d13179421ca5e016f3bf85d8c03facf8a17edfc6288974e8946893f4175cd2c2084f28148a67b5eee3ac983
 EBUILD courier-1.2.3-r1.ebuild 9271 BLAKE2B b5b00c8837cbeb2539af4db461c4bba6e837fad8bbc6a3b8af558ba834da2b4eb3a459ae0a95ce0caf57b22cec5f7dd770c0b59da906ac51b0dfa8c117327a1e SHA512 ebca062d3a6821e46cda3d73f0b0c32ba5434e13295dd8a3ee816073d3f15b9dc969cf8baf847957784767e1eeda889bbb2589be0160bf3fe805267fae250707
 EBUILD courier-1.3.5.ebuild 9316 BLAKE2B a2a3327506ba45fd2d317092c598c0146d82c3f659a13bb925bf839d75a92e27a80dc74dac8b62b66b25137b155401fb6dea4cb7dca3e990c036ae2aedc90505 SHA512 3764af68a579a7264172dbc936fd4f0fb1fd4dc6a6fcb498ac6e7dfcb1f87c47c5f28877323d6394bf0fdc966ee6b8cb252cd25597e1771b93c781f059690832
 EBUILD courier-1.3.7.ebuild 9322 BLAKE2B 844b42d9fc44f7c18655b78f8a11aba5c257063b551df3f8d37deb64f4c52381b17c62af7953e537d8ff53610b82b00d6438f965afc381c3beb1788ba6656930 SHA512 ee0caf8d782cfd1aec20896ec2c847cf67970303e6458e609a9e489a2f8cd7b6e5b7365f1f2365fdbffc7f91da0eef15ba8b00cb056dbcfa9800d57f56e0b9c9
 EBUILD courier-1.3.8-r1.ebuild 9324 BLAKE2B 205c70c4e8a553f8371e1a1847e9a677216c6f4734a7d285da12b1d4b050d1c199e79e1d7fdfb8e09cae27157060f34fa3b99ef9a65de9cf20d4403f0fb53ee5 SHA512 3f64fea93078502cde75dfd601e289cccdbcecde13cbc1d382c56f5ff961f78f390203a1eb0e9a0c8442fb565656d12219659124823690af590a4d619bde6718
 EBUILD courier-1.3.8.ebuild 9322 BLAKE2B 844b42d9fc44f7c18655b78f8a11aba5c257063b551df3f8d37deb64f4c52381b17c62af7953e537d8ff53610b82b00d6438f965afc381c3beb1788ba6656930 SHA512 ee0caf8d782cfd1aec20896ec2c847cf67970303e6458e609a9e489a2f8cd7b6e5b7365f1f2365fdbffc7f91da0eef15ba8b00cb056dbcfa9800d57f56e0b9c9
+EBUILD courier-1.3.9.ebuild 9324 BLAKE2B 205c70c4e8a553f8371e1a1847e9a677216c6f4734a7d285da12b1d4b050d1c199e79e1d7fdfb8e09cae27157060f34fa3b99ef9a65de9cf20d4403f0fb53ee5 SHA512 3f64fea93078502cde75dfd601e289cccdbcecde13cbc1d382c56f5ff961f78f390203a1eb0e9a0c8442fb565656d12219659124823690af590a4d619bde6718
 MISC metadata.xml 756 BLAKE2B e3d128790b1620d9005c9a14cef1c452488fc8e465b235791cc196f431cb2ea8348aba342b0867282878d0c73392694be0db0686dc048d9345b286c3bccf1cab SHA512 c3fcd1ba4b22f91b1acf49faeee41562a7963b51d37e1593156086b79a1eb4172a12e7226b71a9aa55b5a4ef7d734351752451a2300375d061ae20481778b273
diff --git a/mail-mta/courier/courier-1.3.9.ebuild b/mail-mta/courier/courier-1.3.9.ebuild
new file mode 100644
index 000000000000..078cce65251a
--- /dev/null
+++ b/mail-mta/courier/courier-1.3.9.ebuild
@@ -0,0 +1,313 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="An MTA designed specifically for maildirs"
+HOMEPAGE="https://www.courier-mta.org/"
+SRC_URI="https://downloads.sourceforge.net/courier/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="postgres ldap mysql pam nls ipv6 spell fax crypt norewrite \
+	fam web webmail gnutls split-usr"
+
+DEPEND="
+	>=net-libs/courier-authlib-0.72.1
+	>=net-libs/courier-unicode-2.3.0:=
+	net-dns/libidn2:=
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	>=sys-libs/gdbm-1.8.0:=
+	dev-libs/libpcre2
+	app-misc/mime-types
+	dev-lang/perl:=
+	fax? ( >=media-libs/netpbm-9.12 app-text/ghostscript-gpl >=net-dialup/mgetty-1.1.28 )
+	pam? ( sys-libs/pam )
+	mysql? ( dev-db/mysql-connector-c )
+	ldap? ( >=net-nds/openldap-1.2.11:= )
+	postgres? ( dev-db/postgresql:= )
+	spell? ( app-text/aspell )
+	fam? ( virtual/fam )
+	!mail-filter/maildrop
+	!mail-mta/esmtp
+	!mail-mta/exim
+	!mail-mta/msmtp[mta]
+	!mail-mta/netqmail
+	!mail-mta/nullmailer
+	!mail-mta/postfix
+	!mail-mta/sendmail
+	!mail-mta/ssmtp[mta]
+	!mail-mta/opensmtpd
+	!net-mail/dot-forward
+	!sys-apps/ucspi-tcp
+	"
+
+RDEPEND="${DEPEND}
+	sys-process/procps"
+
+# get rid of old style virtual/imapd - bug 350792
+# all blockers really needed?
+RDEPEND="${RDEPEND}
+	!net-mail/courier-imap
+	!net-mail/cyrus-imapd"
+
+PDEPEND="pam? ( net-mail/mailbase )
+	crypt? ( >=app-crypt/gnupg-1.0.4 )"
+
+src_prepare() {
+	use norewrite && eapply "${FILESDIR}/norewrite.patch"
+	default
+}
+
+src_configure() {
+	filter-flags '-fomit-frame-pointer'
+
+	local myconf
+	myconf=""
+
+	use ldap && myconf="${myconf} --with-ldapconfig=/etc/courier/maildropldap.conf"
+
+	econf ${myconf} \
+		$(use_with fam) \
+		$(use_with ipv6) \
+		$(use_with spell ispell) \
+		$(use_with ldap ldapaliasd) \
+		$(use_enable ldap maildroldap) \
+		$(use_with gnutls) \
+		--with-notice=unicode \
+		--enable-mimetypes=/etc/mime.types \
+		--prefix=/usr \
+		--disable-root-check \
+		--mandir=/usr/share/man \
+		--sysconfdir=/etc/courier \
+		--datadir=/usr/share/courier \
+		--sharedstatedir=/var/lib/courier/com \
+		--localstatedir=/var/lib/courier \
+		--with-piddir=/var/run/courier \
+		--with-authdaemonvar=/var/lib/courier/authdaemon \
+		--with-mailuser=mail \
+		--with-mailgroup=mail \
+		--with-paranoid-smtpext \
+		--with-db=gdbm \
+		--disable-autorenamesent \
+		--cache-file="${S}/configuring.cache" \
+		--host="${CHOST}" debug=true || die "./configure"
+}
+
+src_compile() {
+	default
+}
+
+etc_courier() {
+	# Import existing /etc/courier/file if it exists.
+	# Add option only if it was not already set or even commented out
+	local file="${1}" word=$(echo "${2}" | sed -e "s|=.*$||" -e "s|^.*opt ||")
+	[ ! -e "${D}/etc/courier/${file}" ] && [ -e "/etc/courier/${file}" ] && \
+			cp "/etc/courier/${file}" "${D}/etc/courier/${file}"
+	grep -q "${word}" "${D}/etc/courier/${file}" || \
+		echo "${2}" >> "${D}/etc/courier/${file}"
+}
+
+etc_courier_chg() {
+	local file="${1}" key="${2}" value="${3}" section="${4}"
+	[ -z "${section}" ] && section="${2}"
+	grep -q "${key}" "${file}" && elog "Changing ${file}: ${key} to ${value}"
+	sed -i -e"/\#\#NAME: ${section}/,+30 s|${key}=.*|${key}=\"${value}\"|g" ${file}
+}
+
+src_install() {
+	local f
+	diropts -o mail -g mail
+	keepdir /var/lib/courier/tmp
+	keepdir /var/lib/courier/msgs
+	make install DESTDIR="${D}" || die "install"
+	make install-configure DESTDIR="${D}" || die "install-configure"
+
+	# init script takes care of this
+	rm -rf "${D}/var/run"
+
+	# Get rid of files we dont want
+	if ! use webmail ; then
+		rm -rf "${D}/usr/$(get_libdir)/courier/courier/webmail" \
+			"${D}/usr/$(get_libdir)/courier/courier/sqwebmaild" \
+			"${D}/usr/share/courier/sqwebmail/" \
+			"${D}/usr/sbin/webmaild" \
+			"${D}/usr/sbin/webgpg" \
+			"${D}/etc/courier/webmail.authpam" \
+			"${D}/var/lib/courier/webmail-logincache" \
+			"${D}"/etc/courier/sqwebmaild*
+	fi
+
+	if ! use web ; then
+		rm -rf "${D}/usr/share/courier/courierwebadmin/" \
+			"${D}/etc/courier/webadmin"
+	fi
+
+	for dir2keep in $(cd "${D}" && find ./var/lib/courier -type d) ; do
+		keepdir "$dir2keep" || die "failed running keepdir: $dir2keep"
+	done
+
+	newinitd "${FILESDIR}/courier-init-r4" "courier"
+	use fam || sed -i -e's|^.*use famd$||g' "${D}/etc/init.d/courier"
+
+	cd "${D}/etc/courier"
+	if use webmail ; then
+		insinto /etc/courier
+		newins "${FILESDIR}/apache-sqwebmail.inc" apache-sqwebmail.inc
+	fi
+
+	for f in *.dist ; do cp "${f}" "${f%%.dist}" ; done
+	if use ldap ; then
+		[ -e ldapaliasrc ] &&  ( chown root:mail ldapaliasrc ; chmod 640 ldapaliasrc )
+	else
+		rm -f ldapaliasrc
+	fi
+
+	( [ -e /etc/courier/sizelimit ] && cat /etc/courier/sizelimit || echo 0 ) \
+		> "${D}/etc/courier/sizelimit"
+	etc_courier maildroprc ""
+	etc_courier esmtproutes ""
+	etc_courier backuprelay ""
+	etc_courier locallowercase ""
+	etc_courier bofh "opt BOFHBADMIME=accept"
+	etc_courier bofh "opt BOFHSPFTRUSTME=1"
+	etc_courier bofh "opt BOFHSPFHELO=pass,neutral,unknown,none,error,softfail,fail"
+	etc_courier bofh "opt BOFHSPFHELO=pass,neutral,unknown,none"
+	etc_courier bofh "opt BOFHSPFFROM=all"
+	etc_courier bofh "opt BOFHSPFMAILFROM=all"
+	etc_courier bofh "#opt BOFHSPFHARDERROR=fail"
+	etc_courier esmtpd "BOFHBADMIME=accept"
+	etc_courier esmtpd-ssl "BOFHBADMIME=accept"
+	etc_courier esmtpd-msa "BOFHBADMIME=accept"
+
+	use fam && etc_courier_chg imapd IMAP_CAPABILITY "IMAP4rev1 UIDPLUS CHILDREN NAMESPACE THREAD=ORDEREDSUBJECT THREAD=REFERENCES SORT QUOTA AUTH=CRAM-MD5 AUTH=CRAM-SHA1 AUTH=CRAM-SHA256 IDLE"
+	use fam || etc_courier_chg imapd IMAP_CAPABILITY "IMAP4rev1 UIDPLUS CHILDREN NAMESPACE THREAD=ORDEREDSUBJECT THREAD=REFERENCES SORT QUOTA AUTH=CRAM-MD5 AUTH=CRAM-SHA1 AUTH=CRAM-SHA256"
+
+	# Fix for a sandbox violation on subsequential merges
+	# - ticho@gentoo.org, 2005-07-10
+	dosym ../share/courier/pop3d /usr/sbin/courier-pop3d
+	dosym ../share/courier/pop3d-ssl /usr/sbin/courier-pop3d-ssl
+	dosym ../share/courier/imapd /usr/sbin/courier-imapd
+	dosym ../share/courier/imapd-ssl /usr/sbin/courier-imapd-ssl
+
+	cd "${S}"
+	cp imap/README README.imap
+	use nls && cp unicode/README README.unicode
+	dodoc AUTHORS BENCHMARKS COPYING* ChangeLog* INSTALL NEWS README* TODO courier/doc/*.txt
+	dodoc libs/tcpd/README.couriertls
+	mv "${D}/usr/share/courier/htmldoc" "${D}/usr/share/doc/${PF}/html"
+
+	if use webmail ; then
+		insinto /usr/$(get_libdir)/courier/courier
+		insopts -m 755 -o mail -g mail
+		doins "${S}/courier/webmaild"
+	fi
+
+	if use web ; then
+		insinto /etc/courier/webadmin
+		insopts -m 400 -o mail -g mail
+		doins "${FILESDIR}/password.dist"
+	fi
+
+	# avoid name collisions in /usr/sbin, make webadmin match
+	cd "${D}/usr/sbin"
+	for f in imapd imapd-ssl pop3d pop3d-ssl ; do mv "${f}" "courier-${f}" ; done
+	if use web ; then
+		sed -i -e 's:\$sbindir\/imapd:\$sbindir\/courier-imapd:g' \
+			-e 's:\$sbindir\/imapd-ssl:\$sbindir\/courier-imapd-ssl:g' \
+			"${D}/usr/share/courier/courierwebadmin/admin-40imap.pl" \
+			|| ewarn "failed to fix webadmin"
+		sed -i -e 's:\$sbindir\/pop3d:\$sbindir\/courier-pop3d:g' \
+			-e 's:\$sbindir\/pop3d-ssl:\$sbindir\/courier-pop3d-ssl:g' \
+			"${D}/usr/share/courier/courierwebadmin/admin-45pop3.pl" \
+			|| ewarn "failed to fix webadmin"
+	fi
+
+	# users should be able to send mail. Could be restricted with suictl.
+	chmod u+s "${D}/usr/bin/sendmail"
+
+	if use split-usr; then
+		dosym ../bin/sendmail /usr/sbin/sendmail
+	fi
+}
+
+src_test() {
+	if [ `whoami` != 'root' ]; then
+		# Disable valgrind checks
+		echo '#!/bin/sh' > libs/imap/testsuitevalgrind
+		echo '#!/bin/sh' > libs/maildir/testsuitevalgrind
+		sed -i -e 's:VALGRIND=:exit 0 #VALGRIND=:g' libs/maildrop/Makefile*
+		emake -j1 check
+	else
+		einfo "make check skipped, can't run as root."
+		einfo "You can enable it with FEATURES=\"userpriv\""
+	fi
+}
+
+pkg_postinst() {
+	use fam && elog "fam daemon is needed for courier-imapd" \
+		|| ewarn "courier was built without fam support"
+}
+
+pkg_config() {
+	mailhost="$(hostname)"
+	export mailhost
+
+	domainname="$(domainname)"
+	if [ "x$domainname" = "x(none)" ] ; then
+		domainname="$(echo ${mailhost} | sed -e "s/[^\.]*\.\(.*\)/\1/")"
+	fi
+	export domainname
+
+	if [[ -z "${ROOT}" ]] ; then
+		file="${ROOT}/etc/courier/locals"
+		if [ ! -f "${file}" ] ; then
+			echo "localhost" > "${file}";
+			echo "${domainname}" >> "${file}";
+		fi
+		file="${ROOT}/etc/courier/esmtpacceptmailfor.dir/${domainname}"
+		if [ ! -f "${file}" ] ; then
+			echo "${domainname}" > "${file}"
+			/usr/sbin/makeacceptmailfor
+		fi
+
+		file="${ROOT}/etc/courier/smtpaccess/${domainname}"
+		if [ ! -f "${file}" ]
+		then
+			netstat -nr | grep "^[1-9]" | while read network gateway netmask rest
+			do
+				i=1
+				net=""
+				TIFS="${IFS}"
+				IFS="."
+				for o in "${netmask}"
+				do
+					if [ "${o}" == "255" ]
+					then
+						[ "_${net}" == "_" ] || net="${net}."
+						t="$(echo "${network}" | cut -d " " -f ${i})"
+						net="${net}${t}"
+					fi
+					i="$((${i} + 1))"
+				done
+				IFS="${TIFS}"
+				echo "doing configuration - relay control for the network ${net} !"
+				echo "${net}	allow,RELAYCLIENT" >> ${file}
+			done
+			/usr/sbin/makesmtpaccess
+		fi
+	fi
+
+	echo "creating cert for esmtpd-ssl:"
+	/usr/sbin/mkesmtpdcert
+	echo "creating cert for imapd-ssl:"
+	/usr/sbin/mkpop3dcert
+	echo "creating cert for pop3d-ssl:"
+	/usr/sbin/mkimapdcert
+}