gentoo auto-resync : 09:11:2024 - 03:03:12

4 files changed, 560 insertions, 16 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 2ae292fac28c..4f7058bdae58 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -9,10 +9,13 @@ DIST gimp-2.10.34.tar.bz2 31405329 BLAKE2B 0b2d3a81abf89684bb90e2101896db3479a25
 DIST gimp-2.10.36.tar.bz2 31532334 BLAKE2B d033cd1407df3399b5968b7e3f7838d288143080b516476a5dd46599b6a84ac2efca591521368cef7a1c3d9935b45ed3262fb469e1ae36ccf60a1199f5cfa44d SHA512 dbe6152ea6ff99cca59bbf2c88a64fb4ff6b529d98ace7723eadf5dfb0e10d9cbaf2de1e0d5251e9ecf9abca73da9ae1a501f229997802fd4077fb9594f4ba66
 DIST gimp-2.10.38.tar.bz2 31698453 BLAKE2B 58c29e3e00d873e69a5e5f4e9c3ff4d868ccfb11914570306ef12c54ca7d3ef89a62d8c71fac1f2d1f426ac615dc4caf7a7260351c00301dce2b1aa4193bab6d SHA512 343bf1c3bd14bf8e7c7af79c05920faca213da68549127c1d8af53e2e872e55aeaf39a3cfcf578183a34fdc4f98e1c859be63956b0611067186eefd1fdee2aaa
 DIST gimp-2.99.18.tar.xz 25418968 BLAKE2B ccb76bb5c375925d4d71505f3e1546f05ba0e20533859b1b6250a4d9054efb6bec4927a5e0c525272fa24d5a6bdf4fb7881d60a1d34b1210ee38b90e661ef707 SHA512 151ccd0322601e76ed0198b40832ab0b6c138428f2e75806dd558e29c9b3437d9226a243142bf4a86113fa5ea4f5965b99cf7cd0ab0ecb7bdfc48036de35a9c6
+DIST gimp-3.0.0-RC1.tar.xz 28863948 BLAKE2B d9e1ae51809d1c8e5084a9e85b660cd0f3a763f8ee220075fe73f512940e9637d50675a06d0dca88c501571a26404cb6b53c9573348002586143c52736dfa196 SHA512 844896976b66b0498ba9149c7176f5442b2305fd3dc51fce7ff92eb05b7b0f86f16d0bd16e50a3c43ab2c6b9be4e610dbbfc50a99c84a62a4de80a6937d43985
 EBUILD gimp-2.10.34-r3.ebuild 6033 BLAKE2B 1a0c57ea0892099726875dfcdeb8b75d56e6101ccc63cf6006a8d56acc55f9d8bf4edf93f6a4c1e5de3c89b0951fecb2c06cc72ea14fcbf25ccef438df7bb901 SHA512 bdc9794b0d82172436b3b164e27d2de8697f33b9bbb8ae907dc9034bc8c6550075093d515cef82d900302745eaae856d22ead356ff1a55c49f7a2b758c6250c0
 EBUILD gimp-2.10.36-r3.ebuild 6005 BLAKE2B 2df114a4355ef257bd4b88b34b578883b044327c78282aa6239d082f382128cd35adea29af326e2288cd9110100b0e2fccf8c4d3f581e4bb2166dfb4fc188ca6 SHA512 487f909ee8c34a12d662b673b40551b8c80e0a340ce663c8937b216b61c3536ff3b85337b99ca85b33b238c3cece26f875e7195f381941f1f0a472a9c61c32f2
 EBUILD gimp-2.10.36-r4.ebuild 6152 BLAKE2B b0013afb683f05ea7b5dfd1e9ced41bafb6f394a7330b51932dd9021e53bf173ebdc1000062c6d2f8cd256877819805cf70e302b3741f9ec960286ad193c3821 SHA512 ed75fb99737b0e239ba569985cde4981e82a87b6e16286886f50dbe136293a084c872dfef99d086a29df6d940e3154cf9f6d108d60565ae767d3a2ec1e745bff
 EBUILD gimp-2.10.38-r1.ebuild 6263 BLAKE2B 33b03f460723be7296b458ca7fe6c93d4c3fba91c30453ab67dec74415306c91ba248207c255a39459c06b042f423460a2689af76967c5d69680caa0817a78ca SHA512 1b76ead707da38695b9c34885ab464508cb91d20ddf4fa85cbd95458f8ca3fbad89dbf7fdf65adc032dfe519df04e49759b8c4dc6a5c045355f5e6020d771e5d
 EBUILD gimp-2.99.18-r1.ebuild 7253 BLAKE2B 0c95a252589be3d821a73b7651e866207928cee724d16e934f585bd9080869620d1b20546672ddf229ef59bd21f54d5906da19bf2bafab76d479b05b3adfc403 SHA512 042f9a4d904d2be0bedbb6dde123a7d12f8c43b7502990e2a0c6884c287522db8e0bfeebc0fa621a54992739482db4a8b8f3675ba7f5af33999ea4c390f6bf37
