gentoo auto-resync : 20:02:2025 - 00:15:26

3 files changed, 98 insertions, 107 deletions

diff --git a/media-libs/sdl2-mixer/Manifest b/media-libs/sdl2-mixer/Manifest
index 5521069e35c1..412a6204cb42 100644
--- a/media-libs/sdl2-mixer/Manifest
+++ b/media-libs/sdl2-mixer/Manifest
@@ -1,7 +1,7 @@
-DIST SDL2_mixer-2.6.2.tar.gz 9934376 BLAKE2B 9cf378d03046389b3625b90ca7a4c34d9b80e0908bccef454adedc21f16f24d99acc0fc3522ba981be89d8c58c7a6e877e7d98c798b157529e2cb26141faec8c SHA512 16baa9d8b345bf0224538cbfb2ae9fc5d3deea2b454f41a98006c938fe7a65d5a8c84e28a76f98a4dd971c4fe5cf0219d8bf73331cf11f2702e01600eb197658
 DIST SDL2_mixer-2.6.3.tar.gz 9935069 BLAKE2B 9908bdc549300af05b4fbcbb6c0533913ae62bfa2f761118983e0da58a4bcd68c2d008fa5bbcd94b0141241e54f1cd507e275e2d4b637214b803dabdbc5b0250 SHA512 2e9da045d2fdab97236c3901b3d441834a67a47c8851ddfb817c9db6f23ed9fb355a5ef8d2158d0c9959a83934e8cd1b95db8a69eaddf8f7fcca115f01818740
 DIST SDL2_mixer-2.8.0.tar.gz 10874471 BLAKE2B 701ed21416e7a3ceda313f3e9ad47f98687f357712fb90f6c3c2ac065c96a4ded04a907c563f3b9b7bf42f192b6c442d025abb0a5cfbb745bd8719c49e29ff61 SHA512 5ddbc4b0b5fad2e0844a503daa79564b912654192599ef8fa7698531f08323ce01801f6bb17b2b3905020a3df362a967b7566ae725eb085da991578cc0807aad
-EBUILD sdl2-mixer-2.6.2-r1.ebuild 2967 BLAKE2B 346072e77db0dc766de79cae5ebfe22a096e3d5ba9a9afe18d1ff670c849a9cbf7cd55c3d7a2e256593ae398b9e16675fed8aeba93c291e415ac8d8208b5340d SHA512 835214d5a8c545d9952694ac3c3140ebf0bad9c15955e707a9e9c84e0b6bcdb71f93a045294dc80617a5a7946ac6d2790521eea7458411655524b9b7fdce0f06
+DIST SDL2_mixer-2.8.1.tar.gz 5996239 BLAKE2B e03fc3f2aee9e8ed5c2b2fabc54cd319adc57f88e3b965e7c8a26339808cf9d68bac83b53369e172f175896d90f1bd026125fe1356ec73ee88b369402706f455 SHA512 6148591404b2113bcdb54391821658548acfe380a9cba660113e55e6f2fb7da2a5a59a99fefe51a0d7f8b91160648f11f72750353da88d285a962e3a410aecd7
 EBUILD sdl2-mixer-2.6.3-r1.ebuild 3000 BLAKE2B fbcd9cd8458114a589bc95b8577b1bf1cdccf19f05e88241590af1baebc1f3d0cfd5e047a58b2b752757c6d6b32cb2565a400a2a88edfaa427928b29ae058f4b SHA512 aa82a7e7633ee34d5e9ce7a18d664d5e4708c158369cba0e73aca79b89a4db30e6d41cc10956b7eefded1337674ef45d6fbdf38313a3ebd9357c865f130d1e80
 EBUILD sdl2-mixer-2.8.0.ebuild 2790 BLAKE2B e2c6d4cd59f1878c0ada3cb86662d93d9599e5c677508b823cd0371c27cf87f03baa4a37cde23fadf41e2dd5945f95c668a8d7cccaaae4f1fd1e5112a4ede5c4 SHA512 f8597f8f7d0486103f514583d12b1a8e7a0cf84d7c047b84f577434ba7a2d2bf0d062eda12caef6af8c602d32e8e203cbb160e0b48f30c1bf2c3a4b9ea851a45
