gentoo resync : 23.09.2020

3 files changed, 216 insertions, 2 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 98f431aaad43..b820e28c1358 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -2,7 +2,8 @@ AUX gimp-2.10_fix_test-appdata.patch 902 BLAKE2B 2b1a131d874d65422d8bdd44732b984
 DIST gimp-2.10.18.tar.bz2 32946467 BLAKE2B eb1c756ca646ee9ddc42aebe214ad3e2dedf125940dc1b9cfd04a4424bd2b6255041f1bafbda3fc214f93d97e7802372234a42e1daa0ee56caaf0f0bedd908f9 SHA512 88990f2d70508b22f4acadeab6b687e20af19b765ebc6f245d0c99b3dd853fcd3d237c3b7607e50133aa95a1d71931069029dfd7ee94441ff419c542c141bc9f
 DIST gimp-2.10.20.tar.bz2 33108938 BLAKE2B 060c0e46e6f4ac861de265842d545285c2fa4590908172971ef240ae87f8caa2c015447deee810fef59c4869810676daae2e40aa611062168feffe38c7cd9b22 SHA512 7cd0b1833af87a167fdfee59fb491a72727fe3071c21c0de1813adb0f8272a92473e1e300517395b1b4593c8cb6781ee30f7a63966756e5a7f523a164308aba6
 EBUILD gimp-2.10.18-r1.ebuild 6166 BLAKE2B a0457d562c194faf821e57647a171d1152f35c567332dff9fbde3e5c69a1ad55e547f07ca94d4f3f58178be7c56005655d2c77c342b8fc983968aca93784e033 SHA512 e7dbff03388e9b651851eb54aa5c8fb61736f288747d0ada5986bb9851cd5de7fefa9b57fe81b36363de27f608b254fba3049f759d4d2ccc40b1eaf3f70308b4
-EBUILD gimp-2.10.18-r2.ebuild 6317 BLAKE2B 4ed48f6450955abc83ebfc73605a825d1ab493c27ddc4b389d06c93a092961343c9496712f308aee68f81c48757ec3e44257609127a9218b9f02a4d893b7c347 SHA512 44f765e80996107ca3d4b294c4018e23e8ae5619eb2c7cebe6b1f6f0e7614fa296839d58f5b10a5e3f547b12bd1c2e303edd8893d47b5733fc44816ff3b8a0b2
+EBUILD gimp-2.10.18-r2.ebuild 6313 BLAKE2B c4858a01c8bb279ebb9f14bce5c578679bec05de6d6418a4137c012840fa7cdb707d97b74bdb602f0c9a018fe56bd67452af71bf42857b0d9a77a133caa3cc89 SHA512 eca3afb038ed0c51ae1b499e69b1af5f41e3ef2cc95b1d064241d6151b2bc8d8444e2b7a8806a84de15c4f8306a3ee07de8101827114a5a5b9c26acd0e487bca
 EBUILD gimp-2.10.20-r1.ebuild 6022 BLAKE2B 75e149312d91224b99ef93146525509c411a02cf59d87f3c727fcee60504f6769d84dc676439eb59a880edb17cfda65ae5ae2eff0062c9ee4ff74247f1f73cf0 SHA512 d1aec4d39329879101a28769a192dd92cc296c80402d99dfed07c9a5f7974363cd94dfe1765142f146bca43e005a6dad77bac45a86c47be26ae2f46be23f4d62
+EBUILD gimp-2.10.20-r2.ebuild 5652 BLAKE2B 42e8acc097cb3e25713fa144e9e1259ef29c01d0bd706f6f5ecbce4040ac2841027ab9231314d8f3225b4fd9c360e16e51a4a49be02ad5612550892be96a8031 SHA512 467eebc4200c581b91c9af811132b817a7518e41beb238921e735568d8c174052da04a98b0c1a30e7683f4f0cbef4b6a794cf01e0941076df98f5e95d27d1444
 EBUILD gimp-9999.ebuild 6461 BLAKE2B ba3eac8a82d0ebac3cc0ae18c2cddfecdb54fb922707e813d9a922d1f466564f50d42ab24a9de9dab1f63a1302dc84bcede6b4ca3dd4e38503cb64fcee565a93 SHA512 97a1d450095bfa7219672c45100403950029a5c0620ce50ab50eee318baf8e0b944fe387d6483f4f5b9a5c570b8f77b346306c62ba6cfaf673d01c9f6232861e
 MISC metadata.xml 546 BLAKE2B 2d5b9a68c47a72325199586a142f1d8344bef770d24738169c80958f3def3a0f1ad0b4d23774d3c458d80f17a394033813e01fc5e24b8b62146d2c55b5f8c9b0 SHA512 f654d93c738c942605ae61fe0d76972a1b81bffaf4edc23a1f55bb65e71022df7f14e769a71c41e5c5c7307eef9618a667ae418dc9bc77d5ac1299bbe0c58834