-EBUILD gimp-9999.ebuild 7257 BLAKE2B 8dc6eaded83b8ac8bca1fe6c2115e4dfc2cdb5aa3edb308211eb2e6a7df65caaa4120f4ac2cec9253c76cecbc292991b47dc33f1c617941e9b1035cf6e8f594f SHA512 9e53ec59a222f36c3d2a4992921c3ad28982c5d7a32e9a9ab054f7a4846cac02a47157c605d83b74dc96bfdb13bfa17363744a0bae89b2829502085f6e1e2c71
+EBUILD gimp-2.99.18-r2.ebuild 7334 BLAKE2B 48ac3cbc7462d69b6bb36611f72d0d1dc26dee5ca4764c8acf1e65c434fc106aa6ea6f05a10e81b62f8608e109cfae52be6d2e84f46e7c9e5e2443db5a92ebbc SHA512 084e3039ff16d1e6eccb02ca01beee6d702dbac2748ba87e9550949766454cf810357c06c978c5fcb35dc10413aa00a5eee69355cc90fe2103749e0f83a37296
+EBUILD gimp-3.0.0_rc1.ebuild 7043 BLAKE2B 1119162da595325f9b73b6b1344c6e85595f9177c9cd7924d40bebc1b6ac2bb59dab04e740e98b728c469e62d4783d86f50fef27079adcf7909bf34e37b22adc SHA512 84bfc3a42e1d1da2791710229bd58f08be17104107e9d7df4cc798413f0ba05f0a5823629572ea71203f4a8476f0499bf9f953a1d51a3103cf588c3a2b3d23f9
+EBUILD gimp-9999.ebuild 7259 BLAKE2B 94f6605dbe4ce61288c60c9d0650be8021be3b5b5490ea4b1939796a6f8417a9f40df0d6abf6470750acf85a698151644243abd127612427170ea8a564ee4798 SHA512 5b02f36c4e32749d09462fe2418239f74c2142934527775a1619647a971eccd2c697ca4108b7b663b1ebc21c164ae256e1d8d779e58f7f0b76d0d0a3284e669c
 MISC metadata.xml 655 BLAKE2B f6628a2c5edb90b16db0f59af05446a3f31316f5558ece238d30c9350632713cf2db3d315c90b31229596659ec20859c17fde6b051f9ab8f8fe34d64902dad57 SHA512 712a259ae41d9052bde0761087928685b9b66a132db3f3b49121241d87728f51bf31a00541aa385bd03b57a2e2a03a0176356045dd4752485a8dca2bd61c5886
