gentoo auto-resync : 21:03:2024 - 07:00:13

2 files changed, 169 insertions, 0 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 81222f540461..19b5946edb6c 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -4,9 +4,11 @@ DIST gegl-0.4.40.tar.xz 5784744 BLAKE2B c4466a76ec4f7939161e9ead6980b8a701f3fc45
 DIST gegl-0.4.42.tar.xz 5787100 BLAKE2B 6ae3ec98e72b1057b9d84551f56b675edb511994a73979bfccf559e24d3d636ba915aab10d3b3a1b38989d69c63692d3f312c621819700332c8cc1a4b3e86875 SHA512 29ccd93faa6127b6a9b1180eeba47f1b6f9bc06da8a5c9d68315d7474b77ff19d1084a6f4e7b218666b355329b17bc562f5906a334aa2baf93840d7caa0adf57
 DIST gegl-0.4.44.tar.xz 5791844 BLAKE2B dbbdca0ff9985025f528fe298df32672069c09dd87e22ab70330f078ca7fc7efb8b78f8f9077bb559eb61c790c5ab50c53853a1032fe00fbea7080d140baa28c SHA512 4dd3fad0c5e391fc1ac3784d4365ffdc483d37b90a24a29eaa632dd337971674999b2e0f8facf255d86852a3899cc51f4d27f9875ab5849f8b38d9ed5bb7413a
 DIST gegl-0.4.46.tar.xz 5799248 BLAKE2B 2fc9ccd0c711cc901abd50740a24d0f75b162cbb196bdd62ab8430882da3b9ea72c08dd587ecfecaf5e4ba9aca4df51bcd7d98ec197325375b1d954c2995029e SHA512 cd733208da7dc1ec77ca023f03f47e578350e156ad07ece701b39f517a292e9f9c081b3a8a2db846813483b4ddb21f32f9fc8b9c70fea8a6ba27bb97ef8bb847
+DIST gegl-0.4.48.tar.xz 5805488 BLAKE2B 3a800004f166fdbfbd563688bb71c4579bba132380f5f45496e8fb813943333b89781320230adf6e0ee49b9bde7db37d81929a8fd42e19e62281e7f8d1ea3bfb SHA512 8f47e6445062894c16d54eeeec4a55cccc32fc49c9fb9be3428a591daaeb21b1a5b8529a68d82613fd75f107bb8c0418c9e5337346bd94da3226e545189c226b
 EBUILD gegl-0.4.40-r1.ebuild 5058 BLAKE2B 81eaf48488fe7ca7cb5271c0ae0a48444611a26629ca710afbf7a79227d00a872d338eb65882b140dc257183102a8e385ee2362a4a3b9b91e9bce1c9e98fa049 SHA512 53e81de8dbf1f5f9b066eae0acbd8c77904044ac2b199daa54e14dc37859fd97693506566659eb2f10cb5f14d551d570ee51a6a10eb78c53420aa0805f5109d4
 EBUILD gegl-0.4.42-r1.ebuild 5037 BLAKE2B dfadb084b9b429f6b27023c0609e4ed2a19d6acae8a371a39c9337bf83a84c97b531200b494f5c88bc707e385f2401dd3914798fb8082c41aff823330beb0258 SHA512 dc662dcf59f852bef86655966a9cc4e22bf50627d549e4a686a86ace9f5e1b376e0a5b23b04989403d98792acbfd638435cc85f5e11e0c5b6b641c7cdbb57318
 EBUILD gegl-0.4.44.ebuild 4968 BLAKE2B 22e3e0835c82edb5e4174fda51722d0726421a17207a89128b9d8e7f4ce10bd86efefaa414ba78bde94168c8023b7fb10de3721518144f383fa34849a3a45ea7 SHA512 4808a5736a788c602695e03fd617ff63a868adebc8b88fa523c1a013fcb26f7a001b7add6b12c1ee65c244b8636f6b9920a2c77dcd5c88e163567e38d51db191
 EBUILD gegl-0.4.46.ebuild 4968 BLAKE2B 22e3e0835c82edb5e4174fda51722d0726421a17207a89128b9d8e7f4ce10bd86efefaa414ba78bde94168c8023b7fb10de3721518144f383fa34849a3a45ea7 SHA512 4808a5736a788c602695e03fd617ff63a868adebc8b88fa523c1a013fcb26f7a001b7add6b12c1ee65c244b8636f6b9920a2c77dcd5c88e163567e38d51db191
