gentoo auto-resync : 15:04:2024 - 12:04:02

2 files changed, 207 insertions, 0 deletions

diff --git a/media-libs/libsdl2/Manifest b/media-libs/libsdl2/Manifest
index d662c3864861..dbcb94d53923 100644
--- a/media-libs/libsdl2/Manifest
+++ b/media-libs/libsdl2/Manifest
@@ -4,10 +4,12 @@ DIST SDL2-2.28.3.tar.gz 7340914 BLAKE2B 1ef8950b7736fbbca4607ed9750114f94b8e6e94
 DIST SDL2-2.28.4.tar.gz 7344208 BLAKE2B 03d1fec4c9c43d5b906ec9fafd69b75040f7c80696d9097b03c33a93760e579ff677b1dd9385c77d44209a5a8dbb295074d47595b8a2e39f00bc11ad32b7f154 SHA512 16950ccedcfdef42ee6eba1a6bf09ed7231ea0205fe8600388de2aed1aba94da2e5450d16e9732dce9f12569a238730b3727bf64b8699f1fed4cb3c5c94c3eaa
 DIST SDL2-2.28.5.tar.gz 7345355 BLAKE2B c96481bc02af6b6d077247238f7e46b0e3ec216664584add29cafb0a91d06dc6ddc637a01519dbd7182d4fa59cfaf26ad6733f72583021cf65849416f9c4b698 SHA512 12593eb78fcca877a8dfb78cf21a4e6feba7dc87c964de378ac462b36d8e41ecb587222cb41d5f56dd35b838e1b9867b8ae0cf2f4d2a01afaf23ac8c11edc84d
 DIST SDL2-2.30.1.tar.gz 7428023 BLAKE2B 5cc651bcb38a1a3989a966351074b1a77f511b5bef0d3c9aef06d67d89f1d0ee926f5cba4bf2d45be28bb3f1e9da9b3f17a85f094c8547586072b24ee342777d SHA512 bb1863310d627e7b49cfc31bea7eb9100da1908cd83a97c533c28a2e32eac377c72dde83d2c2c4791007f534ea2e5ec8b1ac545a0d2e291dfdce1734a727c4af
+DIST SDL2-2.30.2.tar.gz 7426565 BLAKE2B 258084c6965281951b78619d7ebcd80b0f6873f54ded93d35b6b898f0533fef9a29bef4a8babe53df50bc589b0565b3a3b1378a930b43fdce575c4a5baa70864 SHA512 19316bb4c483a8c4be2140b70d906b7767beabada481873217a9207bd41e79c1854a837e1394325f59795da010f5344f791a7973a846b8189e3f9b662f408aca
 EBUILD libsdl2-2.28.1.ebuild 6445 BLAKE2B 6652314ff4c8d8d50fd0cb1db99b91f1df4a22ee9dcc16224902132a2e150f7a6a750451ed0e4df96dbaf1294a41b8b986e79d0e285b53a9241936eba06ce304 SHA512 f99bbdbde13745818af665bee635997d97491f29a056bac3ad69ed534b47a381cbc7cc7ec5c85998eb6a872d5af1824d924ef28fcba1b31e9ba73aa5ee19f624
 EBUILD libsdl2-2.28.3.ebuild 6444 BLAKE2B f84a1d6d5562d86a782bcf3c418fb1030312929bd18703473d28eb791c9447a4cacfbafc0b0fc84ce5c9fbc109f4abca97d46a0023211cca727507908d58169d SHA512 b22720936efbc140f2f867fce7fd257b8ffff011e679b79b25868e0947df246dfa4f9f5309bf64ac8f7b38e85f24b540558c6a8afc8335b7ca5a361083367fbb
 EBUILD libsdl2-2.28.4-r1.ebuild 6505 BLAKE2B 410574b56df4bc8c42c1b9c0e60a790a0d6c03e8d728c5714e40d10321410d4b10375935eb83d919fc71c819d66ea34009aceafee475b0910b2ef20be76ae4ce SHA512 4b03d2d64ef142b08e5e5f3584194ec9ba588e80a5dd4829f800842d858a6dc1a0f6c96a7d88c908253b8fb80e35f5355da9328da4b1fbd9ca36716cddb95f82
 EBUILD libsdl2-2.28.5-r1.ebuild 7326 BLAKE2B 2ba3da156fc246483847795c10c47fde1e6d26350bc4980734e49068685a36c601ed05225a6c161fb69f042594ef276a1e29c7bfa6dba4c482aeb9887bf924d1 SHA512 e3d7d0bf0680db8e8e8405fff5d3ed3408ea5cd15fec6c639d06abd3759f34646838ef5bd0904544a6e8180a1167835bc43fe5c2aeb7cf3bf3f5ec5099a40f74
 EBUILD libsdl2-2.28.5.ebuild 7355 BLAKE2B 77c6aeb0a7c56c67b20a3b536017ecefadf12f5987c9f932917179f0d8ae168955665ef9ae53f812f5a597c783db059519901de33e350b9168d6c86eb0dc7555 SHA512 50ca9c54dbba69850920cc66a8ceba855606bc2142914cee8b16f2d8bc593a9a747a0b934e01362c03c6264a4189ab7b21225bbaab2fe86f28c7f13ca05ab576
 EBUILD libsdl2-2.30.1.ebuild 7467 BLAKE2B c0173460424d8dab62c0fa4bc7c80078971b35604d126424be9683b88cb261968583c4d0a85c00688072cb9ebd8ec648a0fafa3ae092650fa127623d50b7e06e SHA512 848eddbb8aae40d5a06de89fb4a9418be89a6df3f6b5b14906c46e8e62c4f5a557145bd147c1882893a42ecdf3e8a494615a5b2b580eab0e884cd388fc3a9627