diff --git a/media-gfx/gimp/gimp-2.99.18-r2.ebuild b/media-gfx/gimp/gimp-2.99.18-r2.ebuild
new file mode 100644
index 000000000000..9166dcd6ee43
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.99.18-r2.ebuild
@@ -0,0 +1,275 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+VALA_USE_DEPEND=vapigen
+
+inherit lua-single meson python-single-r1 toolchain-funcs vala xdg
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(ver_cut 1-2)/${P}.tar.xz"
+
+LICENSE="GPL-3+ LGPL-3+"
+SLOT="0/3"
+
+IUSE="X aalib alsa doc fits gnome heif javascript jpeg2k jpegxl lua mng openexr openmp postscript python test udev unwind vala vector-icons webp wmf xpm"
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( X )
+	xpm? ( X )
+"
+
+RESTRICT="!test? ( test )"
+
+# media-libs/{babl,gegl} are required to be built with USE="introspection"
+# to fix the compilation checking of /usr/share/gir-1.0/{Babl-0.1gir,Gegl-0.4.gir}
+COMMON_DEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0
+	>=app-text/poppler-0.90.1[cairo]
+	>=app-text/poppler-data-0.4.9
+	>=dev-libs/appstream-glib-0.7.16
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.4.4
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.46.0:2
+	>=media-gfx/mypaint-brushes-2.0.2:=
+	>=media-libs/babl-0.1.98[introspection,lcms,vala?]
+	>=media-libs/fontconfig-2.12.6
+	>=media-libs/freetype-2.10.2
+	>=media-libs/gegl-0.4.48:0.4[cairo,introspection,lcms,vala?]
+	>=media-libs/gexiv2-0.14.0
+	>=media-libs/harfbuzz-2.6.5:=
+	>=media-libs/lcms-2.13.1:2
+	media-libs/libjpeg-turbo:=
+	>=media-libs/libmypaint-1.6.1:=
+	>=media-libs/libpng-1.6.37:0=
+	>=media-libs/tiff-4.1.0:=
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	>=x11-libs/cairo-1.16.0[X=]
+	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
+	>=x11-libs/gtk+-3.24.16:3[introspection,X=]
+	>=x11-libs/pango-1.50.0[X=]
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	fits? ( sci-libs/cfitsio )
+	heif? ( >=media-libs/libheif-1.13.0:= )
+	javascript? ( dev-libs/gjs )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
+	jpegxl? ( >=media-libs/libjxl-0.6.1:= )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			dev-lua/lgi[${LUA_USEDEP}]
+		')
+	)
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-2.3.0:= )
+	postscript? ( app-text/ghostscript-gpl:= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+		')
+	)
+	udev? ( >=dev-libs/libgudev-167:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8[X=] )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+		>=x11-libs/libXmu-1.1.4
+	)
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( x11-misc/xvfb-run )
+	vala? ( $(vala_depend) )
+"
+
+# TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
+BDEPEND="
+	>=dev-lang/perl-5.30.3
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.21
+	doc? (
+		app-text/yelp-tools
+		dev-libs/gobject-introspection[doctool]
+		dev-util/gi-docgen
+	)
+	virtual/pkgconfig
+"
+
+DOCS=( "AUTHORS" "NEWS" "README" "README.i18n" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10_fix_musl_backtrace_backend_switch.patch" #900148
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+
+	use lua && lua-single_pkg_setup
+
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' meson.build || die #737794
+
+	# Fix Gimp  and GimpUI devel doc installation paths
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp/meson.build || die
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp-ui/meson.build || die
+
+	# Fix pygimp.interp python implementation path.
+	# Meson @PYTHON_PATH@ use sandbox path e.g.:
+	# '/var/tmp/portage/media-gfx/gimp-2.99.12/temp/python3.10/bin/python3'
+	sed -i -e 's/@PYTHON_PATH@/'${EPYTHON}'/' plug-ins/python/pygimp.interp.in || die
+
+	# Set proper intallation path of documentation logo
+	sed -i -e "s/'gimp-@0@'.format(gimp_app_version)/'gimp-${PVR}'/" data/images/meson.build || die
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		-Denable-default-bin=enabled
+
+		-Dcheck-update=no
+		-Denable-multiproc=true
+		-Dappdata-test=disabled
+		-Dbug-report-url=https://bugs.gentoo.org/
+		-Dilbm=disabled
+		-Dlibbacktrace=false
+		-Dwebkit-unmaintained=false
+		$(meson_feature aalib aa)
+		$(meson_feature alsa)
+		$(meson_feature doc gi-docgen)
+		$(meson_feature fits)
+		$(meson_feature heif)
+		$(meson_feature javascript)
+		$(meson_feature jpeg2k jpeg2000)
+		$(meson_feature jpegxl jpeg-xl)
+		$(meson_feature lua)
+		$(meson_feature mng)
+		$(meson_feature openexr)
+		$(meson_feature openmp)
+		$(meson_feature postscript ghostscript)
+		$(meson_feature python)
+		$(meson_feature test headless-tests)
+		$(meson_feature udev gudev)
+		$(meson_feature vala)
+		$(meson_feature webp)
+		$(meson_feature wmf)
+		$(meson_feature X xcursor)
+		$(meson_feature xpm)
+		$(meson_use doc g-ir-doc)
+		$(meson_use unwind libunwind)
+		$(meson_use vector-icons)
+	)
+
+	meson_src_configure
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	meson_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prename=gimp-org-
+	(
+		cd "${ED}"/usr/$(get_libdir)/gimp/2.99/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+			plugin=${plugin_slash%/}
+			if [[ -f ${plugin}/${plugin} ]]; then
+				# NOTE: Folder and file name need to match for Gimp to load that plug-in
+				#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
+				mv ${plugin}/{,${prename}}${plugin} || exit 1
+				mv {,${prename}}${plugin} || exit 1
+			fi
+		done
+	)
+}
+
+src_test() {
+	local -x LD_LIBRARY_PATH="${BUILD_DIR}/libgimp:${LD_LIBRARY_PATH}"
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
+
+	# Create symlinks for Gimp exec in /usr/bin
+	dosym "${ESYSROOT}"/usr/bin/gimp-2.99 /usr/bin/gimp
+	dosym "${ESYSROOT}"/usr/bin/gimp-console-2.99 /usr/bin/gimp-console
+	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
+	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-2.99 /usr/bin/gimp-test-clipboard
+	dosym "${ESYSROOT}"/usr/bin/gimptool-2.99 /usr/bin/gimptool
+
+	_rename_plugins || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}
diff --git a/media-gfx/gimp/gimp-3.0.0_rc1.ebuild b/media-gfx/gimp/gimp-3.0.0_rc1.ebuild
new file mode 100644
index 000000000000..357b6ffb72e4
--- /dev/null
+++ b/media-gfx/gimp/gimp-3.0.0_rc1.ebuild
@@ -0,0 +1,260 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+VALA_USE_DEPEND=vapigen
+
+inherit lua-single meson python-single-r1 toolchain-funcs vala xdg
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(ver_cut 1-2)/${PN}-$(ver_cut 1-3)-RC1.tar.xz"
+
+S="${WORKDIR}/${PN}-$(ver_cut 1-3)-RC1"
+LICENSE="GPL-3+ LGPL-3+"
+SLOT="0/3"
+
+IUSE="X aalib alsa doc fits gnome heif javascript jpeg2k jpegxl lua mng openexr openmp postscript test udev unwind vala vector-icons webp wmf xpm"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	lua? ( ${LUA_REQUIRED_USE} )
+	test? ( X )
+	xpm? ( X )
+"
+
+RESTRICT="!test? ( test )"
+
+# media-libs/{babl,gegl} are required to be built with USE="introspection"
+# to fix the compilation checking of /usr/share/gir-1.0/{Babl-0.1gir,Gegl-0.4.gir}
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+	')
+	>=app-accessibility/at-spi2-core-2.46.0
+	>=app-text/poppler-0.90.1[cairo]
+	>=app-text/poppler-data-0.4.9
+	>=dev-libs/appstream-glib-0.7.16
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.4.4
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.57.3:2
+	>=media-gfx/mypaint-brushes-2.0.2:=
+	>=media-libs/babl-0.1.110[introspection,lcms,vala?]
+	>=media-libs/fontconfig-2.12.6
+	>=media-libs/freetype-2.10.2
+	>=media-libs/gegl-0.4.50:0.4[cairo,introspection,lcms,vala?]
+	>=media-libs/gexiv2-0.14.0
+	>=media-libs/harfbuzz-2.6.5:=
+	>=media-libs/lcms-2.13.1:2
+	media-libs/libjpeg-turbo:=
+	>=media-libs/libmypaint-1.6.1:=
+	>=media-libs/libpng-1.6.37:0=
+	>=media-libs/tiff-4.1.0:=
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	>=x11-libs/cairo-1.16.0[X=]
+	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
+	>=x11-libs/gtk+-3.24.16:3[introspection,X=]
+	>=x11-libs/pango-1.50.0[X=]
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	fits? ( sci-libs/cfitsio )
+	heif? ( >=media-libs/libheif-1.13.0:= )
+	javascript? ( dev-libs/gjs )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
+	jpegxl? ( >=media-libs/libjxl-0.6.1:= )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			dev-lua/lgi[${LUA_USEDEP}]
+		')
+	)
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-2.3.0:= )
+	postscript? ( app-text/ghostscript-gpl:= )
+	udev? ( >=dev-libs/libgudev-167:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8[X=] )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+		>=x11-libs/libXmu-1.1.4
+	)
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( x11-misc/xvfb-run )
+	vala? ( $(vala_depend) )
+"
+
+# TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
+BDEPEND="
+	>=dev-lang/perl-5.30.3
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.21
+	doc? (
+		app-text/yelp-tools
+		dev-libs/gobject-introspection[doctool]
+		dev-util/gi-docgen
+	)
+	virtual/pkgconfig
+"
+
+DOCS=( "AUTHORS" "NEWS" "README" "README.i18n" )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-single-r1_pkg_setup
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' meson.build || die #737794
+
+	# Fix Gimp  and GimpUI devel doc installation paths
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp/meson.build || die
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp-ui/meson.build || die
+
+	# Fix pygimp.interp python implementation path.
+	# Meson @PYTHON_PATH@ use sandbox path e.g.:
+	# '/var/tmp/portage/media-gfx/gimp-2.99.12/temp/python3.10/bin/python3'
+	sed -i -e 's/@PYTHON_PATH@/'${EPYTHON}'/' plug-ins/python/pygimp.interp.in || die
+
+	# Set proper intallation path of documentation logo
+	sed -i -e "s/'gimp-@0@'.format(gimp_app_version)/'gimp-${PVR}'/" gimp-data/images/logo/meson.build || die
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		-Denable-default-bin=enabled
+
+		-Dcheck-update=no
+		-Denable-multiproc=true
+		-Dappdata-test=disabled
+		-Dbug-report-url=https://bugs.gentoo.org/
+		-Dilbm=disabled
+		-Dlibbacktrace=false
+		-Dwebkit-unmaintained=false
+		$(meson_feature aalib aa)
+		$(meson_feature alsa)
+		$(meson_feature doc gi-docgen)
+		$(meson_feature fits)
+		$(meson_feature heif)
+		$(meson_feature javascript)
+		$(meson_feature jpeg2k jpeg2000)
+		$(meson_feature jpegxl jpeg-xl)
+		$(meson_feature mng)
+		$(meson_feature openexr)
+		$(meson_feature openmp)
+		$(meson_feature postscript ghostscript)
+		$(meson_feature test headless-tests)
+		$(meson_feature udev gudev)
+		$(meson_feature vala)
+		$(meson_feature webp)
+		$(meson_feature wmf)
+		$(meson_feature X xcursor)
+		$(meson_feature xpm)
+		$(meson_use doc g-ir-doc)
+		$(meson_use lua)
+		$(meson_use unwind libunwind)
+		$(meson_use vector-icons)
+	)
+
+	meson_src_configure
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	meson_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prename=gimp-org-
+	(
+		cd "${ED}"/usr/$(get_libdir)/gimp/3.0/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+			plugin=${plugin_slash%/}
+			if [[ -f ${plugin}/${plugin} ]]; then
+				# NOTE: Folder and file name need to match for Gimp to load that plug-in
+				#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
+				mv ${plugin}/{,${prename}}${plugin} || exit 1
+				mv {,${prename}}${plugin} || exit 1
+			fi
+		done
+	)
+}
+
+src_test() {
+	local -x LD_LIBRARY_PATH="${BUILD_DIR}/libgimp:${LD_LIBRARY_PATH}"
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	python_optimize
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Create symlinks for Gimp exec in /usr/bin
+	dosym "${ESYSROOT}"/usr/bin/gimp-3.0 /usr/bin/gimp
+	dosym "${ESYSROOT}"/usr/bin/gimp-console-3.0 /usr/bin/gimp-console
+	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
+	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-3.0 /usr/bin/gimp-test-clipboard
+	dosym "${ESYSROOT}"/usr/bin/gimptool-3.0 /usr/bin/gimptool
+
+	_rename_plugins || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}
diff --git a/media-gfx/gimp/gimp-9999.ebuild b/media-gfx/gimp/gimp-9999.ebuild
index 906f16b47136..473f80d33404 100644
--- a/media-gfx/gimp/gimp-9999.ebuild
+++ b/media-gfx/gimp/gimp-9999.ebuild
@@ -15,10 +15,12 @@ EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gimp.git"
 LICENSE="GPL-3+ LGPL-3+"
 SLOT="0/3"
 