+EBUILD gegl-0.4.48.ebuild 4972 BLAKE2B 1b9b0918bff87ea05e18367db6d9c9b5ae9e0fe8656ab4b57e8e248941a10fecc52beb973a83195360bad127d429d743c96fd3907d329b87a47510f6902ef4bc SHA512 0de68ee617f4393f4189714911f9715f0bba48776f57ef5001651119510a67314517be7d967993096c2f7a2033100d119411de0ac45e4a1a0ba43bab4cd76689
 EBUILD gegl-9999.ebuild 4751 BLAKE2B da0a5742a5090e4ddf4fad1cb57cfa261f92198b61bd8040e9a07e3e6ed1ea3ed9f1bbbdb33a05988e327a9c55217ac2d840a5dde1cd05559918ffb259a9aa5a SHA512 d27728e4022cfdcf5c8ab4aa73bf3688713ae555889c2f363e97054e236f7bd2b4659e4af96d48c3d1655ec8f849a1f4c03863c24181a8d62d8ba247a59cebd3
 MISC metadata.xml 761 BLAKE2B fa74f6ff5ae13c05793505d0a27b7bc8587748ad356fa4f3ec5b48bd2919c6197788ab02bdc02fbdbdfe2f376d93222b600e30915e50f4ee4643e973ce054d86 SHA512 8cf93e9c5130a017bb864144e88cd2a4f2eff17b5543514a3ca84066b90e394dda6ee64a5e49d8db3b48eb905df5eef815f3b2689bc2be9772a01dcd2cecad30
diff --git a/media-libs/gegl/gegl-0.4.48.ebuild b/media-libs/gegl/gegl-0.4.48.ebuild
new file mode 100644
index 000000000000..7127527cb64e
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.48.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit flag-o-matic meson optfeature python-any-r1 toolchain-funcs vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr openmp pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	test? ( introspection )
+	vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.68.2:2
+	>=dev-libs/json-glib-1.2.6
+	>=media-libs/babl-0.1.98[introspection?,lcms?,vala?]
+	media-libs/libjpeg-turbo
+	media-libs/libnsgif
+	>=media-libs/libpng-1.6.0:0=
+	>=sys-libs/zlib-1.2.0
+	>=x11-libs/gdk-pixbuf-2.32:2
+	>=x11-libs/pango-1.38.0
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	pdf? ( >=app-text/poppler-0.71.0[cairo] )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	sdl2? ( >=media-libs/libsdl2-2.0.20 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:= )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	>=dev-build/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	>=dev-build/libtool-2.2
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# patch executables suffix
+	sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+	sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+	sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+	# skip UNEXPECTED PASSED 'matting-levin' test
+	sed -i -e "s/composition_tests += 'matting-levin'//" \
+		-e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+	pushd "${S}/opencl/" || die
+	for file in *.cl; do
+		if [[ -f ${file} ]]; then
+			"${EPYTHON}" cltostring.py "${file}" || die
+		fi
+	done
+	popd || die
+}
+
+src_configure() {
+	# Bug #859901
+	filter-lto
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		#  - Disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		-Ddocs=false
+		-Dexiv2=disabled
+		-Dgdk-pixbuf=enabled
+		-Djasper=disabled
+		#  - libspiro: not in portage main tree
+		-Dlibspiro=disabled
+		-Dlua=disabled
+		-Dmrg=disabled
+		-Dpango=enabled
+		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
+		-Dworkshop=false
+		$(meson_feature cairo)
+		$(meson_feature cairo pangocairo)
+		$(meson_feature ffmpeg libav)
+		$(meson_feature lcms)
+		$(meson_feature lensfun)
+		$(meson_feature openexr)
+		$(meson_feature openmp)
+		$(meson_feature pdf poppler)
+		$(meson_feature raw libraw)
+		$(meson_feature sdl sdl1)
+		$(meson_feature sdl2 sdl2)
+		$(meson_feature svg librsvg)
+		$(meson_feature test pygobject)
+		$(meson_feature tiff libtiff)
+		$(meson_feature umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(meson_feature v4l libv4l)
+		$(meson_feature v4l libv4l2)
+		$(meson_feature vala vapigen)
+		$(meson_feature webp)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}