diff --git a/media-gfx/gimp/gimp-2.10.18-r2.ebuild b/media-gfx/gimp/gimp-2.10.18-r2.ebuild
index f586c716b705..ec2b8c9e32d4 100644
--- a/media-gfx/gimp/gimp-2.10.18-r2.ebuild
+++ b/media-gfx/gimp/gimp-2.10.18-r2.ebuild
@@ -13,7 +13,7 @@ HOMEPAGE="https://www.gimp.org/"
 SRC_URI="mirror://gimp/v2.10/${P}.tar.bz2"
 LICENSE="GPL-3 LGPL-3"
 SLOT="2"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~ppc ppc64 x86"
 
 IUSE="aalib alsa aqua debug doc gnome heif jpeg2k mng openexr postscript python udev unwind vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
diff --git a/media-gfx/gimp/gimp-2.10.20-r2.ebuild b/media-gfx/gimp/gimp-2.10.20-r2.ebuild
new file mode 100644
index 000000000000..b608de52d4ef
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.10.20-r2.ebuild
@@ -0,0 +1,213 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_EAUTORECONF=yes
+WANT_AUTOMAKE=
+
+inherit autotools gnome2 toolchain-funcs virtualx
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.10/${P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~ppc ~ppc64 x86"
+
+IUSE="aalib alsa aqua debug doc gnome heif jpeg2k mng openexr postscript udev unwind vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
+
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=app-text/poppler-0.50[cairo]
+	>=app-text/poppler-data-0.4.7
+	>=dev-libs/atk-2.2.0
+	>=dev-libs/glib-2.56.2:2
+	>=dev-libs/json-glib-1.2.6
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.40.6:2
+	>=media-gfx/mypaint-brushes-1.3.0:=
+	>=media-libs/babl-0.1.78
+	>=media-libs/fontconfig-2.12.4
+	>=media-libs/freetype-2.1.7
+	>=media-libs/gegl-0.4.24:0.4[cairo]
+	>=media-libs/gexiv2-0.10.6
+	>=media-libs/harfbuzz-0.9.19
+	>=media-libs/lcms-2.8:2
+	>=media-libs/libmypaint-1.3.0:=
+	>=media-libs/libpng-1.6.25:0=
+	>=media-libs/tiff-3.5.7:0
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	virtual/jpeg
+	>=x11-libs/cairo-1.12.2
+	>=x11-libs/gdk-pixbuf-2.31:2
+	>=x11-libs/gtk+-2.24.32:2
+	x11-libs/libXcursor
+	>=x11-libs/pango-1.29.4
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
+	heif? ( >=media-libs/libheif-1.3.2:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	postscript? ( app-text/ghostscript-gpl )
+	udev? ( dev-libs/libgudev:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	>=dev-lang/perl-5.10.0
+	dev-libs/appstream-glib
+	dev-util/gtk-update-icon-cache
+	>=dev-util/intltool-0.40.1
+	sys-apps/findutils
+	>=sys-devel/gettext-0.19
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+"
+
+DOCS=( "AUTHORS" "ChangeLog" "HACKING" "NEWS" "README" "README.i18n" )
+
+# Bugs 685210 (and duplicate 691070)
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10_fix_test-appdata.patch"
+)
+
+src_prepare() {
+	if has_version "media-gfx/mypaint-brushes:2.0" ; then
+		sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' configure.ac || die #737794
+	fi
+
+	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
+	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+
+	gnome2_src_prepare  # calls eautoreconf
+
+	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
+	fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+
+	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	local myconf=(
+		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
+		GDBUS_CODEGEN="${EPREFIX}"/bin/false
+
+		--enable-default-binary
+
+		--disable-check-update
+		--disable-python
+		--enable-mp
+		--with-appdata-test
+		--with-bug-report-url=https://bugs.gentoo.org/
+		--with-xmc
+		--without-libbacktrace
+		--without-webkit
+		--without-xvfb-run
+		$(use_enable cpu_flags_ppc_altivec altivec)
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable vector-icons)
+		$(use_with aalib aa)
+		$(use_with alsa)
+		$(use_with !aqua x)
+		$(use_with heif libheif)
+		$(use_with jpeg2k jpeg2000)
+		$(use_with mng libmng)
+		$(use_with openexr)
+		$(use_with postscript gs)
+		$(use_with udev gudev)
+		$(use_with unwind libunwind)
+		$(use_with webp)
+		$(use_with wmf)
+		$(use_with xpm libxpm)
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	gnome2_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prepend=gimp-org-
+	(
+		cd "${ED%/}"/usr/$(get_libdir)/gimp/2.0/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+		    plugin=${plugin_slash%/}
+		    if [[ -f ${plugin}/${plugin} ]]; then
+			# NOTE: Folder and file name need to match for Gimp to load that plug-in
+			#       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
+			mv ${plugin}/{,${prepend}}${plugin} || exit 1
+			mv {,${prepend}}${plugin} || exit 1
+		    fi
+		done
+	)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED%/}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	local gimp_app_version=$(get_version_component_range 1-2)
+	mv "${ED%/}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
+	# Remove gimp devel-docs html files if user doesn't need it
+	if ! use doc; then
+		rm -r "${ED%/}"/usr/share/gtk-doc || die
+	fi
+
+	_rename_plugins || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}