-IUSE="X aalib alsa doc gnome heif javascript jpeg2k jpegxl lua mng openexr openmp postscript test udev unwind vala vector-icons webp wmf xpm"
+IUSE="X aalib alsa doc fits gnome heif javascript jpeg2k jpegxl lua mng openexr openmp postscript test udev unwind vala vector-icons webp wmf xpm"
 REQUIRED_USE="
 	${PYTHON_REQUIRED_USE}
 	lua? ( ${LUA_REQUIRED_USE} )
+	test? ( X )
+	xpm? ( X )
 "
 
 RESTRICT="!test? ( test )"
@@ -38,7 +40,7 @@ COMMON_DEPEND="
 	>=dev-libs/json-glib-1.4.4
 	dev-libs/libxml2:2
 	dev-libs/libxslt
-	>=gnome-base/librsvg-2.40.21:2
+	>=gnome-base/librsvg-2.57.3:2
 	>=media-gfx/mypaint-brushes-2.0.2:=
 	>=media-libs/babl-9999[introspection,lcms,vala?]
 	>=media-libs/fontconfig-2.12.6
@@ -53,13 +55,13 @@ COMMON_DEPEND="
 	>=media-libs/tiff-4.1.0:=
 	net-libs/glib-networking[ssl]
 	sys-libs/zlib
