gentoo resync : 09.07.2022

5 files changed, 128 insertions, 90 deletions

diff --git a/media-libs/sdl_audiolib/Manifest b/media-libs/sdl_audiolib/Manifest
index 500086980b87..522a07cc4ab6 100644
--- a/media-libs/sdl_audiolib/Manifest
+++ b/media-libs/sdl_audiolib/Manifest
@@ -1,4 +1,4 @@
-DIST sdl_audiolib-0_pre20220410.tar.xz 223932 BLAKE2B 09f35684b64b2b96fd0230612cc8458a8c7b0b94860c9d616c90141cd6d8088048e783170180191ed9998b2601676892686dc7d8373c8507d71db59b919c178b SHA512 01ef7f4d8987e1e27b4413d21eefbb8a83ab720f64ed76fd6314244d0d53bed5a061f4a22d4967e21cc9f6086532d33fea233f3e72e8a7abc5a80108f74710c1
-EBUILD sdl_audiolib-0_pre20220410.ebuild 1595 BLAKE2B baf2f56c4dd09145cf8d4a2f9d024c1677d6fdcd6f8d7d6bbd26e743c481fa2417d934973daf96bb74d66227518125450a912eb09b51a713c442421c74952c13 SHA512 4762073f00aaf4d08bca24d10280d045fb2b52babb05df5d23379820eb9bc1e5d0af6df6055acd29088f679c3ff222bed6a043a73b23890df5918129c2decb93
-EBUILD sdl_audiolib-9999.ebuild 1595 BLAKE2B baf2f56c4dd09145cf8d4a2f9d024c1677d6fdcd6f8d7d6bbd26e743c481fa2417d934973daf96bb74d66227518125450a912eb09b51a713c442421c74952c13 SHA512 4762073f00aaf4d08bca24d10280d045fb2b52babb05df5d23379820eb9bc1e5d0af6df6055acd29088f679c3ff222bed6a043a73b23890df5918129c2decb93
-MISC metadata.xml 627 BLAKE2B 9f7dce2b6e9ef5f8b8665b4ea890bcc6933bc9fb444387fe9f8b93e44bd5ec6310384ad236b3f27a6f56c4bfd2ba89cf0d037479d628f3b7c61216ee77d381c7 SHA512 743b16b1683dc5aa48030ac7d4ed0effec157f19b222f2b8ba10bc88fa7418804a258c2c3c27792419f5255fc58abd90c16e9eafebfae22b15251bc1de9f26ef
+DIST sdl_audiolib-0_p20220622.tar.gz 1138752 BLAKE2B 01e565506b29e922f3eb5ff2705a0614e53c6afd43526d781eb83d86f54dab6692689de51d618e07779fe8c97ee2cfbe3de744f29c1798e3f10205141dcb28ea SHA512 ec6267665fb1a98fcfb91a40ebbd86f7bb14e9fed36509a903ba5408d0f4b8672b19421943de6a4b3d2d0b187f9531dae4b7c9f766ee07f9c1aefa08ab6a51e3
+EBUILD sdl_audiolib-0_p20220622.ebuild 2068 BLAKE2B 5a575eec91c86e2cddc675ec52012a7a7c5a94d9e9c2e9b63a2b6b616a3992a60899726288e031810402b2ed7f2f29069542a7793de5fef2c1955ebafc4b0212 SHA512 ca1fa86ed95a01a336f7d9319739f38e182f335d39841777145ed42629adc033cbbc1e34c116083cbcfb5d8fe6ee25672b44d0e07461318f2b1ea53753341a34
+EBUILD sdl_audiolib-9999.ebuild 2028 BLAKE2B 456872876217570077b442a244c311f3f58db78e159228a058a656bce28d7182800a46fb0c8b0ccd6883ada1f3772c661767feb637a50a5c5e26156a1ab9cb8f SHA512 0b92b69cb613b388144dae7468d0dc58ae5dba11d7eb3c9cc9d73cc4ac5346bdc132b3827119d6733b3140f5edccc6968d977dbb67127de82ae53159f50cb576
+MISC metadata.xml 826 BLAKE2B 6bf43ce9d28875ebb58e21eedafd36f61944646dd863f0810b25ae1e44d2e0234f002af4473ca265b09a7a77f5e65862e1c5fe90f48e81a450e9167a57351fa3 SHA512 b3353de39f31147e500a9d0138f3531404f342dd01d8d8634365289dfb206a0628d4ce4504726387eb9f91ea8a39fae70182545d52a59a853390a81283187908
diff --git a/media-libs/sdl_audiolib/metadata.xml b/media-libs/sdl_audiolib/metadata.xml
index 20558bf8a00e..93b2751b25dc 100644
--- a/media-libs/sdl_audiolib/metadata.xml
+++ b/media-libs/sdl_audiolib/metadata.xml
@@ -1,12 +1,16 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <!-- maintainer-needed -->
+  <maintainer type="project">
+    <email>games@gentoo.org</email>
+    <name>Gentoo Games Project</name>
+  </maintainer>
   <use>
