gentoo resync : 20.03.2022

3 files changed, 231 insertions, 3 deletions

diff --git a/media-libs/xine-lib/Manifest b/media-libs/xine-lib/Manifest
index 12da573786bd..99db4e7125a4 100644
--- a/media-libs/xine-lib/Manifest
+++ b/media-libs/xine-lib/Manifest
@@ -1,6 +1,8 @@
 DIST xine-lib-1.2.10.tar.xz 5226116 BLAKE2B e1bc088814c951ff56e55b626fe1f6f34c3da744e716de369a68e6c82a5adc414b452675ad19a5f82500bade6795b54efd503de8ffe4f1e65b534317ca0a26af SHA512 1cbe033da606d67a0a59f19968b2fe1cb46eaeb32c4b4aca7b91125b7230e15bd36d1e3e39e48e6eda56e556018f9f9bf84acb0012d3dd634306e7110fdc4c5f
 DIST xine-lib-1.2.11.tar.xz 5282204 BLAKE2B c61bec690f662e01372b1c068b0681ac4435925ca90a767c590d5d3b968163280c11210dc9e3aeb4cc6bb6b3520349ba22e18b17f34bd9139af02280d3a37ee3 SHA512 8208e4699819465ec9e820530f27b6129ee954ea17ab474eb9eda12137af1417ed5260830c1006ce32266a3913d22ba9957689bb5552464908038a1b8a8efbcf
+DIST xine-lib-1.2.12.tar.xz 5341212 BLAKE2B e975be2e7cf013e218001631c6b27a0d5e291605cb236c075e4b7463b30d23f3ee14aa7e18473d52efaf124f6ab0346b93591b613c6d9339f8f28e6a719b1ef8 SHA512 cdc913d0c78a3a34bd6e4060040fd844f22dbc673330e30769c83e9682a46f3369af8f59bd0c759ddc601de979b13d53e7ed10c54f3b78bdc63afceb484826be
 EBUILD xine-lib-1.2.10.ebuild 5196 BLAKE2B 3ab9183a937bf5e72058dc6309a1258e8177b2e1d2044e6b164e525be497688cdfcd12c176f9aa1fe809588c5511de060935ed29189886c4a24ba5f81991170e SHA512 569b9418b0671eba865429434ebdccb52b9a1d387027f70fb7484f4d32b99b9bda5658c1c6a9f58d43bf026e625cd0666ea0d8cb657952cb88e7460543914910
 EBUILD xine-lib-1.2.11.ebuild 5213 BLAKE2B fb1aa47ca34bdc267a2923d55ecfc1d642248e9bb072f782e9dbbcc66a926a1c4278037650d0ae3809ac2021a89e3504bf2586031883979ce5cc7faad1e62333 SHA512 bf042d0761c3320e5a94fd83d6aed7642bb1b3f982befaf05697c9139e1e062bf25624fd23090a656654b2c62d4ed2fa2b75c20ca04b6db11172a76d117bf5a3
-EBUILD xine-lib-1.2.9999.ebuild 5211 BLAKE2B f8c2ae627ba412ae2d0dc19a293787a1395e81729ca20a70170e5521744faa538de5b8e074208d2ede249dd5b85fbb507e324106df37662e0912fcd52df1795f SHA512 6c49006f8a5ee75073a0c28cfce7ffed01d93001cce4bf59fac1eb8efad132ebc982306f66a1495930f78d8b1b8aaf55a37351e51650bf3748cac9512fcf6d05
+EBUILD xine-lib-1.2.12.ebuild 5218 BLAKE2B 3c6d52508e1562030c3f88b013473a23f908e540ffdcadd4debdcd3caff179a52665687cb08802f2351fb6a335a935148e76d8b9f1e69232e83a53a70ac52a4b SHA512 b0fbe4a5ecc646220c8bee90da8b4ecd61960e73cb33f6b1c88b60627e1fc4f0518ec105b5b0651ad94d1be1bdb510edf6f38c317c3aae3b47624c92870d5f78
+EBUILD xine-lib-1.2.9999.ebuild 5218 BLAKE2B 3c6d52508e1562030c3f88b013473a23f908e540ffdcadd4debdcd3caff179a52665687cb08802f2351fb6a335a935148e76d8b9f1e69232e83a53a70ac52a4b SHA512 b0fbe4a5ecc646220c8bee90da8b4ecd61960e73cb33f6b1c88b60627e1fc4f0518ec105b5b0651ad94d1be1bdb510edf6f38c317c3aae3b47624c92870d5f78
 MISC metadata.xml 2679 BLAKE2B e4a259e41b87a49e33a5313d436da9ec288b24a7a0a89f93e61e8ca86ce7da17b7614fa3445307d4cba1a7fedd8ee3578f98884c4523be1cdf2393b045f4a41c SHA512 8f6375ab89a851634acd40e8d749cc4d1347e26c0c2a524cd2452855edc3b6f2e7842b202e1d2b1584bd645c6087a487daec2aa54ccd72cb272dc88445e57d70