-	>=x11-libs/cairo-1.16.0
+	>=x11-libs/cairo-1.16.0[X=]
 	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
-	>=x11-libs/gtk+-3.24.16:3[introspection]
-	>=x11-libs/pango-1.50.0
-	>=x11-libs/libXmu-1.1.4
+	>=x11-libs/gtk+-3.24.16:3[introspection,X=]
+	>=x11-libs/pango-1.50.0[X=]
 	aalib? ( media-libs/aalib )
 	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	fits? ( sci-libs/cfitsio )
 	heif? ( >=media-libs/libheif-1.13.0:= )
 	javascript? ( dev-libs/gjs )
 	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
@@ -76,8 +78,13 @@ COMMON_DEPEND="
 	udev? ( >=dev-libs/libgudev-167:= )
 	unwind? ( >=sys-libs/libunwind-1.1.0:= )
 	webp? ( >=media-libs/libwebp-0.6.0:= )
-	wmf? ( >=media-libs/libwmf-0.2.8 )
-	X? ( x11-libs/libXcursor )
+	wmf? ( >=media-libs/libwmf-0.2.8[X=] )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+		>=x11-libs/libXmu-1.1.4
+	)
 	xpm? ( x11-libs/libXpm )
 "
 
@@ -167,11 +174,13 @@ src_configure() {
 		-Denable-multiproc=true
 		-Dappdata-test=disabled
 		-Dbug-report-url=https://bugs.gentoo.org/
+		-Dilbm=disabled
 		-Dlibbacktrace=false
 		-Dwebkit-unmaintained=false
 		$(meson_feature aalib aa)
 		$(meson_feature alsa)
 		$(meson_feature doc gi-docgen)
+		$(meson_feature fits)
 		$(meson_feature heif)
 		$(meson_feature javascript)
 		$(meson_feature jpeg2k jpeg2000)
@@ -235,15 +244,12 @@ src_install() {
 
 	find "${D}" -name '*.la' -type f -delete || die
 
-	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
-	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
-
 	# Create symlinks for Gimp exec in /usr/bin
-	dosym "${ESYSROOT}"/usr/bin/gimp-2.99 /usr/bin/gimp
-	dosym "${ESYSROOT}"/usr/bin/gimp-console-2.99 /usr/bin/gimp-console
+	dosym "${ESYSROOT}"/usr/bin/gimp-3.0 /usr/bin/gimp
+	dosym "${ESYSROOT}"/usr/bin/gimp-console-3.0 /usr/bin/gimp-console
 	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
-	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-2.99 /usr/bin/gimp-test-clipboard
-	dosym "${ESYSROOT}"/usr/bin/gimptool-2.99 /usr/bin/gimptool
+	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-3.0 /usr/bin/gimp-test-clipboard
+	dosym "${ESYSROOT}"/usr/bin/gimptool-3.0 /usr/bin/gimptool
 
 	_rename_plugins || die
 }