-    <flag name="fluidsynth">use <pkg>media-sound/fluidsynth</pkg> for MIDI</flag>
+    <flag name="fluidsynth">Enable support for MIDI via <pkg>media-sound/fluidsynth</pkg></flag>
     <flag name="mpg123">Enable support for mp3 decoding via <pkg>media-sound/mpg123</pkg></flag>
     <flag name="openmpt">OpenMPT decoder via <pkg>media-libs/libopenmpt</pkg></flag>
     <flag name="soxr">Enable SoX Resampler support via <pkg>media-libs/soxr</pkg></flag>
+    <flag name="wildmidi">Enable support for MIDI via <pkg>media-sound/wildmidi</pkg></flag>
   </use>
   <upstream>
     <remote-id type="github">realnc/SDL_audiolib</remote-id>
diff --git a/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild b/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild
new file mode 100644
index 000000000000..2a3199706b09
--- /dev/null
+++ b/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/realnc/SDL_audiolib.git"
+else
+	SDLAUDIO_COMMIT="b66a66fedf8f65cacc5ce2ff8ed8d10649c6de31"
+	SRC_URI="https://github.com/realnc/SDL_audiolib/archive/${SDLAUDIO_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN/sdl/SDL}-${SDLAUDIO_COMMIT}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Audio decoding, resampling and mixing library for SDL"
+HOMEPAGE="https://github.com/realnc/SDL_audiolib/"
+
+LICENSE="LGPL-3+ BSD-2 || ( MIT Unlicense )"
+SLOT="0"
+IUSE="doc flac fluidsynth libsamplerate modplug mpg123 musepack openmpt opus sndfile soxr vorbis wildmidi"
+
+RDEPEND="
+	dev-libs/libfmt:=
+	media-libs/libsdl2[sound]
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	libsamplerate? ( media-libs/libsamplerate )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	openmpt? ( media-libs/libopenmpt )
+	opus? ( media-libs/opusfile )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	vorbis? ( media-libs/libvorbis )
+	wildmidi? ( media-sound/wildmidi )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_DEC_ADLMIDI=OFF
+		-DUSE_DEC_BASSMIDI=OFF
+		-DUSE_DEC_FLAC=$(usex flac)
+		-DUSE_DEC_FLUIDSYNTH=$(usex fluidsynth)
+		-DUSE_DEC_LIBOPUSFILE=$(usex opus)
+		-DUSE_DEC_LIBVORBIS=$(usex vorbis)
+		-DUSE_DEC_MODPLUG=$(usex modplug)
+		-DUSE_DEC_MPG123=$(usex mpg123)
+		-DUSE_DEC_MUSEPACK=$(usex musepack)
+		-DUSE_DEC_OPENMPT=$(usex openmpt)
+		-DUSE_DEC_SNDFILE=$(usex sndfile)
+		-DUSE_DEC_WILDMIDI=$(usex wildmidi)
+		-DUSE_DEC_XMP=OFF
+		-DUSE_RESAMP_SOXR=$(usex soxr)
+		-DUSE_RESAMP_SRC=$(usex libsamplerate)
+		-DWITH_SYSTEM_FMTLIB=ON
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use !doc || doxygen "${BUILD_DIR}"/Doxyfile || die
+}
+
+src_install() {
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}
diff --git a/media-libs/sdl_audiolib/sdl_audiolib-0_pre20220410.ebuild b/media-libs/sdl_audiolib/sdl_audiolib-0_pre20220410.ebuild
deleted file mode 100644
index d993c84aa88b..000000000000
--- a/media-libs/sdl_audiolib/sdl_audiolib-0_pre20220410.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake
-
-DESCRIPTION="audio decoding, resampling and mixing library"
-HOMEPAGE="https://github.com/realnc/SDL_audiolib"
-if [[ "${PV}" == *9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/realnc/SDL_audiolib.git"
-else
-	# No official releases from upstream yet
-	SRC_URI="https://dev.gentoo.org/~polynomial-c/dist/${P}.tar.xz"
-	KEYWORDS="~amd64 ~x86"
-fi
-LICENSE="LGPL-3"
-SLOT="0"
-
-IUSE="fluidsynth libsamplerate modplug mpg123 musepack openmpt opus sndfile soxr vorbis"
-
-RDEPEND="
-	media-libs/libsdl2
-	fluidsynth? ( media-sound/fluidsynth )
-	libsamplerate? ( media-libs/libsamplerate )
-	modplug? ( media-libs/libmodplug )
-	mpg123? ( media-sound/mpg123 )
-	musepack? ( media-sound/musepack-tools )
-	openmpt? ( media-libs/libopenmpt )
-	opus? ( media-libs/opusfile )
-	sndfile? ( media-libs/libsndfile )
-	soxr? ( media-libs/soxr )
-	vorbis? ( media-libs/libvorbis )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-"
-
-src_configure() {
-	local mycmakeargs=(
-		-DUSE_DEC_ADLMIDI=OFF
-		-DUSE_DEC_BASSMIDI=OFF
-		-DUSE_DEC_FLUIDSYNTH="$(usex fluidsynth)"
-		-DUSE_DEC_MODPLUG="$(usex modplug)"
-		-DUSE_DEC_MPG123="$(usex mpg123)"
-		-DUSE_DEC_MUSEPACK="$(usex musepack)"
-		-DUSE_DEC_OPENMPT="$(usex openmpt)"
-		-DUSE_DEC_LIBOPUSFILE="$(usex opus)"
-		-DUSE_DEC_SNDFILE="$(usex sndfile)"
-		-DUSE_DEC_LIBVORBIS="$(usex vorbis)"
-		-DUSE_DEC_WILDMIDI=OFF
-		-DUSE_DEC_XMP=OFF
-		-DUSE_RESAMP_SOXR="$(usex soxr)"
-		-DUSE_RESAMP_SRC="$(usex libsamplerate)"
-	)
-	cmake_src_configure
-}
diff --git a/media-libs/sdl_audiolib/sdl_audiolib-9999.ebuild b/media-libs/sdl_audiolib/sdl_audiolib-9999.ebuild
index d993c84aa88b..961a40fde5e4 100644
--- a/media-libs/sdl_audiolib/sdl_audiolib-9999.ebuild
+++ b/media-libs/sdl_audiolib/sdl_audiolib-9999.ebuild
@@ -5,24 +5,28 @@ EAPI=8
 
 inherit cmake
 
-DESCRIPTION="audio decoding, resampling and mixing library"
-HOMEPAGE="https://github.com/realnc/SDL_audiolib"
-if [[ "${PV}" == *9999 ]] ; then
+if [[ ${PV} == 9999 ]] ; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/realnc/SDL_audiolib.git"
 else
-	# No official releases from upstream yet
-	SRC_URI="https://dev.gentoo.org/~polynomial-c/dist/${P}.tar.xz"
+	SDLAUDIO_COMMIT=""
+	SRC_URI="https://github.com/realnc/SDL_audiolib/archive/${SDLAUDIO_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN/sdl/SDL}-${SDLAUDIO_COMMIT}"
 	KEYWORDS="~amd64 ~x86"
 fi
-LICENSE="LGPL-3"
-SLOT="0"
 
-IUSE="fluidsynth libsamplerate modplug mpg123 musepack openmpt opus sndfile soxr vorbis"
+DESCRIPTION="Audio decoding, resampling and mixing library for SDL"
+HOMEPAGE="https://github.com/realnc/SDL_audiolib/"
+
+LICENSE="LGPL-3+ BSD-2 || ( MIT Unlicense )"
+SLOT="0"
+IUSE="doc flac fluidsynth libsamplerate modplug mpg123 musepack openmpt opus sndfile soxr vorbis wildmidi"
 
 RDEPEND="
-	media-libs/libsdl2
-	fluidsynth? ( media-sound/fluidsynth )
+	dev-libs/libfmt:=
+	media-libs/libsdl2[sound]
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth:= )
 	libsamplerate? ( media-libs/libsamplerate )
 	modplug? ( media-libs/libmodplug )
 	mpg123? ( media-sound/mpg123 )
@@ -32,28 +36,41 @@ RDEPEND="
 	sndfile? ( media-libs/libsndfile )
 	soxr? ( media-libs/soxr )
 	vorbis? ( media-libs/libvorbis )
-"
+	wildmidi? ( media-sound/wildmidi )"
 DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-"
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_configure() {
 	local mycmakeargs=(
 		-DUSE_DEC_ADLMIDI=OFF
 		-DUSE_DEC_BASSMIDI=OFF
-		-DUSE_DEC_FLUIDSYNTH="$(usex fluidsynth)"
-		-DUSE_DEC_MODPLUG="$(usex modplug)"
-		-DUSE_DEC_MPG123="$(usex mpg123)"
-		-DUSE_DEC_MUSEPACK="$(usex musepack)"
-		-DUSE_DEC_OPENMPT="$(usex openmpt)"
-		-DUSE_DEC_LIBOPUSFILE="$(usex opus)"
-		-DUSE_DEC_SNDFILE="$(usex sndfile)"
-		-DUSE_DEC_LIBVORBIS="$(usex vorbis)"
-		-DUSE_DEC_WILDMIDI=OFF
+		-DUSE_DEC_FLAC=$(usex flac)
+		-DUSE_DEC_FLUIDSYNTH=$(usex fluidsynth)
+		-DUSE_DEC_LIBOPUSFILE=$(usex opus)
+		-DUSE_DEC_LIBVORBIS=$(usex vorbis)
+		-DUSE_DEC_MODPLUG=$(usex modplug)
+		-DUSE_DEC_MPG123=$(usex mpg123)
+		-DUSE_DEC_MUSEPACK=$(usex musepack)
+		-DUSE_DEC_OPENMPT=$(usex openmpt)
+		-DUSE_DEC_SNDFILE=$(usex sndfile)
+		-DUSE_DEC_WILDMIDI=$(usex wildmidi)
 		-DUSE_DEC_XMP=OFF
-		-DUSE_RESAMP_SOXR="$(usex soxr)"
-		-DUSE_RESAMP_SRC="$(usex libsamplerate)"
+		-DUSE_RESAMP_SOXR=$(usex soxr)
+		-DUSE_RESAMP_SRC=$(usex libsamplerate)
+		-DWITH_SYSTEM_FMTLIB=ON
 	)
+
 	cmake_src_configure
 }
+
+src_compile() {
+	cmake_src_compile
+
+	use !doc || doxygen "${BUILD_DIR}"/Doxyfile || die
+}
+
+src_install() {
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}