+EBUILD sdl2-mixer-2.8.1.ebuild 2790 BLAKE2B e2c6d4cd59f1878c0ada3cb86662d93d9599e5c677508b823cd0371c27cf87f03baa4a37cde23fadf41e2dd5945f95c668a8d7cccaaae4f1fd1e5112a4ede5c4 SHA512 f8597f8f7d0486103f514583d12b1a8e7a0cf84d7c047b84f577434ba7a2d2bf0d062eda12caef6af8c602d32e8e203cbb160e0b48f30c1bf2c3a4b9ea851a45
 MISC metadata.xml 1496 BLAKE2B 05f497210171797d550f073fcd1901374103a55d7658868646cdf55017a0d0889c9444b3de45c9da390ae6ed025ad2b2079183eb170b7f560e266921f9d0a7eb SHA512 2bc4dbaebe3c89d716c1a82940203a524fb0e06a451ad4003224745d0f48fd68234d0a151451f72b883a338efa1c875b6d412e7c798a596a4324cf736c21c780
diff --git a/media-libs/sdl2-mixer/sdl2-mixer-2.6.2-r1.ebuild b/media-libs/sdl2-mixer/sdl2-mixer-2.6.2-r1.ebuild
deleted file mode 100644
index 8d0c97b24f43..000000000000
--- a/media-libs/sdl2-mixer/sdl2-mixer-2.6.2-r1.ebuild
+++ /dev/null
@@ -1,105 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-MY_P="SDL2_mixer-${PV}"
-inherit multilib-minimal
-
-DESCRIPTION="Simple Direct Media Layer Mixer Library"
-HOMEPAGE="https://github.com/libsdl-org/SDL_mixer"
-SRC_URI="https://www.libsdl.org/projects/SDL_mixer/release/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="ZLIB"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ppc ppc64 ~riscv sparc x86"
-IUSE="flac fluidsynth midi mod mp3 opus playtools static-libs timidity tremor vorbis +wav"
-REQUIRED_USE="
-	midi? ( || ( timidity fluidsynth ) )
-	timidity? ( midi )
-	fluidsynth? ( midi )
-	tremor? ( vorbis )
-"
-
-RDEPEND="
-	>=media-libs/libsdl2-2.0.7[${MULTILIB_USEDEP}]
-	flac? ( >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}] )
-	midi? (
-		fluidsynth? ( >=media-sound/fluidsynth-1.1.6-r1:=[${MULTILIB_USEDEP}] )
-		timidity? ( media-sound/timidity++ )
-	)
-	mod? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
-	mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
-	opus? ( >=media-libs/opusfile-0.2 )
-	vorbis? (
-		tremor? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
-		!tremor? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
-	)
-"
-DEPEND="${RDEPEND}"
-
-src_prepare() {
-	default
-
-	multilib_copy_sources
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		$(use_enable static-libs static)
-		--disable-sdltest
-		--enable-music-cmd
-		$(use_enable wav music-wave)
-		$(use_enable mod music-mod)
-		$(use_enable mod music-mod-modplug)
-		--disable-music-mod-modplug-shared
-		$(use_enable midi music-midi)
-		$(use_enable timidity music-midi-timidity)
-		$(use_enable fluidsynth music-midi-fluidsynth)
-		--disable-music-midi-fluidsynth-shared
-		$(use_enable vorbis music-ogg)
-		$(usex vorbis \
-			$(use_enable !tremor music-ogg-vorbis) \
-			--disable-music-ogg-vorbis)
-		--disable-music-ogg-vorbis-shared
-		$(use_enable tremor music-ogg-tremor)
-		--disable-music-ogg-tremor-shared
-		$(use_enable flac music-flac)
-		$(use_enable flac music-flac-libflac)
-		--disable-music-flac-libflac-shared
-		$(use_enable mp3 music-mp3)
-		$(use_enable mp3 music-mp3-mpg123)
-		--disable-music-mp3-mpg123-shared
-		$(use_enable opus music-opus)
-		--disable-music-opus-shared
-	)
-
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install
-	if multilib_is_native_abi && use playtools ; then
-		emake DESTDIR="${D}" install-bin
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc {CHANGES,README}.txt
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
-	# bug #412035
-	if use midi && use fluidsynth; then
-		ewarn "FluidSynth support requires you to set the SDL_SOUNDFONTS"
-		ewarn "environment variable to the location of a SoundFont file"
-		ewarn "unless the game or application happens to do this for you."
-		if use timidity; then
-			ewarn "Failing to do so will result in Timidity being used instead."
-		else
-			ewarn "Failing to do so will result in silence."
-		fi
-	fi
-}
diff --git a/media-libs/sdl2-mixer/sdl2-mixer-2.8.1.ebuild b/media-libs/sdl2-mixer/sdl2-mixer-2.8.1.ebuild
new file mode 100644
index 000000000000..f336653b1b09
--- /dev/null
+++ b/media-libs/sdl2-mixer/sdl2-mixer-2.8.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="SDL2_mixer-${PV}"
+inherit cmake-multilib
+
+DESCRIPTION="Simple Direct Media Layer Mixer Library"
+HOMEPAGE="https://github.com/libsdl-org/SDL_mixer"
+SRC_URI="https://www.libsdl.org/projects/SDL_mixer/release/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc64 ~riscv ~sparc ~x86"
+IUSE="flac fluidsynth gme midi mod modplug mp3 opus playtools stb timidity tremor vorbis +wav wavpack xmp"
+REQUIRED_USE="
+	midi? ( || ( timidity fluidsynth ) )
+	timidity? ( midi )
+	fluidsynth? ( midi )
+
+	vorbis? ( ?? ( stb tremor ) )
+	stb? ( vorbis )
+	tremor? ( vorbis )
+
+	mod? ( || ( modplug xmp ) )
+	modplug? ( mod )
+	xmp? ( mod )
+"
+
+RDEPEND="
+	media-libs/libsdl2[${MULTILIB_USEDEP}]
+	flac? ( media-libs/flac:=[${MULTILIB_USEDEP}] )
+	midi? (
+		fluidsynth? ( media-sound/fluidsynth:=[${MULTILIB_USEDEP}] )
+		timidity? ( media-sound/timidity++ )
+	)
+	mod? (
+		modplug? ( media-libs/libmodplug[${MULTILIB_USEDEP}] )
+		xmp? ( media-libs/libxmp )
+	)
+	mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	opus? ( media-libs/opusfile )
+	vorbis? (
+		stb? ( dev-libs/stb )
+		tremor? ( media-libs/tremor[${MULTILIB_USEDEP}] )
+		!stb? ( !tremor? ( media-libs/libvorbis[${MULTILIB_USEDEP}] ) )
+	)
+	gme? ( media-libs/game-music-emu[${MULTILIB_USEDEP}] )
+	wavpack? ( media-sound/wavpack[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DSDL2MIXER_CMD=yes
+		-DSDL2MIXER_WAVE=$(usex wav)
+		-DSDL2MIXER_MOD=$(usex mod)
+		-DSDL2MIXER_MOD_MODPLUG=$(usex modplug)
+		-DSDL2MIXER_MOD_XMP=$(usex xmp)
+		-DSDL2MIXER_MIDI=$(usex midi)
+		-DSDL2MIXER_MIDI_TIMIDITY=$(usex timidity)
+		-DSDL2MIXER_MIDI_FLUIDSYNTH=$(usex fluidsynth)
+		-DSDL2MIXER_VORBIS=$(usex vorbis $(usex stb STB $(usex tremor TREMOR VORBISFILE) ) no )
+		-DSDL2MIXER_FLAC=$(usex flac)
+		-DSDL2MIXER_FLAC_LIBFLAC=$(usex flac)
+		-DSDL2MIXER_MP3=$(usex mp3)
+		-DSDL2MIXER_MP3_MPG123=$(usex mp3)
+		-DSDL2MIXER_OPUS=$(usex opus)
+		-DSDL2MIXER_GME=$(usex gme)
+		-DSDL2MIXER_WAVPACK=$(usex wavpack)
+		-DSDL2MIXER_SAMPLES=$(usex playtools)
+		-DSDL2MIXER_SAMPLES_INSTALL=$(usex playtools)
+	)
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	dodoc {CHANGES,README}.txt
+	rm -r "${ED}"/usr/share/licenses || die
+}
+
+pkg_postinst() {
+	# bug #412035
+	if use midi && use fluidsynth; then
+		ewarn "FluidSynth support requires you to set the SDL_SOUNDFONTS"
+		ewarn "environment variable to the location of a SoundFont file"
+		ewarn "unless the game or application happens to do this for you."
+		if use timidity; then
+			ewarn "Failing to do so will result in Timidity being used instead."
+		else
+			ewarn "Failing to do so will result in silence."
+		fi
+	fi
+}