diff --git a/media-libs/xine-lib/xine-lib-1.2.12.ebuild b/media-libs/xine-lib/xine-lib-1.2.12.ebuild
new file mode 100644
index 000000000000..b3f3393bc258
--- /dev/null
+++ b/media-libs/xine-lib/xine-lib-1.2.12.ebuild
@@ -0,0 +1,226 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic libtool
+
+if [[ ${PV} == *9999* ]]; then
+	EHG_REPO_URI="http://hg.code.sf.net/p/xine/xine-lib-1.2"
+	inherit autotools mercurial
+	unset NLS_IUSE
+	NLS_DEPEND="sys-devel/gettext"
+	NLS_RDEPEND="virtual/libintl"
+else
+	KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+	SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
+	NLS_IUSE="nls"
+	NLS_DEPEND="nls? ( sys-devel/gettext )"
+	NLS_RDEPEND="nls? ( virtual/libintl )"
+fi
+
+DESCRIPTION="Core libraries for Xine movie player"
+HOMEPAGE="http://xine.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="1"
+IUSE="a52 aac aalib +alsa altivec bluray +css dts dvb dxr3 fbcon flac gtk imagemagick ipv6 jack jpeg libcaca mad +mmap mng modplug musepack nfs opengl oss pulseaudio samba sftp sdl speex theora truetype v4l vaapi vcd vdpau vdr vidix +vis vorbis vpx wavpack wayland +X xinerama +xv xvmc ${NLS_IUSE}"
+
+BDEPEND="
+	app-arch/xz-utils
+	>=sys-devel/libtool-2.2.6b
+	virtual/pkgconfig
+"
+RDEPEND="${NLS_RDEPEND}
+	dev-libs/libxdg-basedir
+	media-libs/libdvdnav
+	media-video/ffmpeg:0=
+	sys-libs/zlib:=
+	virtual/libiconv
+	a52? ( media-libs/a52dec )
+	aac? ( media-libs/faad2 )
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	bluray? ( >=media-libs/libbluray-0.2.1:= )
+	css? ( >=media-libs/libdvdcss-1.2.10 )
+	dts? ( media-libs/libdca )
+	dxr3? ( media-libs/libfame )
+	flac? ( media-libs/flac )
+	gtk? ( x11-libs/gdk-pixbuf:2 )
+	imagemagick? ( virtual/imagemagick-tools )
+	jack? ( virtual/jack )
+	jpeg? ( virtual/jpeg:0 )
+	libcaca? ( media-libs/libcaca )
+	mad? ( media-libs/libmad )
+	mng? ( media-libs/libmng:= )
+	modplug? ( >=media-libs/libmodplug-0.8.8.1 )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	nfs? ( net-fs/libnfs:= )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( net-fs/samba )
+	sftp? ( net-libs/libssh2 )
+	sdl? ( media-libs/libsdl )
+	speex? (
+		media-libs/libogg
+		media-libs/speex
+	)
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	truetype? (
+		media-libs/fontconfig
+		media-libs/freetype:2
+	)
+	v4l? ( media-libs/libv4l )
+	vaapi? ( x11-libs/libva:0=[X,opengl] )
+	vcd? (
+		>=media-video/vcdimager-0.7.23
+		dev-libs/libcdio:0=[-minimal]
+	)
+	vdpau? ( x11-libs/libvdpau )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	vpx? ( media-libs/libvpx:0= )
+	wavpack? ( media-sound/wavpack )
+	wayland? ( dev-libs/wayland )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libxcb
+	)
+	xinerama? ( x11-libs/libXinerama )
+	xv? ( x11-libs/libXv )
+	xvmc? ( x11-libs/libXvMC )
+"
+DEPEND="${RDEPEND}
+	${NLS_DEPEND}
+	oss? ( virtual/os-headers )
+	v4l? ( virtual/os-headers )
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libXt
+	)
+	xv? ( x11-base/xorg-proto )
+	xvmc? ( x11-base/xorg-proto )
+	xinerama? ( x11-base/xorg-proto )
+"
+REQUIRED_USE="
+	vidix? ( || ( X fbcon ) )
+	xv? ( X )
+	xinerama? ( X )
+"
+
+src_prepare() {
+	default
+
+	sed -i -e '/define VDR_ABS_FIFO_DIR/s|".*"|"/var/vdr/xine"|' src/vdr/input_vdr.c || die
+
+	if [[ "${PV}" = *9999* ]] ; then
+		eautoreconf
+	else
+		elibtoolize
+	fi
+
+	local x
+	for x in 0 1 2 3; do
+		sed -i -e "/^O${x}_CFLAGS=\"-O${x}\"/d" configure || die
+	done
+}
+
+src_configure() {
+	[[ ${CHOST} == i?86-* ]] && append-flags -fomit-frame-pointer #422519
+
+	local win32dir #197236
+	if has_multilib_profile; then
+		win32dir=/usr/$(ABI="x86" get_libdir)/win32
+	else
+		win32dir=/usr/$(get_libdir)/win32
+	fi
+
+	local myconf=(
+		--disable-directfb
+		--disable-gnomevfs
+		--disable-optimizations
+		--disable-real-codecs
+		--disable-v4l
+		--disable-w32dll
+		--enable-avformat
+		--with-external-dvdnav
+		--with-real-codecs-path=/usr/$(get_libdir)/codecs
+		--with-w32-path=${win32dir}
+		--with-xv-path=/usr/$(get_libdir)
+		--without-esound
+		--without-fusionsound
+		$(use_enable a52 a52dec)
+		$(use_enable aac faad)
+		$(use_enable aalib)
+		$(use_enable altivec)
+		$(use_enable bluray)
+		$(use_enable dts)
+		$(use_enable dvb)
+		$(use_enable dxr3)
+		$(use_enable fbcon fb)
+		$(use_enable gtk gdkpixbuf)
+		$(use_enable ipv6)
+		$(use_enable jpeg libjpeg)
+		$(use_enable mad)
+		$(use_enable mmap)
+		$(use_enable mng)
+		$(use_enable modplug)
+		$(use_enable musepack)
+		$(use_enable nfs)
+		$(use_enable opengl)
+		$(use_enable opengl glu)
+		$(use_enable oss)
+		$(use_enable samba)
+		$(use_enable sftp)
+		$(use_enable v4l libv4l)
+		$(use_enable v4l v4l2)
+		$(use_enable vaapi)
+		$(use_enable vdpau)
+		$(use_enable vis)
+		$(use_enable vidix)
+		$(use_enable xinerama)
+		$(use_enable xvmc)
+		$(use_enable vcd)
+		$(use_enable vdr)
+		$(use_enable vpx)
+		$(use_enable wayland)
+		$(use_with alsa)
+		$(use_with flac libflac)
+		$(use_with imagemagick)
+		$(use_with jack)
+		$(use_with libcaca caca)
+		$(use_with pulseaudio)
+		$(use_with sdl)
+		$(use_with speex)
+		$(use_with theora)
+		$(use_with truetype fontconfig)
+		$(use_with truetype freetype)
+		$(use_with vorbis)
+		$(use_with wavpack)
+		$(use_with X x)
+		$(use_with X xcb)
+	)
+	[[ ${PV} == *9999* ]] || myconf+=( $(use_enable nls) )
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	# enable verbose building, bug #448140
+	emake V=1
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+	rm "${ED}"/usr/share/doc/${PF}/COPYING || die
+}
diff --git a/media-libs/xine-lib/xine-lib-1.2.9999.ebuild b/media-libs/xine-lib/xine-lib-1.2.9999.ebuild
index e683322d35dd..b3f3393bc258 100644
--- a/media-libs/xine-lib/xine-lib-1.2.9999.ebuild
+++ b/media-libs/xine-lib/xine-lib-1.2.9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ if [[ ${PV} == *9999* ]]; then
 	NLS_DEPEND="sys-devel/gettext"
 	NLS_RDEPEND="virtual/libintl"
 else
-	KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
 	SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
 	NLS_IUSE="nls"
 	NLS_DEPEND="nls? ( sys-devel/gettext )"