gentoo resync : 02.02.2022

3 files changed, 184 insertions, 9 deletions

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index 6ef737ae2820..4f33b58c10c7 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -1,6 +1,8 @@
 AUX inkscape-1.1-poppler-21.11.0.patch 690 BLAKE2B 61fbaf22fa86170d1a72393795fb195b5c93d1c9f3e512751d4a9a355acda28656978529c1022caf9df701bc86e3c2b6e50b14eeed5d0c013013090b51ff6716 SHA512 9c7a312de85d11aa8ff3f7347a5c08ef84050522bc8ab59f9aa1aa84c405ddb707275cab7d447e34b1593d633b99fb8e482864e9397c576d688dcd7d34035c6d
 DIST inkscape-1.1-musl.txz 10820 BLAKE2B 3e7d346161d8c58436cae01227ce0eafc122276ba4b0483271cbb2e74447c7a89b2033bf709adb521abe2aebca79fffece183786071478b29aedbf3c742c4616 SHA512 8900863fb2d12cb6aea39b2e2ac8d32b512086aa3a26f3598d3117abd0b44f95b6001ea21ac02ce2368dd66dee0faefdef049c433f62380904770b7680680668
+DIST inkscape-1.1.1.tar.xz 34221284 BLAKE2B e628ead14f76fa3de929cfe14a6f085c5e9cd4304d2ee0a4b2046380284aacb8a32ff311c2e104f39f6abd0d080594ec4f9783fcaff183588107eedb49863c82 SHA512 22b1b584a344c4f4ebd0b6e84a4af44e472ef47b3971cb97cbb026a4bf7cb5bea49a7de0c2af2a9e439c7c794f775081c8d1904f33eadb49a5389ea01bc0896c
 DIST inkscape-1.1.tar.xz 34203156 BLAKE2B 38896509dcdcf1ef18523c790855035ef16dfae75e27c2d69f782270f52a579557edcb790bef30f3210b9f797a619369d7d16dd23f098debdd8e5b6abf9b30aa SHA512 54b75f8794d748ef59d5b719ea04e3debadc1a5cf3f62f14254502567973bbd634850edd0a3bc082be878dacf041e9bd10982c4846bf154f89aa5319eda4ee80
 EBUILD inkscape-1.1-r1.ebuild 4365 BLAKE2B 1a575b33c2b7a90851560291a17ffaeac85287c6dc1289c096a06e9a21da4490b8cd72590e61e390aad50542a0d18bd941c62e32ff625700071ec97383003461 SHA512 2f387d0c8283204aa667ba103274527b4ea9e97daef7775bab8b2cce42d44da5ad4b50ec1e4ae49d0409dd4c2f3c63a29f224451c8569497851113abf34fab2d
-EBUILD inkscape-9999.ebuild 4224 BLAKE2B ae54a77ce4d1aab3e2f9c550017632f54ccb1e41cccc4b32b3769afc934d5bbafe3f4935c24e61610bed7e8578e20b4eeb96f50248d819263d8476312ef3af0d SHA512 fe29d3e89ccdcac3088a7c369353d70eeee54b6e1c8e0b9716377e240f3ebbe498dd7ac8244f8e9f376eda86a0932ad65d9a76f05696d81992c7e39eefc25c37
+EBUILD inkscape-1.1.1.ebuild 4198 BLAKE2B 25d7e6a67d7971b573a498f26a487d318d2f1e751d6c7a16afc13cb68c60f8a6402190e42534c443f98432390e98ec8a46562a72dbe2a744570da3cc64e4adab SHA512 5033c65432b52f8674654514043b62c342f39fbaf98acaeee3a823b988c644cd73442c7a8c4e9bc2ff46f307355102b14b3d8258e0c82cfa835f92ace64d194d
+EBUILD inkscape-9999.ebuild 4498 BLAKE2B cec5ba92467d97f7a6732f16f95dff330645f4b65e7bcde7fe0b82e08b264762950971fb8be08f99261fca734f5c99711dc502d47707fd5eb1008ae2bb8fca02 SHA512 17ccd273ee58f91004335e433dc8a130bff50c2ead9e80e17839a117a3ab1231f2b83b357a77f5060b777a4cc5b104a34c8ba0626d66b4316d57f82724076d32
 MISC metadata.xml 984 BLAKE2B 8aee1f973005f9587571770eb14ccf725bf3ba9034d9935b029f776e64e17a9e156ec864e1150b259d2a983aec6e53b10791be4f1a3b67d5aa465ee115d966f0 SHA512 7ee7c7d473ae2120b9f592777b08d77899c6bf7f750f09cc334dc76a997a472e2593442fb281a9984d77e1aa4eca39e389484405e0aa8b5614da0f718c713fc0