+EBUILD libsdl2-2.30.2.ebuild 5724 BLAKE2B bd326a7abdd15f68943863cc1afabadec82f9b37cc5000f0581348fffd70af1188296f18ca6c9cedd74786660865b4c8728e094c2a9e7e6801cd8cecc537cc59 SHA512 3ac6e32c86a42aa0a5a0617ef7f3a907d2a959ef883b932c77bb3ad4fd5b3644439681687411f7818bd94d72c9dcec59c586e1b1358333a00e426e20618cdca3
 MISC metadata.xml 1945 BLAKE2B 0f4c4a1526296bfbef001169c45626f0393cfcb6f5003d3d644c1ff1ef0197fdd38ddc2f16f1c1590ef895448bd6aa85ea3619a31487609d9ea2569077decd64 SHA512 d25c6e3b2cf3055f2faf71d926d5ad01c5b528f1349284dc3097607015ed93c70116223db0078d8ae764b598bc13a99f1b82cebe1e65206ea737508bdede12df
diff --git a/media-libs/libsdl2/libsdl2-2.30.2.ebuild b/media-libs/libsdl2/libsdl2-2.30.2.ebuild
new file mode 100644
index 000000000000..02c8eabacee0
--- /dev/null
+++ b/media-libs/libsdl2/libsdl2-2.30.2.ebuild
@@ -0,0 +1,205 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+MY_P="SDL2-${PV}"
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="https://www.libsdl.org/"
+SRC_URI="https://www.libsdl.org/release/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="alsa aqua cpu_flags_ppc_altivec cpu_flags_x86_3dnow cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 custom-cflags dbus doc fcitx4 gles1 gles2 +haptic ibus jack +joystick kms libsamplerate nas opengl oss pipewire pulseaudio sndio +sound static-libs test +threads udev +video vulkan wayland X xscreensaver"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	alsa? ( sound )
+	fcitx4? ( dbus )
+	gles1? ( video )
+	gles2? ( video )
+	haptic? ( joystick )
+	ibus? ( dbus )
+	jack? ( sound )
+	nas? ( sound )
+	opengl? ( video )
+	pulseaudio? ( sound )
+	sndio? ( sound )
+	test? ( static-libs )
+	vulkan? ( video )
+	wayland? ( gles2 )
+	xscreensaver? ( X )
+"
+
+COMMON_DEPEND="
+	virtual/libiconv[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+	ibus? ( app-i18n/ibus )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	kms? (
+		>=x11-libs/libdrm-2.4.82[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.0.0[${MULTILIB_USEDEP},gbm(+)]
+	)
+	libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+	nas? (
+		>=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
+		>=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]
+	)
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+	)
+	pipewire? ( media-video/pipewire:=[${MULTILIB_USEDEP}] )
+	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
+	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
+	udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.20[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},egl(+),gles2,wayland]
+		>=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-6.0.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	fcitx4? ( app-i18n/fcitx:4 )
+	gles1? ( media-libs/mesa[${MULTILIB_USEDEP},gles1] )
+	gles2? ( media-libs/mesa[${MULTILIB_USEDEP},gles2] )
+	vulkan? ( media-libs/vulkan-loader )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	gles1? ( media-libs/libglvnd )
+	gles2? ( media-libs/libglvnd )
+	ibus? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+	test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	vulkan? ( dev-util/vulkan-headers )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+	wayland? ( >=dev-util/wayland-scanner-1.20 )
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/SDL2/SDL_config.h
+	/usr/include/SDL2/SDL_platform.h
+	/usr/include/SDL2/begin_code.h
+	/usr/include/SDL2/close_code.h
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Unbundle some headers.
+	rm -r src/video/khronos || die
+	ln -s "${ESYSROOT}/usr/include" src/video/khronos || die
+}
+
+src_configure() {
+	use custom-cflags || strip-flags
+
+	local mycmakeargs=(
+		-DSDL_STATIC=$(usex static-libs)
+		-DSDL_SYSTEM_ICONV=ON
+		-DSDL_GCC_ATOMICS=ON
+		-DSDL_AUDIO=$(usex sound)
+		-DSDL_VIDEO=$(usex video)
+		-DSDL_JOYSTICK=$(usex joystick)
+		-DSDL_HAPTIC=$(usex haptic)
+		-DSDL_POWER=ON
+		-DSDL_FILESYSTEM=ON
+		-DSDL_PTHREADS=$(usex threads)
+		-DSDL_TIMERS=ON
+		-DSDL_FILE=ON
+		-DSDL_LOADSO=ON
+		-DSDL_ASSEMBLY=ON
+		-DSDL_ALTIVEC=$(usex cpu_flags_ppc_altivec)
+		-DSDL_SSEMATH=$(usex cpu_flags_x86_sse)
+		-DSDL_MMX=$(usex cpu_flags_x86_mmx)
+		-DSDL_3DNOW=$(usex cpu_flags_x86_3dnow)
+		-DSDL_SSE=$(usex cpu_flags_x86_sse)
+		-DSDL_SSE2=$(usex cpu_flags_x86_sse2)
+		-DSDL_SSE3=$(usex cpu_flags_x86_sse3)
+		-DSDL_OSS=$(usex oss)
+		-DSDL_ALSA=$(usex alsa)
+		-DSDL_ALSA_SHARED=OFF
+		-DSDL_JACK=$(usex jack)
+		-DSDL_JACK_SHARED=OFF
+		-DSDL_ESD=OFF
+		-DSDL_PIPEWIRE=$(usex pipewire)
+		-DSDL_PIPEWIRE_SHARED=OFF
+		-DSDL_PULSEAUDIO=$(usex pulseaudio)
+		-DSDL_PULSEAUDIO_SHARED=OFF
+		-DSDL_ARTS=OFF
+		-DSDL_LIBSAMPLERATE=$(usex libsamplerate)
+		-DSDL_LIBSAMPLERATE_SHARED=OFF
+		-DSDL_WERROR=OFF
+		-DSDL_NAS=$(usex nas)
+		-DSDL_NAS_SHARED=OFF
+		-DSDL_SNDIO=$(usex sndio)
+		-DSDL_SNDIO_SHARED=OFF
+		-DSDL_DISKAUDIO=$(usex sound)
+		-DSDL_DUMMYAUDIO=$(usex sound)
+		-DSDL_WAYLAND=$(usex wayland)
+		-DSDL_WAYLAND_SHARED=OFF
+		-DSDL_RPI=OFF
+		-DSDL_X11=$(usex X)
+		-DSDL_X11_SHARED=OFF
+		-DSDL_X11_XSCRNSAVER=$(usex xscreensaver)
+		-DSDL_COCOA=$(usex aqua)
+		-DSDL_DIRECTFB=OFF
+		-DSDL_FUSIONSOUND=OFF
+		-DSDL_KMSDRM=$(usex kms)
+		-DSDL_KMSDRM_SHARED=OFF
+		-DSDL_DUMMYVIDEO=$(usex video)
+		-DSDL_OPENGL=$(usex opengl)
+		-DSDL_OPENGLES=$(use gles1 || use gles2 && echo ON || echo OFF)
+		-DSDL_VULKAN=$(usex vulkan)
+		-DSDL_LIBUDEV=$(usex udev)
+		-DSDL_DBUS=$(usex dbus)
+		-DSDL_IBUS=$(usex ibus)
+		-DSDL_DIRECTX=OFF
+		-DSDL_RPATH=OFF
+		-DSDL_VIDEO_RENDER_D3D=OFF
+		-DSDL_TESTS=$(usex test)
+	)
+	cmake-multilib_src_configure
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		cd docs || die
+		doxygen || die
+	fi
+}
+
+src_test() {
+	unset SDL_GAMECONTROLLERCONFIG SDL_GAMECONTROLLER_USE_BUTTON_LABELS
+	cmake-multilib_src_test
+}
+
+multilib_src_install_all() {
+	rm -r "${ED}"/usr/share/licenses/ || die
+	dodoc {BUGS,CREDITS,README-SDL,TODO,WhatsNew}.txt README.md docs/README*.md
+	use doc && dodoc -r docs/output/html/
+}