Merge branch 'edge' into next

2 files changed, 114 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index 6e19888b433e..cb3fecdf778f 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,3 +1,5 @@
 DIST gstreamer-vaapi-1.14.5.tar.xz 1068344 BLAKE2B b98363981dc7f111fc8c15188d31dea394b7f6cf300050b95d564b75020931a0f8690d11410f2d3d18d6649ef2ee290c933c3731b4bc3ca43bffb57a4c1bf542 SHA512 287df56ad9bb3fd0754b9f307082eb180c8f0b622e2c9436c5dcf2272a5fb620cb18970726d231688837d52cb169a10e98e14160e51fd82198c34ea612c0d60b
+DIST gstreamer-vaapi-1.16.2.tar.xz 1095012 BLAKE2B 5bf3d34db429d180dfc09cfeccab32f57f7fdad9d05e27ac1aab2ea89e1b14442d4bdb4fd768408b9aee25a117232081adb28447b252c5d553da9d9e0f5b8676 SHA512 61554b5496dca595fa6e278a5634112e225784e9f0a7e731800fd04b395ba4e11dc467b8d074cb8cfed182fa9b9511c104192aecbba3ac755a4c32372061ac9f
 EBUILD gst-plugins-vaapi-1.14.5.ebuild 4326 BLAKE2B 3a4f15fa01265c69f1e65717c180375a621188523cb306ee957185b0504ad70b6ef1513ea562c83e5feffcd49b3e384e711612be60b95386c1dfb5de5a443b66 SHA512 fee4f766032af2310eda0567c2c3b911faae5720c773615277a675696f786b6f6c720c932d5d51b41c53be4c1aa7b7ec2fc7658980bfdbdc12c2dd34f8e9280d
+EBUILD gst-plugins-vaapi-1.16.2.ebuild 4368 BLAKE2B 4494f97a3d9fbec47276170c614efce3789781481490b2d078529961718a721e804e21dd2c03395873db3caf709c7dcf7e5a5c085ae6afe126d03f5cc355e500 SHA512 1205c8b3d1a14952027a95aee678e4ce4737cdb4b746cde8d68bbedeca3862f8562a65ad6c7886950793cfc7c436c01890649a3df39c52ae2c8037dfb96c179a
 MISC metadata.xml 433 BLAKE2B d46828441b89363cce84ff10747ad13f30329aea96cf2acd2fc7deb786c3f3ec0ec5a86011657d39ac905f9f33a3904b38860b16f53cfb150530cc4142f1beed SHA512 366bbe78a862a65a8b82ee43521508db5766cde3a72f4ad8e7f0b703dc23347589e07dcfdb3f3ec12e62ac91adb38b2a58cee5dff4732069ac2b8724524a405b
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.16.2.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.16.2.ebuild
new file mode 100644
index 000000000000..aa36989078b0
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.16.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib-minimal
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://cgit.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+drm +egl gles2 +opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
+
+# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
+# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
+# enable opengl support at all and choices get chained from there.
+# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
+# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
+# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
+# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
+# gles2 API only supported windowing system (on linux) is EGL, so require it
+# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
+REQUIRED_USE="
+	|| ( drm gles2 opengl wayland X )
+	gles2? ( egl )
+	opengl? ( || ( egl X ) )
+"
+
+# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
+# USE flag behavior:
+# 'drm' enables vaapi drm support
+# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
+# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
+#   it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
+# 'gles2' enables GLESv2 or GLESv3 based GL API support
+# 'opengl' enables desktop OpenGL based GL API support
+# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
+# 'X' enables non-GL X support; GLX support when combined with 'opengl'
+# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
+GST_REQ="${PV}"
+GL_DEPS="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
+	media-libs/mesa[gles2?,egl?,X(+),${MULTILIB_USEDEP}]
+"
+RDEPEND="
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=x11-libs/libva-1.4.0:=[drm?,wayland?,X?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	)
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+	wayland? (
+		>=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}]
+		>=dev-libs/wayland-protocols-1.15 )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		x11-libs/libXrender[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+	local myconf=()
+	if use opengl || use gles2; then
+		myconf+=(
+			$(use_enable egl)
+			--with-glapi=$(usex opengl 'gl,' '')$(usex gles2 'gles2,gles3' '') # It's fine to have extra commas passed
+		)
+	else
+		myconf+=(
+			--disable-egl
+			--without-glapi
+		)
+	fi
+
+	if use opengl && use X; then
+		myconf+=( --enable-glx )
+	else
+		myconf+=( --disable-glx )
+	fi
+
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-static \
+		--disable-debug \
+		--disable-examples \
+		--enable-encoders \
+		$(use_enable drm) \
+		$(use_enable X x11) \
+		$(use_enable wayland) \
+		--without-gtk \
+		"${myconf[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}