diff --git a/media-gfx/inkscape/inkscape-1.1.1.ebuild b/media-gfx/inkscape/inkscape-1.1.1.ebuild
new file mode 100644
index 000000000000..080afaf78213
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-1.1.1.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+
+inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
+
+DESCRIPTION="SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/"
+SRC_URI="https://media.inkscape.org/dl/resources/file/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cdr dbus dia exif graphicsmagick imagemagick inkjar jemalloc jpeg
+openmp postscript readline spell svg2 visio wpg"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.57.0:=[cairo]
+	>=dev-cpp/cairomm-1.12:0
+	>=dev-cpp/glibmm-2.54.1:2
+	dev-cpp/gtkmm:3.0
+	>=dev-cpp/pangomm-2.40:1.4
+	>=dev-libs/boehm-gc-7.1:=
+	>=dev-libs/boost-1.65:=
+	dev-libs/double-conversion:=
+	>=dev-libs/glib-2.41
+	>=dev-libs/libsigc++-2.8:2
+	>=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.1.25
+	dev-libs/gdl:3
+	dev-libs/popt
+	media-gfx/potrace
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	net-libs/libsoup:2.4
+	sci-libs/gsl:=
+	x11-libs/libX11
+	>=x11-libs/pango-1.37.2
+	x11-libs/gtk+:3
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_USEDEP}]
+		media-gfx/scour[${PYTHON_USEDEP}]
+	')
+	cdr? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libcdr
+	)
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( media-libs/libexif )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
+		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
+	)
+	jemalloc? ( dev-libs/jemalloc )
+	jpeg? ( virtual/jpeg:0 )
+	readline? ( sys-libs/readline:= )
+	spell? ( app-text/gspell )
+	visio? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libvisio
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+	')
+	dia? ( app-office/dia )
+	postscript? ( app-text/ghostscript-gpl )
+"
+DEPEND="${COMMON_DEPEND}"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${P}_2021-09-20_3bf5ae0d25"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-1.1-poppler-21.11.0.patch
+
+	cmake_src_prepare
+	sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		# -DWITH_LPETOOL   # Compile with LPE Tool and experimental LPEs enabled
+		-DWITH_NLS=ON
+		-DENABLE_POPPLER=ON
+		-DENABLE_POPPLER_CAIRO=ON
+		-DWITH_PROFILING=OFF
+		-DBUILD_TESTING=OFF
+		-DWITH_LIBCDR=$(usex cdr)
+		-DWITH_DBUS=$(usex dbus)
+		-DWITH_IMAGE_MAGICK=$(usex imagemagick $(usex !graphicsmagick)) # requires ImageMagick 6, only IM must be enabled
+		-DWITH_GRAPHICS_MAGICK=$(usex graphicsmagick $(usex imagemagick)) # both must be enabled to use GraphicsMagick
+		-DWITH_GNU_READLINE=$(usex readline)
+		-DWITH_GSPELL=$(usex spell)
+		-DWITH_JEMALLOC=$(usex jemalloc)
+		-DENABLE_LCMS=ON
+		-DWITH_OPENMP=$(usex openmp)
+		-DBUILD_SHARED_LIBS=ON
+		-DWITH_SVG2=$(usex svg2)
+		-DWITH_LIBVISIO=$(usex visio)
+		-DWITH_LIBWPG=$(usex wpg)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.bz2' -exec bzip2 -d {} \; || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.gz' -exec gzip -d {} \; || die
+
+	local extdir="${ED}"/usr/share/${PN}/extensions
+
+	if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then
+		python_optimize "${ED}"/usr/share/${PN}/extensions
+	fi
+
+	# Empty directory causes sandbox issues, see bug #761915
+	rm -r "${ED}/usr/share/inkscape/fonts" || die "Failed to remove fonts directory."
+}
diff --git a/media-gfx/inkscape/inkscape-9999.ebuild b/media-gfx/inkscape/inkscape-9999.ebuild
index c77a2bc64410..863a38c311f8 100644
--- a/media-gfx/inkscape/inkscape-9999.ebuild
+++ b/media-gfx/inkscape/inkscape-9999.ebuild
@@ -1,22 +1,28 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_COMPAT=( python3_{8..10} )
 PYTHON_REQ_USE="xml"
 MY_P="${P/_/}"
-inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1 git-r3
+inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
+
+if [[ ${PV} = 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/inkscape/inkscape.git"
+else
+	SRC_URI="https://media.inkscape.org/dl/resources/file/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
 
 DESCRIPTION="SVG based generic vector-drawing program"
 HOMEPAGE="https://inkscape.org/"
-EGIT_REPO_URI="https://gitlab.com/inkscape/inkscape.git"
 
 LICENSE="GPL-2 LGPL-2.1"
 SLOT="0"
-KEYWORDS=""
 IUSE="cdr dbus dia exif graphicsmagick imagemagick inkjar jemalloc jpeg
-openmp postscript readline spell static-libs svg2 test visio wpg"
+openmp postscript readline spell svg2 test visio wpg"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
@@ -105,6 +111,15 @@ pkg_pretend() {
 	fi
 }
 
+src_unpack() {
+	if [[ ${PV} = 9999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+	[[ -d "${S}" ]] || mv -v "${WORKDIR}/${P}_202"?-??-* "${S}" || die
+}
+
 src_prepare() {
 	cmake_src_prepare
 	sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
@@ -130,7 +145,7 @@ src_configure() {
 		-DWITH_JEMALLOC=$(usex jemalloc)
 		-DENABLE_LCMS=ON
 		-DWITH_OPENMP=$(usex openmp)
-		-DBUILD_SHARED_LIBS=$(usex !static-libs)
+		-DBUILD_SHARED_LIBS=ON
 		-DWITH_SVG2=$(usex svg2)
 		-DWITH_LIBVISIO=$(usex visio)
 		-DWITH_LIBWPG=$(usex wpg)
@@ -152,7 +167,6 @@ src_install() {
 
 	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.gz' -exec gzip -d {} \; || die
 
-	# No extensions are present in beta1
 	local extdir="${ED}"/usr/share/${PN}/extensions
 
 	if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then